blob: 44e3f0147e0b2c0f84f88887dec7828210c3f836 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Copyright (c) 2018 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Settings ***
| Library | resources.libraries.python.L2Util
| Resource | resources/libraries/robot/shared/default.robot
| Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
| Resource | resources/libraries/robot/l2/l2_traffic.robot
| Resource | resources/libraries/robot/shared/interfaces.robot
| Resource | resources/libraries/robot/shared/testing_path.robot
| ...
| Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
| ... | FUNCTEST | L2BDMACLRN | BASE | ETH | ICMP
| ...
| Suite Setup | Setup suite single link
| Test Setup | Setup test
| Test Teardown | Tear down test | packet_trace
| ...
| Documentation | *L2 bridge-domain test cases*
| ...
| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology \
| ... | with single links between nodes.
| ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of \
| ... | IPv4; Eth-IPv6-ICMPv6 for L2 switching of IPv6 use. Both apply to all \
| ... | links.
| ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge-domain \
| ... | switching.
| ... | *[Ver] TG verification:* Test ICMPv4 (or ICMPv6) Echo Request packets \
| ... | are sent in both directions by TG on links to DUT1; on receive TG \
| ... | verifies packets for correctness and their IPv4 (IPv6) src-addr, \
| ... | dst-addr and MAC addresses.
| ... | *[Ref] Applicable standard specifications:* RFC792
*** Variables ***
| @{plugins_to_enable}= | dpdk_plugin.so
| ${nic_name}= | virtual
| ${bd_id}= | 1
*** Test Cases ***
| tc01-eth2p-ethicmpv4-l2bdbase-device
| | [Documentation]
| | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv4-ICMPv4.
| | ... | [Cfg] Configure L2 bridge-domain (L2BD) with MAC learning enabled on \
| | ... | DUT1. Add both interfaces towards TG to this L2BD.
| | ... | [Ver] Make TG send ICMPv4 Echo Req in both directions between two of \
| | ... | its interfaces to be switched by DUT1; verify all packets are \
| | ... | received.
| | ...
| | Given Add PCI devices to all DUTs
| | And Apply startup configuration on all VPP DUTs
| | And VPP Enable Traces On All Duts | ${nodes}
| | When Configure path in 2-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
| | And Configure interfaces in path up
| | And Create bridge domain | ${dut_node} | ${bd_id}
| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if1}
| | ... | ${bd_id}
| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if2}
| | ... | ${bd_id}
| | And All Vpp Interfaces Ready Wait | ${nodes}
| | Then Send ICMPv4 bidirectionally and verify received packets | ${tg_node}
| | ... | ${tg_to_dut_if1} | ${tg_to_dut_if2}
| | ...
| | And VPP get bridge domain data | ${nodes['DUT1']}
| | And Get L2 Fib Table | ${nodes['DUT1']} | ${bd_id}
| tc02-eth2p-ethicmpv6-l2bdbase-device
| | [Documentation]
| | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] Configure L2 bridge-domain (L2BD) with MAC learning enabled on \
| | ... | DUT1. Add both interfaces towards TG to this L2BD.
| | ... | [Ver] Make TG send ICMPv6 Echo Req in both directions between two of \
| | ... | its interfaces to be switched by DUT1; verify all packets are \
| | ... | received.
| | ...
| | Given Add PCI devices to all DUTs
| | And Apply startup configuration on all VPP DUTs
| | And VPP Enable Traces On All Duts | ${nodes}
| | When Configure path in 2-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
| | And Configure interfaces in path up
| | And Create bridge domain | ${dut_node} | ${bd_id}
| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if1}
| | ... | ${bd_id}
| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if2}
| | ... | ${bd_id}
| | And All Vpp Interfaces Ready Wait | ${nodes}
| | Then Send ICMPv6 bidirectionally and verify received packets
| | ... | ${tg_node} | ${tg_to_dut_if1} | ${tg_to_dut_if2}
| | VPP get bridge domain data | ${nodes['DUT1']} | bd_id=${bd_id}
|
