Add qinq through xconnect tests.

Change-Id: Ia20f5959dab41290bf60490ead830f0e37ecff0d
Signed-off-by: Patrik Hrnciar <phrnciar@cisco.com>

6 files changed, 260 insertions, 0 deletions

diff --git a/resources/libraries/python/InterfaceUtil.py b/resources/libraries/python/InterfaceUtil.py
index bf1ba1e8aa..a5f00ad03e 100644
--- a/resources/libraries/python/InterfaceUtil.py
+++ b/resources/libraries/python/InterfaceUtil.py
@@ -461,3 +461,49 @@ class InterfaceUtil(object):
         else:
             raise RuntimeError('Unable to create VXLAN interface on node {}'
                                .format(node))
+
+    @staticmethod
+    def create_subinterface(node, interface, sub_id, outer_vlan_id,
+                            inner_vlan_id, type_subif):
+        """Create sub-interface on node.
+
+        :param node: Node to add sub-interface.
+        :param interface: Interface name on which create sub-interface.
+        :param sub_id: ID of the sub-interface to be created.
+        :param outer_vlan_id: Outer VLAN ID.
+        :param inner_vlan_id: Inner VLAN ID.
+        :param type_subif: Type of sub-interface.
+        :type node: dict
+        :type interface: str or int
+        :type sub_id: int
+        :type outer_vlan_id: int
+        :type inner_vlan_id: int
+        :type type_subif: str
+        :return: name and index of created sub-interface
+        :rtype: tuple
+        """
+
+        if isinstance(interface, basestring):
+            sw_if_index = Topology.get_interface_sw_index(node, interface)
+        else:
+            sw_if_index = interface
+
+        output = VatExecutor.cmd_from_template(node, "create_sub_interface.vat",
+                                               sw_if_index=sw_if_index,
+                                               sub_id=sub_id,
+                                               outer_vlan_id=outer_vlan_id,
+                                               inner_vlan_id=inner_vlan_id,
+                                               type_subif=type_subif)
+
+        if output[0]["retval"] == 0:
+            sw_subif_index = output[0]["sw_if_index"]
+            logger.trace('Created subinterface with index {}'
+                         .format(sw_subif_index))
+        else:
+            raise RuntimeError('Unable to create subinterface on node {}'
+                               .format(node['host']))
+
+        with VatTerminal(node) as vat:
+            vat.vat_terminal_exec_cmd('exec show interfaces')
+
+        return '{}.{}'.format(interface, sub_id), sw_subif_index
diff --git a/resources/libraries/python/L2Util.py b/resources/libraries/python/L2Util.py
index e0824598b4..5903d03549 100644
--- a/resources/libraries/python/L2Util.py
+++ b/resources/libraries/python/L2Util.py
@@ -248,3 +248,26 @@ class L2Util(object):
                     return bridge_domain
 
         return data
+
+    @staticmethod
+    def l2_tag_rewrite(node, interface, tag_rewrite_method):
+        """Rewrite tags in frame.
+
+        :param node: Node to rewrite tags.
+        :param interface: Interface on which rewrite tags.
+        :param tag_rewrite_method: Method of tag rewrite.
+        :type node: dict
+        :type interface: str or int
+        :type tag_rewrite_method : str
+        """
+
+        if isinstance(interface, basestring):
+            sw_if_index = Topology.get_interface_sw_index(node, interface)
+        else:
+            sw_if_index = interface
+
+        with VatTerminal(node) as vat:
+            vat.vat_terminal_exec_cmd_from_template("l2_tag_rewrite.vat",
+                                                    sw_if_index=sw_if_index,
+                                                    tag_rewrite_method=
+                                                    tag_rewrite_method)
diff --git a/resources/libraries/robot/tagging.robot b/resources/libraries/robot/tagging.robot
new file mode 100644
index 0000000000..e0f26a5938
--- /dev/null
+++ b/resources/libraries/robot/tagging.robot
@@ -0,0 +1,140 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Documentation | Keywords for VLAN tests
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/l2_xconnect.robot
+| Library | resources.libraries.python.L2Util
+| Library | resources.libraries.python.InterfaceUtil
+| Library | resources.libraries.python.NodePath
+
+*** Keywords ***
+
+| Node path computed for 3-node topology
+| | [Arguments] | ${TG} | ${DUT1} | ${DUT2} | ${TG}
+| | [Documentation] | *Create interface variables for 3-node topology.*
+| | ...
+| | ... | *Arguments:*
+| | ... | - ${TG} - Node attached to the path. Type: dictionary
+| | ... | - ${DUT1} - Node attached to the path. Type: dictionary
+| | ... | - ${DUT2} - Node attached to the path. Type: dictionary
+| | ...
+| | ... | _Set testcase variables for nodes and interfaces._
+| | ... | - ${tg} - Variable for node in path. Type: dictionary
+| | ... | - ${dut1} - Variable for node in path. Type: dictionary
+| | ... | - ${dut2} - Variable for node in path. Type: dictionary
+| | ... | - ${tg_if1} - First interface of TG node. Type: str
+| | ... | - ${tg_if2} - Second interface of TG node. Type: str
+| | ... | - ${dut1_if1} - First interface of first DUT node. Type: str
+| | ... | - ${dut1_if2} - Second interface of first DUT node. Type: str
+| | ... | - ${dut2_if1} - First interface of second DUT node. Type: str
+| | ... | - ${dut2_if2} - Second interface of second DUT node. Type: str
+| | ...
+| | Append Nodes | ${TG} | ${DUT1} | ${DUT2} | ${TG}
+| | Compute Path
+| | ${tg_if1} | ${tg}= | Next Interface
+| | ${dut1_if1} | ${dut1}= | Next Interface
+| | ${dut1_if2} | ${dut1}= | Next Interface
+| | ${dut2_if1} | ${dut2}= | Next Interface
+| | ${dut2_if2} | ${dut2}= | Next Interface
+| | ${tg_if2} | ${tg}= | Next Interface
+| | Set Test Variable | ${tg}
+| | Set Test Variable | ${tg_if1}
+| | Set Test Variable | ${tg_if2}
+| | Set Test Variable | ${dut1}
+| | Set Test Variable | ${dut1_if1}
+| | Set Test Variable | ${dut1_if2}
+| | Set Test Variable | ${dut2}
+| | Set Test Variable | ${dut2_if1}
+| | Set Test Variable | ${dut2_if2}
+
+| Interfaces in path are up
+| | [Documentation] | *Set UP state on interfaces in path on nodes.*
+| | ...
+| | Set Interface State | ${tg} | ${tg_if1} | up
+| | Set Interface State | ${tg} | ${tg_if2} | up
+| | Set Interface State | ${dut1} | ${dut1_if1} | up
+| | Set Interface State | ${dut1} | ${dut1_if2} | up
+| | Set Interface State | ${dut2} | ${dut2_if1} | up
+| | Set Interface State | ${dut2} | ${dut2_if2} | up
+| | Vpp Node Interfaces Ready Wait | ${dut1}
+| | Vpp Node Interfaces Ready Wait | ${dut2}
+
+| VLAN subinterfaces initialized on 3-node topology
+| | [Arguments] | ${DUT1} | ${INT1} | ${DUT2} | ${INT2} | ${SUB_ID}
+| | ...         | ${OUTER_VLAN_ID} | ${INNER_VLAN_ID} | ${TYPE_SUBIF}
+| | [Documentation] | *Create two subinterfaces on DUTs.*
+| | ...
+| | ... | *Arguments:*
+| | ... | - ${DUT1} - Node to add sub-interface.
+| | ... | - ${INT1} - Interface name on which create sub-interface.
+| | ... | - ${DUT2} - Node to add sub-interface.
+| | ... | - ${INT2} - Interface name on which create sub-interface.
+| | ... | - ${SUB_ID} - ID of the sub-interface to be created.
+| | ... | - ${OUTER_VLAN_ID} - Outer VLAN ID.
+| | ... | - ${INNER_VLAN_ID} - Inner VLAN ID.
+| | ... | - ${TYPE_SUBIF} - Type of sub-interface.
+| | ...
+| | ... | _Set testcase variables with name and index of created interfaces:_
+| | ... | - ${subif_name_1}
+| | ... | - ${subif_index_1}
+| | ... | - ${subif_name_2}
+| | ... | - ${subif_index_2}
+| | ...
+| | ${subif_name_1} | ${subif_index_1}= | Create subinterface | ${DUT1}
+| | ...                                 | ${INT1} | ${SUB_ID}
+| | ...                                 | ${OUTER_VLAN_ID} | ${INNER_VLAN_ID}
+| | ...                                 | ${TYPE_SUBIF}
+| | ${subif_name_2} | ${subif_index_2}= | Create subinterface | ${DUT2}
+| | ...                                 | ${INT2} | ${SUB_ID}
+| | ...                                 | ${OUTER_VLAN_ID} | ${INNER_VLAN_ID}
+| | ...                                 | ${TYPE_SUBIF}
+| | Set Interface State | ${DUT1} | ${subif_index_1} | up
+| | Set Interface State | ${DUT2} | ${subif_index_2} | up
+| | Set Test Variable | ${subif_name_1}
+| | Set Test Variable | ${subif_index_1}
+| | Set Test Variable | ${subif_name_2}
+| | Set Test Variable | ${subif_index_2}
+
+| L2 tag rewrite pop 2 tags setup on interfaces
+| | [Arguments] | ${DUT1} | ${SUB_INT1} | ${DUT2} | ${SUB_INT2}
+| | ...         | ${TAG_REWRITE_METHOD}
+| | [Documentation] | *Setup tag rewrite on sub-interfaces on DUTs.*
+| | ...
+| | ... | *Arguments:*
+| | ... | - ${DUT1} - Node to rewrite tags.
+| | ... | - ${SUB_INT1} - Interface on which rewrite tags.
+| | ... | - ${DUT2} - Node to rewrite tags.
+| | ... | - ${SUB_INT2} - Interface on which rewrite tags.
+| | ... | - ${TAG_REWRITE_METHOD} - Method of tag rewrite.
+| | ...
+| | L2 tag rewrite | ${DUT1} | ${SUB_INT1} | ${TAG_REWRITE_METHOD}
+| | L2 tag rewrite | ${DUT2} | ${SUB_INT2} | ${TAG_REWRITE_METHOD}
+
+| Interfaces and VLAN sub-interfaces inter-connected using L2-xconnect
+| | [Arguments] | ${DUT1} | ${INT1} | ${SUB_INT1}
+| | ...         | ${DUT2} | ${INT2} | ${SUB_INT2}
+| | [Documentation] | *Add interface and subinterface to bidirectional
+| | ...             | L2-xconnect on DUTs.*
+| | ...
+| | ... | *Arguments:*
+| | ... | - ${DUT1} - Node to add bidirectional cross-connect.
+| | ... | - ${INT1} - Interface to add to the cross-connect.
+| | ... | - ${SUB_INT1} - Sub-interface to add to the cross-connect.
+| | ... | - ${DUT2} - Node to add bidirectional cross-connect.
+| | ... | - ${INT2} - Interface to add to the cross-connect.
+| | ... | - ${SUB_INT2} - Sub-interface to add to the cross-connect.
+| | ...
+| | L2 setup xconnect on DUT | ${DUT1} | ${INT1} | ${SUB_INT1}
+| | L2 setup xconnect on DUT | ${DUT2} | ${INT2} | ${SUB_INT2}
diff --git a/resources/templates/vat/create_sub_interface.vat b/resources/templates/vat/create_sub_interface.vat
new file mode 100644
index 0000000000..4d7da0c0c7
--- /dev/null
+++ b/resources/templates/vat/create_sub_interface.vat
@@ -0,0 +1 @@
+create_subif sw_if_index {sw_if_index} sub_id {sub_id} outer_vlan_id {outer_vlan_id} inner_vlan_id {inner_vlan_id} {type_subif}
\ No newline at end of file
diff --git a/resources/templates/vat/l2_tag_rewrite.vat b/resources/templates/vat/l2_tag_rewrite.vat
new file mode 100644
index 0000000000..efc6e3bb98
--- /dev/null
+++ b/resources/templates/vat/l2_tag_rewrite.vat
@@ -0,0 +1 @@
+l2_interface_vlan_tag_rewrite sw_if_index {sw_if_index} {tag_rewrite_method}
diff --git a/tests/suites/tagging/qinq_l2_xconnect.robot b/tests/suites/tagging/qinq_l2_xconnect.robot
new file mode 100644
index 0000000000..786f870b5a
--- /dev/null
+++ b/tests/suites/tagging/qinq_l2_xconnect.robot
@@ -0,0 +1,49 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/tagging.robot
+| Resource | resources/libraries/robot/l2_traffic.robot
+| Library  | resources.libraries.python.Trace
+| Force Tags | 3_NODE_SINGLE_LINK_TOPO | HW_ENV | VM_ENV
+| Test Setup | Setup all DUTs before test
+| Suite Setup | Setup all TGs before traffic script
+| Test Teardown | Show Packet Trace on All DUTs | ${nodes}
+
+*** Variables ***
+| ${subid}= | 10
+| ${outer_vlan_id}= | 100
+| ${inner_vlan_id}= | 200
+| ${type_subif}= | two_tags
+| ${tag_rewrite_method}= | pop-2
+
+*** Test Cases ***
+| VPP can push and pop two VLAN tags to traffic transfering through xconnect
+| | [Documentation] | Push two tags on DUT 1 to traffic sent from TG,
+| | ...             | pop two tags on DUT 2 from this traffic
+| | ...             | and receive untagged traffic on TG.
+| | ...
+| | Given Node path computed for 3-node topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in path are up
+| | When VLAN subinterfaces initialized on 3-node topology
+| | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
+| | ... | ${outer_vlan_id} | ${inner_vlan_id} | ${type_subif}
+| | And L2 tag rewrite pop 2 tags setup on interfaces
+| | ... | ${dut1} | ${subif_index_1} | ${dut2} | ${subif_index_2}
+| | ... | ${tag_rewrite_method}
+| | And Interfaces and VLAN sub-interfaces inter-connected using L2-xconnect
+| | ... | ${dut1} | ${dut1_if1} | ${subif_index_1}
+| | ... | ${dut2} | ${dut2_if2} | ${subif_index_2}
+| | Then Send and receive ICMPv4 | ${tg} | ${tg_if1} | ${tg_if2}