Add dot1q-ip6base-[ndrpdr|mrr] perf tests for 2-node topology

Jira: CSIT-1283

Change-Id: I0f6841bafdb47bdbc3efe29801fe66a0d4c388ca
Signed-off-by: Jan Gelety <jgelety@cisco.com>

1 files changed, 132 insertions, 0 deletions

diff --git a/tests/vpp/perf/ip6/10ge2p1x710-dot1q-ip6base-mrr.robot b/tests/vpp/perf/ip6/10ge2p1x710-dot1q-ip6base-mrr.robot
new file mode 100644
index 0000000000..6b7a21770a
--- /dev/null
+++ b/tests/vpp/perf/ip6/10ge2p1x710-dot1q-ip6base-mrr.robot
@@ -0,0 +1,132 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/performance/performance_setup.robot
+| ...
+| Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
+| ... | NIC_Intel-X710 | ETH | IP6FWD | BASE | DOT1Q | IP6BASE
+| ...
+| Suite Setup | Set up 3-node performance topology with DUT's NIC model
+| ... | L3 | Intel-X710
+| Suite Teardown | Tear down 3-node performance topology
+| ...
+| Test Setup | Set up performance test
+| Test Teardown | Tear down performance mrr test
+| ...
+| Test Template | Local Template
+| ...
+| Documentation | *Raw results IPv6 routing with IEEE 802.1Q test cases*
+| ...
+| ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
+| ... | with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv6 for IPv6 routing. IEEE 802.1Q\
+| ... | tagging is applied on link between DUT1 and DUT2.
+| ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
+| ... | routing and two static IPv6 /64 route entries. DUT1 and DUT2 are tested\
+| ... | with 2p10GE NIC X710 by Intel.
+| ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic\
+| ... | at line rate and reports total received/sent packets over trial period.\
+| ... | Test packets are generated by TG on links to DUTs. TG traffic profile\
+| ... | contains two L3 flow-groups (flow-group per direction, 253 flows per\
+| ... | flow-group) with all packets containing Ethernet header, IPv6 header\
+| ... | and static payload. MAC addresses are matching MAC addresses of the TG\
+| ... | node interfaces.
+| ... | *[Ref] Applicable standard specifications:* RFC2544.
+
+*** Variables ***
+| ${subid}= | 10
+| ${tag_rewrite}= | pop-1
+| ${overhead}= | ${4}
+# X710 bandwidth limit
+| ${s_limit}= | ${10000000000}
+# TG subnets used by T-Rex
+| ${tg_if1_net}= | 2001:1::0
+| ${tg_if2_net}= | 2001:2::0
+# Traffic profile:
+| ${traffic_profile}= | trex-sl-3n-ethip6-ip6src253
+
+*** Keywords ***
+| Local Template
+| | [Documentation]
+| | ... | [Cfg] Each DUT runs IPv6 routing with VLAN and uses ${phy_cores}\
+| | ... | physical core(s) for worker threads.
+| | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
+| | ... | trial throughput test.
+| | ...
+| | ... | *Arguments:*
+| | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
+| | ... | Type: integer, string
+| | ... | - phy_cores - Number of physical cores. Type: integer
+| | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
+| | ...
+| | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
+| | ...
+| | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
+| | And Add PCI devices to all DUTs
+| | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
+| | ... | ${s_limit} | ${framesize} | overhead=${overhead}
+| | And Apply startup configuration on all VPP DUTs
+| | When Initialize IPv6 forwarding with VLAN dot1q sub-interfaces in circular topology
+| | ... | ${tg_if1_net} | ${tg_if2_net} | ${subid} | ${tag_rewrite}
+| | Then Traffic should pass with maximum rate
+| | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
+
+*** Test Cases ***
+| tc01-78B-1c-dot1q-ip6base-mrr
+| | [Tags] | 78B | 1C
+| | framesize=${78} | phy_cores=${1}
+
+| tc02-78B-2c-dot1q-ip6base-mrr
+| | [Tags] | 78B | 2C
+| | framesize=${78} | phy_cores=${2}
+
+| tc03-78B-4c-dot1q-ip6base-mrr
+| | [Tags] | 78B | 4C
+| | framesize=${78} | phy_cores=${4}
+
+| tc04-1518B-1c-dot1q-ip6base-mrr
+| | [Tags] | 1518B | 1C
+| | framesize=${1518} | phy_cores=${1}
+
+| tc05-1518B-2c-dot1q-ip6base-mrr
+| | [Tags] | 1518B | 2C
+| | framesize=${1518} | phy_cores=${2}
+
+| tc06-1518B-4c-dot1q-ip6base-mrr
+| | [Tags] | 1518B | 4C
+| | framesize=${1518} | phy_cores=${4}
+
+| tc07-9000B-1c-dot1q-ip6base-mrr
+| | [Tags] | 9000B | 1C
+| | framesize=${9000} | phy_cores=${1}
+
+| tc08-9000B-2c-dot1q-ip6base-mrr
+| | [Tags] | 9000B | 2C
+| | framesize=${9000} | phy_cores=${2}
+
+| tc09-9000B-4c-dot1q-ip6base-mrr
+| | [Tags] | 9000B | 4C
+| | framesize=${9000} | phy_cores=${4}
+
+| tc10-IMIX-1c-dot1q-ip6base-mrr
+| | [Tags] | IMIX | 1C
+| | framesize=IMIX_v4_1 | phy_cores=${1}
+
+| tc11-IMIX-2c-dot1q-ip6base-mrr
+| | [Tags] | IMIX | 2C
+| | framesize=IMIX_v4_1 | phy_cores=${2}
+
+| tc12-IMIX-4c-dot1q-ip6base-mrr
+| | [Tags] | IMIX | 4C
+| | framesize=IMIX_v4_1 | phy_cores=${4}