Update cmake build

 - cleanups and updates
 - updates docs for centos build using devtoolset7 compiler

Change-Id: I4c5635b1512dcd08e98291bde1f14c51f9067b63
Signed-off-by: Michal Cmarada <mcmarada@cisco.com>

4 files changed, 213 insertions, 0 deletions

diff --git a/modules/FindSphinx.cmake b/modules/FindSphinx.cmake
index cb68e51..4952960 100644
--- a/modules/FindSphinx.cmake
+++ b/modules/FindSphinx.cmake
@@ -1,3 +1,16 @@
+# Copyright (c) 2019 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
 find_program(SPHINX_EXECUTABLE NAMES sphinx-build
         HINTS
         $ENV{SPHINX_DIR}
diff --git a/modules/ccache.cmake b/modules/ccache.cmake
new file mode 100644
index 0000000..9c42227
--- /dev/null
+++ b/modules/ccache.cmake
@@ -0,0 +1,28 @@
+# Copyright (c) 2019 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+##############################################################################
+# ccache
+##############################################################################
+option(JVPP_USE_CCACHE "Use ccache compiler cache." ON)
+if(JVPP_USE_CCACHE)
+  find_program(CCACHE_FOUND ccache)
+  message(STATUS "Looking for ccache")
+  if(CCACHE_FOUND)
+    message(STATUS "Looking for ccache - found")
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
+  else(CCACHE_FOUND)
+    message(STATUS "Looking for ccache - not found")
+  endif(CCACHE_FOUND)
+endif(JVPP_USE_CCACHE)
diff --git a/modules/cpu.cmake b/modules/cpu.cmake
new file mode 100644
index 0000000..c3a4ce4
--- /dev/null
+++ b/modules/cpu.cmake
@@ -0,0 +1,60 @@
+# Copyright (c) 2019 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+##############################################################################
+# CPU optimizations and multiarch support
+##############################################################################
+if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
+  set(CMAKE_C_FLAGS "-march=corei7 -mtune=corei7-avx ${CMAKE_C_FLAGS}")
+  check_c_compiler_flag("-march=core-avx2" compiler_flag_march_core_avx2)
+  if(compiler_flag_march_core_avx2)
+    list(APPEND MARCH_VARIANTS "avx2\;-march=core-avx2 -mtune=core-avx2")
+  endif()
+  check_c_compiler_flag("-march=skylake-avx512" compiler_flag_march_skylake_avx512)
+  if(compiler_flag_march_skylake_avx512)
+    list(APPEND MARCH_VARIANTS "avx512\;-march=skylake-avx512 -mtune=skylake-avx512")
+  endif()
+elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
+  set(CMAKE_C_FLAGS "-march=armv8-a+crc ${CMAKE_C_FLAGS}")
+  check_c_compiler_flag("-march=armv8-a+crc+crypto -mtune=qdf24xx" compiler_flag_march_core_qdf24xx)
+  if(compiler_flag_march_core_qdf24xx)
+    list(APPEND MARCH_VARIANTS "qdf24xx\;-march=armv8-a+crc+crypto -DCLIB_N_PREFETCHES=8")
+  endif()
+  check_c_compiler_flag("-march=armv8.1-a+crc+crypto -mtune=thunderx2t99" compiler_flag_march_thunderx2t99)
+  if(compiler_flag_march_thunderx2t99)
+    if (CMAKE_C_COMPILER_VERSION VERSION_GREATER 7.3)
+      list(APPEND MARCH_VARIANTS "thunderx2t99\;-march=armv8.1-a+crc+crypto -mtune=thunderx2t99 -DCLIB_N_PREFETCHES=8")
+    else()
+      list(APPEND MARCH_VARIANTS "thunderx2t99\;-march=armv8.1-a+crc+crypto -DCLIB_N_PREFETCHES=8")
+    endif()
+  endif()
+  check_c_compiler_flag("-march=armv8-a+crc+crypto -mtune=cortex-a72" compiler_flag_march_cortexa72)
+  if(compiler_flag_march_cortexa72)
+    list(APPEND MARCH_VARIANTS "cortexa72\;-march=armv8-a+crc+crypto -mtune=cortex-a72 -DCLIB_N_PREFETCHES=6")
+  endif()
+endif()
+
+macro(vpp_library_set_multiarch_sources lib)
+  foreach(V ${MARCH_VARIANTS})
+    list(GET V 0 VARIANT)
+    list(GET V 1 VARIANT_FLAGS)
+    set(l ${lib}_${VARIANT})
+    add_library(${l} OBJECT ${ARGN})
+    set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
+    target_compile_options(${l} PUBLIC "-DCLIB_MARCH_VARIANT=${VARIANT}" -Wall -fno-common)
+    separate_arguments(VARIANT_FLAGS)
+    target_compile_options(${l} PUBLIC ${VARIANT_FLAGS})
+    target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${l}>)
+  endforeach()
+endmacro()
+
diff --git a/modules/misc.cmake b/modules/misc.cmake
new file mode 100644
index 0000000..56c9d7c
--- /dev/null
+++ b/modules/misc.cmake
@@ -0,0 +1,112 @@
+# Copyright (c) 2019 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+##############################################################################
+# Highlight WARNING and ERROR messages
+##############################################################################
+function(message)
+  list(GET ARGV 0 type)
+  if("$ENV{TERM}" STREQUAL "xterm-256color" OR "$ENV{TERM}" STREQUAL "xterm-color" OR "$ENV{TERM}" STREQUAL "xterm")
+    string(ASCII 27 esc)
+    set(red "${esc}[1;31m")
+    set(yellow "${esc}[1;33m")
+    set(cyan "${esc}[36m")
+    set(white "${esc}[37;1m")
+    set(reset "${esc}[m")
+  endif()
+  if(type STREQUAL FATAL_ERROR OR type STREQUAL SEND_ERROR)
+    list(REMOVE_AT ARGV 0)
+    _message(${type} "${red}${ARGV}${reset}")
+  elseif(type STREQUAL WARNING)
+    list(REMOVE_AT ARGV 0)
+    _message(STATUS "${yellow}${ARGV}${reset}")
+  elseif(type STREQUAL STATUS)
+    list(REMOVE_AT ARGV 0)
+    _message(STATUS "${cyan}${ARGV}${reset}")
+  elseif(type STREQUAL INFO)
+    list(REMOVE_AT ARGV 0)
+    _message("${white}${ARGV}${reset}")
+  elseif(type STREQUAL INFO1)
+    list(REMOVE_AT ARGV 0)
+    _message("    ${white}${ARGV}${reset}")
+  else()
+    _message(${ARGV})
+  endif()
+endfunction()
+
+##############################################################################
+# aligned config output
+##############################################################################
+function(info desc val)
+  if("$ENV{TERM}" STREQUAL "xterm-256color" OR "$ENV{TERM}" STREQUAL "xterm-color" OR "$ENV{TERM}" STREQUAL "xterm")
+    string(ASCII 27 esc)
+    set(reset "${esc}[m")
+    set(white "${esc}[37;1m")
+  endif()
+  string(LENGTH ${desc} len)
+  while (len LESS 20)
+    set (desc "${desc} ")
+    string(LENGTH ${desc} len)
+  endwhile()
+  if("${val}" MATCHES ";")
+    string(REPLACE ";" "\n                          " val "${val}")
+  endif()
+  _message("    ${white}${desc}${reset}: ${val}")
+endfunction()
+
+##############################################################################
+# Convert to camel case string from lower case underscored string.
+#
+# :param input: the input lowercase underscored string
+# :type input: string
+# :param output: the output camelcase string
+# :type output: string
+##############################################################################
+function(camel_case_string input output)
+    string(REPLACE "_" ";" list ${input})
+    foreach(SUBSTR ${list})
+        string(SUBSTRING ${SUBSTR} 0 1 FIRST_LETTER)
+        string(TOUPPER ${FIRST_LETTER} FIRST_LETTER)
+        string(REGEX REPLACE "^.(.*)" "${FIRST_LETTER}\\1" SUBSTR "${SUBSTR}")
+        string(APPEND result ${SUBSTR})
+    endforeach(SUBSTR)
+    set(${output} "${result}" PARENT_SCOPE)
+endfunction()
+
+##############################################################################
+# string append
+##############################################################################
+
+macro(string_append var str)
+  if (NOT ${var})
+    set(${var} "${str}")
+  else()
+    set(${var} "${${var}} ${str}")
+  endif()
+endmacro()
+
+# OS RELATED VARIABLES
+list(APPEND DebianBasedOS "Ubuntu" "LinuxMint")
+list(APPEND RHBasedOS "CentOS")
+unset(RELEASE_ID)
+unset(RELEASE_CODENAME)
+find_program(LSB_RELEASE_EXEC lsb_release)
+execute_process(COMMAND ${LSB_RELEASE_EXEC} -is
+        OUTPUT_VARIABLE RELEASE_ID
+        OUTPUT_STRIP_TRAILING_WHITESPACE
+        )
+
+execute_process(COMMAND ${LSB_RELEASE_EXEC} -cs
+        OUTPUT_VARIABLE RELEASE_CODENAME
+        OUTPUT_STRIP_TRAILING_WHITESPACE
+        )