From a23197980e40d4d9414bcfaf59005a1dc2a89251 Mon Sep 17 00:00:00 2001
From: sreejith <sreejith.surendrannair@linaro.org>
Date: Wed, 29 Mar 2017 01:15:02 -0400
Subject: Added vpp intial source code from master branch 17.01.1

Change-Id: I81bdace6f330825a1746a853766779dfb24765fd
Signed-off-by: sreejith <sreejith.surendrannair@linaro.org>
---
 vpp/plugins/configure.ac | 68 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 vpp/plugins/configure.ac

(limited to 'vpp/plugins/configure.ac')

diff --git a/vpp/plugins/configure.ac b/vpp/plugins/configure.ac
new file mode 100644
index 00000000..6e7d5b8a
--- /dev/null
+++ b/vpp/plugins/configure.ac
@@ -0,0 +1,68 @@
+AC_INIT(core_plugins, 1.0)
+LT_INIT
+AM_INIT_AUTOMAKE
+AM_SILENT_RULES([yes])
+
+AC_PROG_CC
+
+AC_ARG_ENABLE(tests,
+              AC_HELP_STRING([--enable-tests], [Build unit tests]),
+              [enable_tests=1],
+              [enable_tests=0])
+
+AC_ARG_WITH(dpdk,
+            AC_HELP_STRING([--with-dpdk],[Use DPDK]),
+            [with_dpdk=1],
+            [with_dpdk=0])
+
+AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" = "1")
+
+AM_CONDITIONAL(WITH_DPDK, test "$with_dpdk" = "1")
+AC_SUBST(DPDK,["-DDPDK=${with_dpdk}"])
+
+AC_DEFUN([PLUGIN_ENABLED],
+[
+   AC_ARG_ENABLE($1_plugin,
+       AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
+              [enable_the_plugin=0],
+              [enable_the_plugin=1])
+if test "x$enable_the_plugin" = x1; then
+   AC_CONFIG_SUBDIRS($1-plugin)
+fi
+AM_CONDITIONAL(ENABLE_$1_PLUGIN, test "$enable_the_plugin" = "1")
+])
+
+AC_DEFUN([PLUGIN_DISABLED],
+[
+   AC_ARG_ENABLE($1_plugin,
+       AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
+              [enable_the_plugin=1],
+              [enable_the_plugin=0])
+if test "x$enable_the_plugin" = x1; then
+   AC_CONFIG_SUBDIRS($1-plugin)
+fi
+AM_CONDITIONAL(ENABLE_$1_PLUGIN, test "$enable_the_plugin" = "1")
+])
+
+# To add a new plugin subdirectory:
+#
+# add PLUGIN(new) below, and
+# add the following to Makefile.am:
+#
+# if ENABLE_new_PLUGIN
+# SUBDIRS += new-plugin
+# endif
+
+PLUGIN_ENABLED(sixrd)
+PLUGIN_ENABLED(ioam)
+PLUGIN_ENABLED(snat)
+PLUGIN_ENABLED(ila)
+PLUGIN_ENABLED(lb)
+PLUGIN_ENABLED(flowperpkt)
+PLUGIN_ENABLED(acl)
+
+# Disabled plugins, require --enable-XXX-plugin
+PLUGIN_DISABLED(vcgn)
+PLUGIN_DISABLED(sample)
+
+AC_OUTPUT([Makefile])
-- 
cgit 1.2.3-korg