Add Tests for Honeycomb VxLAN GPE support

JIRA: CSIT-131

- add tests for Honeycomb VxLAN GPE support
- add keywords needed for tests

Change-Id: I460ecd30835bb95140958b20946b1d41ac6d9abc
Signed-off-by: Tibor Frank <tifrank@cisco.com>

8 files changed, 590 insertions, 35 deletions

diff --git a/resources/libraries/python/InterfaceUtil.py b/resources/libraries/python/InterfaceUtil.py
index 35077d8268..a84d595767 100644
--- a/resources/libraries/python/InterfaceUtil.py
+++ b/resources/libraries/python/InterfaceUtil.py
@@ -686,3 +686,53 @@ class InterfaceUtil(object):
                                                     sw_if_index=sw_if_index,
                                                     ip_version=ip_version,
                                                     table_index=table_index)
+
+    @staticmethod
+    def get_sw_if_index(node, interface_name):
+        """Get sw_if_index for the given interface from actual interface dump.
+
+        :param node: VPP node to get interface data from.
+        :param interface_name: Name of the specific interface.
+        :type node: dict
+        :type interface_name: str
+        :return: sw_if_index of the given interface.
+        :rtype: str
+        """
+
+        with VatTerminal(node) as vat:
+            if_data = vat.vat_terminal_exec_cmd_from_template(
+                "interface_dump.vat")
+        for interface in if_data[0]:
+            if interface["interface_name"] == interface_name:
+                return interface["sw_if_index"]
+
+        return None
+
+    @staticmethod
+    def vxlan_gpe_dump(node, interface_name=None):
+        """Get VxLAN GPE data for the given interface.
+
+        :param node: VPP node to get interface data from.
+        :param interface_name: Name of the specific interface. If None,
+        information about all VxLAN GPE interfaces is returned.
+        :type node: dict
+        :type interface_name: str
+        :return: Dictionary containing data for the given VxLAN GPE interface or
+        if interface=None, the list of dictionaries with all VxLAN GPE
+        interfaces.
+        :rtype: dict or list
+        """
+
+        with VatTerminal(node) as vat:
+            vxlan_gpe_data = vat.vat_terminal_exec_cmd_from_template(
+                "vxlan_gpe_dump.vat")
+
+        if interface_name:
+            sw_if_index = InterfaceUtil.get_sw_if_index(node, interface_name)
+            if sw_if_index:
+                for vxlan_gpe in vxlan_gpe_data[0]:
+                    if vxlan_gpe["sw_if_index"] == sw_if_index:
+                        return vxlan_gpe
+            return {}
+
+        return vxlan_gpe_data[0]
diff --git a/resources/libraries/python/honeycomb/HcAPIKwInterfaces.py b/resources/libraries/python/honeycomb/HcAPIKwInterfaces.py
index e8cbc78bea..92b5830847 100644
--- a/resources/libraries/python/honeycomb/HcAPIKwInterfaces.py
+++ b/resources/libraries/python/honeycomb/HcAPIKwInterfaces.py
@@ -35,7 +35,7 @@ class InterfaceKeywords(object):
     """
 
     INTF_PARAMS = ("name", "description", "type", "enabled",
-                   "link-up-down-trap-enable", "v3po:l2")
+                   "link-up-down-trap-enable", "v3po:l2", "v3po:vxlan-gpe")
     IPV4_PARAMS = ("enabled", "forwarding", "mtu")
     IPV6_PARAMS = ("enabled", "forwarding", "mtu", "dup-addr-detect-transmits")
     IPV6_AUTOCONF_PARAMS = ("create-global-addresses",
@@ -63,6 +63,12 @@ class InterfaceKeywords(object):
                        "match-any-inner-id",
                        "exact-match",
                        "default-subif")
+    VXLAN_GPE_PARAMS = ("local",
+                        "remote",
+                        "vni",
+                        "next-protocol",
+                        "encap-vrf-id",
+                        "decap-vrf-id")
 
     def __init__(self):
         pass
@@ -1073,3 +1079,37 @@ class InterfaceKeywords(object):
             if name not in names1 and name not in ignore:
                 raise HoneycombError("Interface {0} not present in list {1}"
                                      .format(name, list1))
+
+    @staticmethod
+    def create_vxlan_gpe_interface(node, interface, **kwargs):
+        """Create a new VxLAN GPE interface.
+
+        :param node: Honeycomb node.
+        :param interface: The name of interface to be created.
+        :param kwargs: Parameters and their values. The accepted parameters are
+        defined in InterfaceKeywords.VXLAN_GPE_PARAMS.
+        :type node: dict
+        :type interface: str
+        :type kwargs: dict
+        :return: Content of response.
+        :rtype: bytearray
+        :raises HoneycombError: If a parameter in kwargs is not valid.
+        """
+
+        new_vxlan_gpe = {
+            "name": interface,
+            "type": "v3po:vxlan-gpe-tunnel",
+            "v3po:vxlan-gpe": {}
+        }
+        for param, value in kwargs.items():
+            if param in InterfaceKeywords.INTF_PARAMS:
+                new_vxlan_gpe[param] = value
+            elif param in InterfaceKeywords.VXLAN_GPE_PARAMS:
+                new_vxlan_gpe["v3po:vxlan-gpe"][param] = value
+            else:
+                raise HoneycombError("The parameter {0} is invalid.".
+                                     format(param))
+        path = ("interfaces", "interface")
+        vxlan_gpe_structure = [new_vxlan_gpe, ]
+        return InterfaceKeywords._set_interface_properties(
+            node, interface, path, vxlan_gpe_structure)
diff --git a/resources/libraries/robot/honeycomb/interfaces.robot b/resources/libraries/robot/honeycomb/interfaces.robot
index a187a107ff..19f4ddac71 100644
--- a/resources/libraries/robot/honeycomb/interfaces.robot
+++ b/resources/libraries/robot/honeycomb/interfaces.robot
@@ -334,3 +334,37 @@
 | | [Arguments] | ${node} | ${interface} | ${mtu} | ${vrf-id}
 | | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
 | | Should be equal | ${vat_data['mtu']} | ${mtu}
+
+| Interface configuration from Honeycomb should be empty
+| | [Documentation] | Attempts to retrieve interface configuration through\
+| | ... | Honeycomb and expects to get empty dictionary.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of a interface on the specified node. Type:\
+| | ... | string
+| | ...
+| | ... | *Example:*
+| | ... | \| Interface configuration from Honeycomb should be empty\
+| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \|
+| | ...
+| | [Arguments] | ${node} | ${interface}
+| | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
+| | Should be empty | ${api_data}
+
+| Interface configuration from VAT should be empty
+| | [Documentation] | Attempts to retrieve Interface configuration through\
+| | ... | VAT and expects to get empty dictionary.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of a Interface on the specified node. Type:\
+| | ... | string
+| | ...
+| | ... | *Example:*
+| | ... | \| Interface configuration from VAT should be empty\
+| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \|
+| | ...
+| | [Arguments] | ${node} | ${interface} |
+| | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
+| | Should be empty | ${vat_data}
diff --git a/resources/libraries/robot/honeycomb/sub_interface.robot b/resources/libraries/robot/honeycomb/sub_interface.robot
index dd68e3f22e..e7f9c8a66b 100644
--- a/resources/libraries/robot/honeycomb/sub_interface.robot
+++ b/resources/libraries/robot/honeycomb/sub_interface.robot
@@ -145,40 +145,6 @@
 | | ... | Should be equal as integers | ${vat_data['sub_default']}
 | | ... | ${sub_settings['default-subif']}
 
-| Sub-interface configuration from Honeycomb should be empty
-| | [Documentation] | Attempts to retrieve sub-interface configuration through\
-| | ... | Honeycomb and expects to get empty dictionary.
-| | ...
-| | ... | *Arguments:*
-| | ... | - node - information about a DUT node. Type: dictionary
-| | ... | - interface - name of a sub-interface on the specified node. Type:\
-| | ... | string
-| | ...
-| | ... | *Example:*
-| | ... | \| Sub-interface configuration from Honeycomb should be empty\
-| | ... | \| ${nodes['DUT1']} \| sub_test \|
-| | ...
-| | [Arguments] | ${node} | ${interface}
-| | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
-| | Should be empty | ${api_data}
-
-| Sub-interface configuration from VAT should be empty
-| | [Documentation] | Attempts to retrieve sub-interface configuration through\
-| | ... | VAT and expects to get empty dictionary.
-| | ...
-| | ... | *Arguments:*
-| | ... | - node - information about a DUT node. Type: dictionary
-| | ... | - interface - name of a sub-interface on the specified node. Type:\
-| | ... | string
-| | ...
-| | ... | *Example:*
-| | ... | \| Sub-interface configuration from VAT should be empty\
-| | ... | \| ${nodes['DUT1']} \| sub_test \|
-| | ...
-| | [Arguments] | ${node} | ${interface} |
-| | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
-| | Should be empty | ${vat_data}
-
 | Honeycomb adds sub-interface to bridge domain
 | | [Documentation] | Honeycomb adds the given sub-interface to bridge domain.
 | | ...
diff --git a/resources/libraries/robot/honeycomb/vxlan_gpe.robot b/resources/libraries/robot/honeycomb/vxlan_gpe.robot
new file mode 100644
index 0000000000..3850eb83fa
--- /dev/null
+++ b/resources/libraries/robot/honeycomb/vxlan_gpe.robot
@@ -0,0 +1,190 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Library | resources.libraries.python.InterfaceUtil
+| ...     | WITH NAME | interfaceCLI
+| Library | resources.libraries.python.honeycomb.HcAPIKwInterfaces.InterfaceKeywords
+| ...     | WITH NAME | InterfaceAPI
+
+*** Variables ***
+# Translation table used to convert values received from Honeycomb to values
+# received from VAT.
+| &{protocols}=
+| ... | -=0
+| ... | ipv4=1
+| ... | ipv6=2
+| ... | ethernet=3
+| ... | nsh=4
+
+*** Keywords ***
+| Honeycomb creates VxLAN GPE interface
+| | [Documentation] | Uses Honeycomb API to configure a VxLAN tunnel.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface to be created. Type: string
+| | ... | - base_settings - configuration data common for all interfaces.\
+| | ... | Type: dictionary
+| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ... | \| Honeycomb creates VxLAN GPE interface \
+| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${base_params} \
+| | ... | \| ${vxlan_gpe_params} \|
+| | ...
+| | [Arguments] | ${node} | ${interface}
+| | ... | ${base_settings} | ${vxlan_gpe_settings}
+| | ...
+| | interfaceAPI.Create VxLAN GPE interface
+| | ... | ${node} | ${interface} | &{base_settings} | &{vxlan_gpe_settings}
+
+| Honeycomb removes VxLAN GPE interface
+| | [Documentation] | Uses Honeycomb API to remove VxLAN GPE interface from\
+| | ... | node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of the interface to be removed. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Honeycomb removes VxLAN GPE interface \
+| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \|
+| | ...
+| | [Arguments] | ${node} | ${interface}
+| | ...
+| | interfaceAPI.Delete interface | ${node} | ${interface}
+
+| VxLAN GPE configuration from Honeycomb should be
+| | [Documentation] | Uses Honeycomb API to get operational data about the\
+| | ... | given interface and compares them to the values provided as arguments.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface to be checked. Type: string
+| | ... | - base_settings - configuration data common for all interfaces.\
+| | ... | Type: dictionary
+| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ... | \| VxLAN GPE configuration from Honeycomb should be \
+| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${base_params} \
+| | ... | \| ${vxlan_gpe_params} \|
+| | ...
+| | [Arguments] | ${node} | ${interface}
+| | ... | ${base_settings} | ${vxlan_gpe_settings}
+| | ...
+| | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
+| | Should be equal as strings
+| | ... | ${api_data['name']} | ${base_settings['name']}
+| | Should be equal as strings
+| | ... | ${api_data['type']} | v3po:vxlan-gpe-tunnel
+| | Run keyword if | '${base_settings['enabled']}' == 'true'
+| | ... | Run keywords
+| | ... | Should be equal as strings | ${api_data['admin-status']} | up
+| | ... | AND
+| | ... | Should be equal as strings | ${api_data['oper-status']} | up
+| | ... | ELSE
+| | ... | Run keywords
+| | ... | Should be equal as strings | ${api_data['admin-status']} | down
+| | ... | AND
+| | ... | Should be equal as strings | ${api_data['oper-status']} | down
+
+| VxLAN GPE configuration from VAT should be
+| | [Documentation] | Uses VAT to get operational data about the given\
+| | ... | interface and compares them to the values provided as arguments.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface to be checked. Type: string
+| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ... | \| VxLAN GPE configuration from VAT should be \
+| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${vxlan_gpe_params} \|
+| | ...
+| | [Arguments] | ${node} | ${interface} | ${vxlan_gpe_params}
+| | ...
+| | ${vat_data}= | VxLAN GPE Dump | ${node} | ${interface}
+| | Should be equal as strings
+| | ... | ${vat_data['local']} | ${vxlan_gpe_params['local']}
+| | Should be equal as strings
+| | ... | ${vat_data['remote']} | ${vxlan_gpe_params['remote']}
+| | Should be equal as strings
+| | ... | ${vat_data['vni']} | ${vxlan_gpe_params['vni']}
+| | Should be equal as strings
+| | ... | ${vat_data['encap_vrf_id']} | ${vxlan_gpe_params['encap-vrf-id']}
+| | Should be equal as strings
+| | ... | ${vat_data['decap_vrf_id']} | ${vxlan_gpe_params['decap-vrf-id']}
+| | Should be equal as strings | ${vat_data['protocol']}
+| | ... | ${protocols['${vxlan_gpe_params['next-protocol']}']}
+
+| Interface indices should be the same from Honeycomb and VAT
+| | [Documentation] | Uses VAT and Honeycomb to get operational data about the\
+| | ... | given interface and compares the interface indexes.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of the interface to be checked. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Interface indices should be the same from Honeycomb and VAT \
+| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \|
+| | ...
+| | [Arguments] | ${node} | ${interface}
+| | ...
+| | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
+| | ${vat_data}= | VxLAN GPE Dump | ${node} | ${interface}
+| | Should be equal as strings
+| | ... | ${api_data['if-index']} | ${vat_data['sw_if_index']}
+
+| VxLAN GPE configuration from VAT should be empty
+| | [Documentation] | Uses VAT to get operational data about the given\
+| | ... | interface and expects empty dictionary.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ... | \| VxLAN GPE configuration from VAT should be empty\
+| | ... | \| ${nodes['DUT1']} \|
+| | ...
+| | [Arguments] | ${node}
+| | ...
+| | Run Keyword And Expect Error | ValueError: No JSON object could be decoded
+| | ... | VxLAN Dump | ${node}
+
+| Honeycomb fails to create VxLAN GPE interface
+| | [Documentation] | Uses Honeycomb API to configure a VxLAN tunnel with wrong\
+| | ... | configuration data.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - information about a DUT node. Type: dictionary
+| | ... | - interface - name of an interface to be created. Type: string
+| | ... | - base_settings - Configuration data common for all interfaces.\
+| | ... | Type: dictionary
+| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
+| | ...
+| | ... | *Example:*
+| | ... | \| Honeycomb fails to create VxLAN GPE interface \
+| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${wrong_base_params} \
+| | ... | \| ${vxlan_gpe_params} \|
+| | ...
+| | [Arguments] | ${node} | ${interface}
+| | ... | ${base_settings} | ${vxlan_gpe_settings}
+| | ...
+| | Run keyword and expect error | *HoneycombError*not successful. * code: *00.
+| | ... | interfaceAPI.Create VxLAN GPE interface
+| | ... | ${node} | ${interface} | &{base_settings} | &{vxlan_gpe_settings}
diff --git a/resources/templates/vat/vxlan_gpe_dump.vat b/resources/templates/vat/vxlan_gpe_dump.vat
new file mode 100644
index 0000000000..e82d94cf14
--- /dev/null
+++ b/resources/templates/vat/vxlan_gpe_dump.vat
@@ -0,0 +1 @@
+vxlan_gpe_tunnel_dump
\ No newline at end of file
diff --git a/tests/suites/honeycomb/8 - vxlan_gpe.robot b/tests/suites/honeycomb/8 - vxlan_gpe.robot
new file mode 100644
index 0000000000..43d6b4bc04
--- /dev/null
+++ b/tests/suites/honeycomb/8 - vxlan_gpe.robot
@@ -0,0 +1,175 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Variables ***
+# Node and interfaces to run tests on.
+| ${node}= | ${nodes['DUT1']}
+| ${interface}= | ${node['interfaces']['port1']['name']}
+
+# Parameters to be set on existing interface
+| ${vxlan_gpe_existing_if}= | ${interface}
+| &{vxlan_gpe_base_wrong_interface_settings}=
+| ... | name=${vxlan_gpe_existing_if}
+| ... | type=iana-if-type:ethernetCsmacd
+| ... | description=for testing purposes
+| ... | enabled=true
+| ... | link-up-down-trap-enable=enabled
+| &{vxlan_gpe_wrong_interface_settings}=
+| ... | local=192.168.50.77
+| ... | remote=192.168.50.72
+| ... | vni=${9}
+| ... | next-protocol=wrong_ipv4
+| ... | encap-vrf-id=${0}
+| ... | decap-vrf-id=${0}
+
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/honeycomb/interfaces.robot
+| Resource | resources/libraries/robot/honeycomb/vxlan_gpe.robot
+# Import additional VxLAN GPE settings from resource file
+| Variables | tests/suites/honeycomb/resources/vxlan_gpe.py
+| Documentation | *Honeycomb VxLAN-GPE management test suite.*
+| Force Tags | honeycomb_sanity
+
+*** Test Cases ***
+| Honeycomb creates VxLAN GPE tunnel
+| | [Documentation] | Check if Honeycomb API can configure VxLAN GPE tunnel.
+| | ...
+| | Given interface configuration from Honeycomb should be empty
+| | ... | ${node} | ${vxlan_gpe_if1}
+| | And interface configuration from VAT should be empty
+| | ... | ${node} | ${vxlan_gpe_if1}
+| | When Honeycomb creates VxLAN GPE interface
+| | ... | ${node} | ${vxlan_gpe_if1}
+| | ... | ${vxlan_gpe_base_settings} | ${vxlan_gpe_settings}
+| | Then run keyword and continue on failure
+| | ... | VxLAN GPE configuration from Honeycomb should be
+| | ... | ${node} | ${vxlan_gpe_if1}
+| | ... | ${vxlan_gpe_base_settings} | ${vxlan_gpe_settings}
+| | And run keyword and continue on failure
+| | ... | VxLAN GPE configuration from VAT should be
+| | ... | ${node} | ${vxlan_gpe_if1} | ${vxlan_gpe_settings}
+| | And run keyword and continue on failure
+| | ... | Interface indices should be the same from Honeycomb and VAT
+| | ... | ${node} | ${vxlan_gpe_if1}
+
+| Honeycomb removes VxLAN GPE tunnel
+| | [Documentation] | Check if Honeycomb API can remove VxLAN GPE tunnel.
+| | ...
+# Disabled beacuse of bug in Honeycomb.
+# TODO: Enable when fixed.
+#| | Given VxLAN GPE configuration from Honeycomb should be
+#| | ... | ${node} | ${vxlan_gpe_if1}
+#| | ... | ${vxlan_gpe_base_settings} | ${vxlan_gpe_settings}
+#| | And VxLAN GPE configuration from VAT should be
+#| | ... | ${node} | ${vxlan_gpe_if1} | ${vxlan_gpe_settings}
+| | When Honeycomb removes VxLAN GPE interface
+| | ... | ${node} | ${vxlan_gpe_if1}
+| | Then VxLAN GPE configuration from VAT should be empty
+| | ... | ${node}
+| | And VxLAN GPE configuration from Honeycomb should be
+| | ... | ${node} | ${vxlan_gpe_if1}
+| | ... | ${vxlan_gpe_disabled_base_settings} | ${vxlan_gpe_settings}
+
+| Honeycomb sets wrong interface type while creating VxLAN GPE tunnel
+| | [Documentation] | Check if Honeycomb refuses to create a VxLAN GPE tunnel\
+| | ... | with a wrong interface type set.
+| | ...
+| | Given interface configuration from Honeycomb should be empty
+| | ... | ${node} | ${vxlan_gpe_if2}
+| | And interface configuration from VAT should be empty
+| | ... | ${node} | ${vxlan_gpe_if2}
+| | When Honeycomb fails to create VxLAN GPE interface
+| | ... | ${node} | ${vxlan_gpe_if2}
+| | ... | ${vxlan_gpe_wrong_type_base_settings} | ${vxlan_gpe_settings}
+| | Then interface configuration from Honeycomb should be empty
+| | ... | ${node} | ${vxlan_gpe_if2}
+| | And interface configuration from VAT should be empty
+| | ... | ${node} | ${vxlan_gpe_if2}
+
+| Honeycomb sets wrong protocol while creating VxLAN GPE tunnel
+| | [Documentation] | Check if Honeycomb refuses to create a VxLAN GPE tunnel\
+| | ... | with a wrong next-protocol set.
+| | ...
+| | Given interface configuration from Honeycomb should be empty
+| | ... | ${node} | ${vxlan_gpe_if3}
+| | And interface configuration from VAT should be empty
+| | ... | ${node} | ${vxlan_gpe_if3}
+| | When Honeycomb fails to create VxLAN GPE interface
+| | ... | ${node} | ${vxlan_gpe_if3}
+| | ... | ${vxlan_gpe_wrong_protocol_base_settings}
+| | ... | ${vxlan_gpe_wrong_protocol_settings}
+| | Then interface configuration from Honeycomb should be empty
+| | ... | ${node} | ${vxlan_gpe_if3}
+| | And interface configuration from VAT should be empty
+| | ... | ${node} | ${vxlan_gpe_if3}
+
+| Honeycomb sets VxLAN GPE tunnel on existing interface with wrong type
+| | [Documentation] | Check if Honeycomb refuses to create a VxLAN GPE tunnel\
+| | ... | on existing interface with wrong type.
+| | ...
+| | Given VxLAN GPE configuration from VAT should be empty
+| | ... | ${node}
+| | When Honeycomb fails to create VxLAN GPE interface
+| | ... | ${node} | ${vxlan_gpe_existing_if}
+| | ... | ${vxlan_gpe_base_wrong_interface_settings}
+| | ... | ${vxlan_gpe_wrong_interface_settings}
+| | Then VxLAN GPE configuration from VAT should be empty
+| | ... | ${node}
+
+| Honeycomb creates VxLAN GPE tunnel with ipv6
+| | [Documentation] | Check if Honeycomb API can configure VxLAN GPE tunnel\
+| | ... | with IPv6 addresses.
+| | ...
+| | Given VxLAN GPE configuration from VAT should be empty
+| | ... | ${node}
+# Disabled beacuse of bug in Honeycomb
+# TODO: Enable when fixed.
+#| | And VxLAN GPE configuration from Honeycomb should be
+#| | ... | ${node} | ${vxlan_gpe_if5}
+#| | ... | ${vxlan_gpe_disabled_base_settings} | ${vxlan_gpe_settings}
+| | When Honeycomb creates VxLAN GPE interface
+| | ... | ${node} | ${vxlan_gpe_if5}
+| | ... | ${vxlan_gpe_base_ipv6_settings} | ${vxlan_gpe_ipv6_settings}
+| | Then run keyword and continue on failure
+| | ... | VxLAN GPE configuration from Honeycomb should be
+| | ... | ${node} | ${vxlan_gpe_if5}
+| | ... | ${vxlan_gpe_base_ipv6_settings} | ${vxlan_gpe_ipv6_settings}
+| | And run keyword and continue on failure
+| | ... | VxLAN GPE configuration from VAT should be
+| | ... | ${node} | ${vxlan_gpe_if5} | ${vxlan_gpe_ipv6_settings}
+| | And run keyword and continue on failure
+| | ... | Interface indices should be the same from Honeycomb and VAT
+| | ... | ${node} | ${vxlan_gpe_if5}
+
+| Honeycomb creates the second VxLAN GPE tunnel with ipv6
+| | [Documentation] | Check if Honeycomb API can configure another one VxLAN\
+| | ... | GPE tunnel with IPv6 addresses.
+| | ...
+| | Given interface configuration from Honeycomb should be empty
+| | ... | ${node} | ${vxlan_gpe_if6}
+| | And interface configuration from VAT should be empty
+| | ... | ${node} | ${vxlan_gpe_if6}
+| | When Honeycomb creates VxLAN GPE interface
+| | ... | ${node} | ${vxlan_gpe_if6}
+| | ... | ${vxlan_gpe_base_ipv6_settings2} | ${vxlan_gpe_ipv6_settings2}
+| | Then run keyword and continue on failure
+| | ... | VxLAN GPE configuration from Honeycomb should be
+| | ... | ${node} | ${vxlan_gpe_if6}
+| | ... | ${vxlan_gpe_base_ipv6_settings2} | ${vxlan_gpe_ipv6_settings2}
+| | And run keyword and continue on failure
+| | ... | VxLAN GPE configuration from VAT should be
+| | ... | ${node} | ${vxlan_gpe_if6} | ${vxlan_gpe_ipv6_settings2}
+| | And run keyword and continue on failure
+| | ... | Interface indices should be the same from Honeycomb and VAT
+| | ... | ${node} | ${vxlan_gpe_if6}
diff --git a/tests/suites/honeycomb/resources/vxlan_gpe.py b/tests/suites/honeycomb/resources/vxlan_gpe.py
new file mode 100644
index 0000000000..7f219f93b6
--- /dev/null
+++ b/tests/suites/honeycomb/resources/vxlan_gpe.py
@@ -0,0 +1,99 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Test variables for Honeycomb VxLAN GPE management test suite."""
+
+# The first VxLAN GPE Interface used in tests.
+vxlan_gpe_if1 = 'vxlan_gpe_tunnel0'
+vxlan_gpe_base_settings = {
+    'name': vxlan_gpe_if1,
+    'description': 'for testing purposes',
+    'enabled': True,
+    'link-up-down-trap-enable': 'enabled'
+}
+vxlan_gpe_settings = {
+    'local': '192.168.50.76',
+    'remote': '192.168.50.71',
+    'vni': 9,
+    'next-protocol': 'ipv4',
+    'encap-vrf-id': 0,
+    'decap-vrf-id': 0
+}
+
+# The values of parameters of disabled VxLAN GPE interface.
+vxlan_gpe_disabled_base_settings = {
+    'name': vxlan_gpe_if1,
+    'description': 'for testing purposes',
+    'enabled': 'false'
+}
+
+# Wrong interface type.
+vxlan_gpe_if2 = 'vxlan_gpe_tunnel1'
+vxlan_gpe_wrong_type_base_settings = {
+    'name': vxlan_gpe_if2,
+    'type': 'iana-if-type:ethernetCsmacd',
+    'description': 'for testing purposes',
+    'enabled': 'true',
+    'link-up-down-trap-enable': 'enabled'
+}
+
+# Wrong next-protocol value.
+vxlan_gpe_if3 = 'vxlan_gpe_tunnel1'
+vxlan_gpe_wrong_protocol_base_settings = {
+    'name': vxlan_gpe_if3,
+    'description': 'for testing purposes',
+    'enabled': 'true',
+    'link-up-down-trap-enable': 'enabled'
+}
+vxlan_gpe_wrong_protocol_settings = {
+    'local': '192.168.50.77',
+    'remote': '192.168.50.72',
+    'vni': 9,
+    'next-protocol': 'wrong_ipv4',
+    'encap-vrf-id': 0,
+    'decap-vrf-id': 0
+}
+
+# The first IPv6 VxLAN GPE interface.
+vxlan_gpe_if5 = 'vxlan_gpe_tunnel0'
+vxlan_gpe_base_ipv6_settings = {
+    'name': vxlan_gpe_if5,
+    'description': 'for testing purposes',
+    'enabled': 'true',
+    'link-up-down-trap-enable': 'enabled'
+}
+vxlan_gpe_ipv6_settings = {
+    'local': '10:10:10:10:10:10:10:10',
+    'remote': '10:10:10:10:10:10:10:11',
+    'vni': 9,
+    'next-protocol':'ipv4',
+    'encap-vrf-id': 0,
+    'decap-vrf-id': 0
+}
+
+# The second IPv6 VxLAN GPE interface.
+vxlan_gpe_if6 = 'vxlan_gpe_tunnel1'
+vxlan_gpe_base_ipv6_settings2 = {
+    'name': vxlan_gpe_if6,
+    'description': 'for testing purposes',
+    'enabled': 'true',
+    'link-up-down-trap-enable': 'enabled'
+}
+vxlan_gpe_ipv6_settings2 = {
+    'local': '10:10:10:10:10:10:10:20',
+    'remote': '10:10:10:10:10:10:10:21',
+    'vni': 9,
+    'next-protocol': 'ipv4',
+    'encap-vrf-id': 0,
+    'decap-vrf-id': 0
+}