VTS VXLAN vhost-user with single DUT, TG sends VXLAN

Change-Id: I63539af2cdbdbd02a67068e48d0fdf2743da3b1e
Signed-off-by: Peter Ginchev <pginchev@cisco.com>

4 files changed, 557 insertions, 0 deletions

diff --git a/resources/libraries/robot/performance/performance_configuration.robot b/resources/libraries/robot/performance/performance_configuration.robot
index c2f591ad0c..21826a2160 100644
--- a/resources/libraries/robot/performance/performance_configuration.robot
+++ b/resources/libraries/robot/performance/performance_configuration.robot
@@ -1482,6 +1482,75 @@
 | | Add interface to bridge domain | ${dut2} | ${vhost_if2} | ${bd_id2}
 | | Add interface to bridge domain | ${dut2} | ${dut2_if2} | ${bd_id2}
 
+| Init L2 bridge domains with single DUT with Vhost-User and VXLANoIPv4 in 3-node circular topology
+| | [Documentation]
+| | ... | Create two Vhost-User interfaces on one VPP node. Add each
+| | ... | Vhost-User interface into L2 bridge domains with learning enabled
+| | ... | one connected to physical interface, the other to VXLAN.
+| | ... | Setup VXLANoIPv4 between DUTs and TG by connecting physical and vxlan
+| | ... | interfaces on the DUT. All interfaces are brought up.
+| | ... | IPv4 addresses with prefix /24 are configured on interfaces between
+| | ... | DUT and TG.
+| | ...
+| | ... | *Arguments:*
+| | ... | - dut1_address - Address of physical interface on DUT1. Type: string
+| | ... | - dut1_address_subnet - Subnet of the address of physical interface on
+| | ... |                         DUT1. Type: string
+| | ... | - dut2_address - Address of physical interface on DUT2. Type: string
+| | ... | - dut2_address_subnet - Subnet of the address of physical interface on
+| | ... |                         DUT2. Type: string
+| | ... | - dut1_gw - Address of the _gateway_ to which the traffic will be
+| | ... |             forwarded on DUT1. Type: string
+| | ... | - dut2_gw - Address of the _gateway_ to which the traffic will be
+| | ... |             forwarded on DUT2. Type: string
+| | ... | - dut1_vxlans - List of VXLAN params to be configured on DUT1.
+| | ... |                 Type: list of dicts, dict params vni, vtep
+| | ... | - dut2_vxlans - List of VXLAN params to be configured on DUT2.
+| | ... |                 Type: list of dicts, dict params vni, vtep
+| | ... | - dut1_route_subnet - Subnet address to forward to  _gateway_ on DUT1.
+| | ... |                       Type: string
+| | ... | - dut1_route_mask - Subnet address mask to forward to  _gateway_
+| | ... |                     on DUT1. Type: string
+| | ... | - dut2_route_subnet - Subnet address to forward to  _gateway_ on DUT2.
+| | ... |                       Type: string
+| | ... | - dut2_route_mask - Subnet address mask to forward to  _gateway_
+| | ... |                     on DUT2. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | [Arguments] | ${dut1_address} | ${dut1_address_subnet} |
+| | ... | ${dut2_address} | ${dut2_address_subnet} | ${dut1_gw} | ${dut2_gw} |
+| | ... | ${dut1_vxlans} | ${dut2_vxlans} | ${dut1_route_subnet} |
+| | ... | ${dut1_route_mask} | ${dut2_route_subnet} | ${dut2_route_mask}
+| | ...
+| | Configure IP addresses on interfaces | ${dut1} | ${dut1_if1} |
+| | ... | ${dut1_address} | ${dut1_address_subnet}
+| | Configure IP addresses on interfaces | ${dut2} | ${dut2_if2} |
+| | ... | ${dut2_address} | ${dut2_address_subnet}
+| | ${dut1_bd_id1}= | Set Variable | 1
+| | ${dut1_bd_id2}= | Set Variable | 2
+| | ${dut2_bd_id1}= | Set Variable | 1
+| | :FOR | ${vxlan} | IN | @{dut1_vxlans}
+| | | ${dut1s_vxlan}= | Create VXLAN interface | ${dut1} | ${vxlan.vni}
+| | | ... | ${dut1_address} | ${vxlan.vtep}
+| | | Add interface to bridge domain | ${dut1} | ${dut1s_vxlan} | ${dut1_bd_id1}
+| | :FOR | ${vxlan} | IN | @{dut2_vxlans}
+| | | ${dut2s_vxlan}= | Create VXLAN interface | ${dut2} | ${vxlan.vni}
+| | | ... | ${dut2_address} | ${vxlan.vtep}
+| | | Add interface to bridge domain | ${dut2} | ${dut2s_vxlan} | ${dut2_bd_id1}
+| | ${tg_if1_mac}= | Get Interface MAC | ${tg} | ${tg_if1}
+| | ${tg_if2_mac}= | Get Interface MAC | ${tg} | ${tg_if2}
+| | Add arp on dut | ${dut1} | ${dut1_if1} | ${dut1_gw} | ${tg_if1_mac}
+| | Add arp on dut | ${dut2} | ${dut2_if2} | ${dut2_gw} | ${tg_if2_mac}
+| | Vpp Route Add | ${dut1} | ${dut1_route_subnet} | ${dut1_route_mask}
+| | ... | ${dut1_gw} | ${dut1_if1}
+| | Vpp Route Add | ${dut2} | ${dut2_route_subnet} | ${dut2_route_mask}
+| | ... | ${dut2_gw} | ${dut2_if2}
+| | Add interface to bridge domain | ${dut1} | ${dut1_if2} | ${dut1_bd_id2}
+| | Add interface to bridge domain | ${dut2} | ${dut2_if1} | ${dut2_bd_id1}
+| | Add interface to bridge domain | ${dut1} | ${vhost_if1} | ${dut1_bd_id1}
+| | Add interface to bridge domain | ${dut1} | ${vhost_if2} | ${dut1_bd_id2}
+
 | Initialize L2 bridge domains with Vhost-User in 2-node circular topology
 | | [Documentation]
 | | ... | Create two Vhost-User interfaces on all defined VPP nodes. Add each
diff --git a/resources/libraries/robot/performance/performance_setup.robot b/resources/libraries/robot/performance/performance_setup.robot
index f4e07b1103..adcdb2173d 100644
--- a/resources/libraries/robot/performance/performance_setup.robot
+++ b/resources/libraries/robot/performance/performance_setup.robot
@@ -636,6 +636,31 @@
 | | Run keyword unless | ${dut2_node}==${None}
 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 
+| Tear down performance test with vhost and VM with dpdk-testpmd and ACL
+| | [Documentation] | Common test teardown for performance tests which use
+| | ... | vhost(s) and VM(s) with ACL and dpdk-testpmd.
+| | ...
+| | ... | *Arguments:*
+| | ... | - rate - Rate for sending packets. Type: string
+| | ... | - framesize - L2 Frame Size [B]. Type: integer
+| | ... | - topology_type - Topology type. Type: string
+| | ... | - dut1_node - Node where to clean qemu. Type: dictionary
+| | ... | - dut1_vm_refs - VM references on node. Type: dictionary
+| | ... | - dut2_node - Node where to clean qemu. Type: dictionary
+| | ... | - dut2_vm_refs - VM references on node. Type: dictionary
+| | ...
+| | [Arguments] | ${rate} | ${framesize} | ${topology_type}
+| | ... | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
+| | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
+| | ...
+| | Tear down performance test with vhost and VM with dpdk-testpmd
+| | ... | ${rate} | ${framesize} | ${topology_type}
+| | ... | ${dut1_node} | ${dut1_vm_refs}
+| | ... | ${dut2_node} | ${dut2_vm_refs}
+| | Vpp Log Plugin Acl Settings | ${dut1}
+| | Run Keyword If Test Failed | Run Keyword And Ignore Error
+| | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
+
 | Tear down performance pdrchk test with vhost and VM with dpdk-testpmd
 | | [Documentation] | Common test teardown for performance pdrchk tests which \
 | | ... | use vhost(s) and VM(s) with dpdk-testpmd.
diff --git a/resources/traffic_profiles/trex/trex-sl-ethip4-vxlansrc253.py b/resources/traffic_profiles/trex/trex-sl-ethip4-vxlansrc253.py
new file mode 100644
index 0000000000..1018c13c53
--- /dev/null
+++ b/resources/traffic_profiles/trex/trex-sl-ethip4-vxlansrc253.py
@@ -0,0 +1,134 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Stream profile for T-rex traffic generator.
+
+Stream profile:
+ - Two streams sent in directions 0 --> 1 and 1 --> 0 at the same time.
+ - Packet: ETH / IP / VXLAN / ETH / IP
+ - Direction 0 --> 1:
+   - Source IP address:                172.17.0.2
+   - Destination IP address:           172.16.0.1
+   - VXLAN VNI:                        24
+   - Payload source MAC address:       00:de:ad:00:00:00
+   - Payload source IP address:        10.0.0.2
+   - Payload destination MAC address:  00:de:ad:00:00:01
+   - Payload destination IP address:   10.0.0.1
+ - Direction 1 --> 0:
+   - Source IP address:                172.27.0.2
+   - Destination IP address:           172.26.0.1
+   - VXLAN VNI:                        24
+   - Payload source MAC address:       00:de:ad:00:00:01
+   - Payload source IP address:        10.0.0.1
+   - Payload destination MAC address:  00:de:ad:00:00:00
+   - Payload destination IP address:   10.0.0.2
+
+"""
+
+from trex_stl_lib.api import *
+from profile_trex_stateless_base_class import TrafficStreamsBaseClass
+
+# RFC 7348 - Virtual eXtensible Local Area Network (VXLAN):
+# A Framework for Overlaying Virtualized Layer 2 Networks over Layer 3 Networks
+# http://tools.ietf.org/html/rfc7348
+_VXLAN_FLAGS = list('R'*24 + "RRRIRRRRR")
+
+
+class VXLAN(Packet):
+    name = "VXLAN"
+    fields_desc = [FlagsField("flags", 0x08000000, 32, _VXLAN_FLAGS),
+                   ThreeBytesField("vni", 0),
+                   XByteField("reserved", 0x00)]
+
+    def mysummary(self):
+        return self.sprintf("VXLAN (vni=%VXLAN.vni%)")
+
+
+bind_layers(UDP, VXLAN, dport=4789)
+bind_layers(VXLAN, Ether)
+
+
+class TrafficStreams(TrafficStreamsBaseClass):
+    """Stream profile."""
+
+    def __init__(self):
+        """Initialization and setting of streams' parameters."""
+
+        super(TrafficStreamsBaseClass, self).__init__()
+
+    def define_packets(self):
+        """Defines the packets to be sent from the traffic generator.
+
+        Packet definition: | ETH | IP |
+
+        :returns: Packets to be sent from the traffic generator.
+        :rtype: tuple
+        """
+
+        # Direction 0 --> 1
+        base_pkt_a = (
+            Ether()/
+            IP(src="172.17.0.2",dst="172.16.0.1")/
+            UDP(sport=1337,dport=4789)/
+            VXLAN(vni=24)/
+            Ether(src="00:de:ad:00:00:00",dst="00:de:ad:00:00:01")/
+            IP(src="10.0.0.2",dst="10.0.0.1"))
+
+        # Direction 1 --> 0
+        base_pkt_b = (
+            Ether()/
+            IP(src="172.27.0.2",dst="172.26.0.1")/
+            UDP(sport=1337,dport=4789)/
+            VXLAN(vni=24)/
+            Ether(src="00:de:ad:00:00:01",dst="00:de:ad:00:00:00")/
+            IP(src="10.0.0.1",dst="10.0.0.2"))
+
+
+        # Direction 0 --> 1
+        vm1 = STLScVmRaw([
+            STLVmFlowVar(name="src", min_value="172.17.0.2" ,
+                         max_value="172.17.0.254", size=4, op="inc"),
+            STLVmFlowVar(name="src_mac", min_value=2 , max_value=3100,
+                         size=2, op="inc"),
+            STLVmWrFlowVar(fv_name="src", pkt_offset="IP.src"),
+            STLVmWrFlowVar(fv_name="src_mac", pkt_offset=60),
+            STLVmFixIpv4(offset = "IP")
+        ])
+
+        # Direction 1 --> 0
+        vm2 = STLScVmRaw([
+            STLVmFlowVar(name="src", min_value="172.27.0.2" ,
+                         max_value="172.27.0.254", size=4, op="inc"),
+            STLVmFlowVar(name="src_mac", min_value=2 , max_value=3100,
+                         size=2, op="inc"),
+            STLVmWrFlowVar(fv_name="src", pkt_offset="IP.src"),
+            STLVmWrFlowVar(fv_name="src_mac", pkt_offset=60),
+            STLVmFixIpv4(offset = "IP")
+        ])
+
+        # for now there's a single VXLAN tunnel per direction, the above
+        # variations are for reference only
+        vm1, vm2 = [], []
+
+        return base_pkt_a, base_pkt_b, vm1, vm2
+
+def register():
+    """Register this traffic profile to T-rex.
+
+    Do not change this function.
+
+    :return: Traffic streams.
+    :rtype: Object
+    """
+    return TrafficStreams()
+
diff --git a/tests/vpp/perf/vts/10ge2p1x520-ethip4vxlan-l2bdbasemaclrn-eth-iacldstbase-2vhostvr1024-1vm-ndrpdrdisc.robot b/tests/vpp/perf/vts/10ge2p1x520-ethip4vxlan-l2bdbasemaclrn-eth-iacldstbase-2vhostvr1024-1vm-ndrpdrdisc.robot
new file mode 100644
index 0000000000..95cbbdfb4d
--- /dev/null
+++ b/tests/vpp/perf/vts/10ge2p1x520-ethip4vxlan-l2bdbasemaclrn-eth-iacldstbase-2vhostvr1024-1vm-ndrpdrdisc.robot
@@ -0,0 +1,329 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/performance/performance_setup.robot
+| Library | resources.libraries.python.QemuUtils
+| Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDRDISC
+| ... | NIC_Intel-X520-DA2 | L2BDMACLRN | ENCAP | VXLAN | L2OVRLAY | IP4UNRLAY
+| ... | VHOST | VM | VHOST_1024 | VTS
+| ...
+| Suite Setup | Run Keywords
+| ... | Set up 3-node performance topology with DUT's NIC model
+| ... | L3 | Intel-X520-DA2
+| ... | AND | Set up performance test suite with ACL
+| Suite Teardown | Tear down 3-node performance topology
+| ...
+| Test Setup | Set up performance test
+| Test Teardown | Tear down performance test with vhost and VM with dpdk-testpmd and ACL
+| ... | ${min_rate}pps | ${framesize} | ${traffic_profile}
+| ... | dut1_node=${dut1} | dut1_vm_refs=${dut1_vm_refs}
+| ...
+| Documentation | *RFC2544: Packet throughput L2BD test cases with VXLANoIPv4
+| ... | and vhost*
+| ...
+| ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
+| ... | with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
+| ... | Eth-IPv4-VXLAN-Eth-IPv4 is applied on link between DUT1 and DUT2.
+| ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2 bridge-
+| ... | domain and MAC learning enabled. Qemu Guest is connected to VPP via
+| ... | vhost-user interfaces. Guest is running DPDK testpmd interconnecting
+| ... | vhost-user interfaces using 5 cores pinned to cpus 5-9 and 2048M
+| ... | memory. Testpmd is using socket-mem=1024M (512x2M hugepages), 5 cores
+| ... | (1 main core and 4 cores dedicated for io), forwarding mode is set to
+| ... | io, rxd/txd=256, burst=64. DUT1, DUT2 are tested with 2p10GE NIC X520
+| ... | Niantic by Intel.
+| ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
+| ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
+| ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
+| ... | of packets transmitted. NDR and PDR are discovered for different
+| ... | Ethernet L2 frame sizes using either binary search or linear search
+| ... | algorithms with configured starting rate and final step that determines
+| ... | throughput measurement resolution. Test packets are generated by TG on
+| ... | links to DUTs. TG traffic profile contains two L3 flow-groups
+| ... | (flow-group per direction, 253 flows per flow-group) with all packets
+| ... | containing Ethernet header, IPv4 header with IP protocol=61 and static
+| ... | payload. MAC addresses are matching MAC addresses of the TG node
+| ... | interfaces.
+| ... | *[Ref] Applicable standard specifications:* RFC2544, RFC7348.
+
+*** Variables ***
+| ${perf_qemu_qsz}= | 1024
+# X520-DA2 bandwidth limit
+| ${s_limit}= | ${10000000000}
+| ${vxlan_overhead}= | ${50}
+# Socket names
+| ${dut1_bd_id1}= | 1
+| ${dut1_bd_id2}= | 2
+| ${dut2_bd_id1}= | 1
+| ${sock1}= | /tmp/sock-1-${dut1_bd_id1}
+| ${sock2}= | /tmp/sock-1-${dut1_bd_id2}
+# Traffic profile:
+| ${traffic_profile} | trex-sl-ethip4-vxlansrc253
+| ${min_rate}= | ${10000}
+
+
+*** Keywords ***
+| Configure ACLs on a single interface
+| | [Documentation]
+| | ... | Configure ACL
+| | ...
+| | ... | *Arguments:*
+| | ... | - dut - DUT node. Type: string
+| | ... | - dut_if - DUT node interface name. Type: string
+| | ... | - acl_apply_type - To what path apply the ACL - input or output.
+| | ... | - acl_action - Action for the rule - deny, permit, permit+reflect.
+| | ... | - subnets - Subnets to apply the specific ACL. Type: list
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Configure ACLs on a single interface \| ${nodes['DUT1']}
+| | ... | \| ... \| GigabitEthernet0/7/0 \| input \| permit | 0.0.0.0/0
+| | ...
+| | [Arguments] | ${dut} | ${dut_if} | ${acl_apply_type} | ${acl_action}
+| | ... | @{subnets}
+| | Set Test variable | ${acl} | ${EMPTY}
+| | :FOR | ${subnet} | IN | @{subnets}
+| | | ${acl}= | Run Keyword If | '${acl}' == '${EMPTY}'
+| | | ... | Set Variable | ipv4 ${acl_action} src ${subnet}
+| | | ... | ELSE
+| | | ... | Catenate | SEPARATOR=, | ${acl}
+| | | ... | ipv4 ${acl_action} src ${subnet}
+| | Add Replace Acl Multi Entries | ${dut} | rules=${acl}
+| | @{acl_list}= | Create List | ${0}
+| | Set Acl List For Interface | ${dut} | ${dut_if} | ${acl_apply_type}
+| | ... | ${acl_list}
+
+
+*** Keywords ***
+| Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | [Arguments] | ${num_of_threads} | ${rxq} | ${pkt_framesize} | ${search_type}
+| | ... | ${acl_type}=${EMPTY}
+| | [Documentation]
+| | ... | [Cfg] DUT runs L2BD switching config with 1 thread, 1 phy core,\
+| | ... | 1 receive queue per NIC port.
+| | ... | [Ver] Find NDR for 64 Byte frames using binary search start at 10GE\
+| | ... | linerate, step 10kpps.
+| | ...
+| | ... | *Arguments:*
+| | ... | - num_of_threads - Number of worker threads to be used. Type: integer
+| | ... | - rxq - Number of Rx queues to be used. Type: integer
+| | ... | - pkt_framesize - L2 Frame Size [B]. Type: integer
+| | ... | - search_type - Type of the search - non drop rate (NDR) or partial
+| | ... | drop rare (PDR). Type: string
+| | ...
+| | ${binary_min}= | Set Variable | ${min_rate}
+| | ${threshold}= | Set Variable | ${min_rate}
+| | ${max_pkt_size}= | Set Variable If | '${pkt_framesize}' == 'IMIX_v4_1' |
+| | ... | ${1500 + ${vxlan_overhead}} | ${pkt_framesize + ${vxlan_overhead}}
+| | ${max_rate}= | Calculate pps | ${s_limit} | ${max_pkt_size}
+| | ${binary_max}= | Set Variable | ${max_rate}
+| | Given Add '${num_of_threads}' worker threads and '${rxq}' rxqueues in 3-node single-link circular topology
+| | Add PCI devices to DUTs in 3-node single link topology
+| | And Run Keyword If | ${max_pkt_size} < ${1522}
+| | ... | Add no multi seg to all DUTs
+| | And Apply startup configuration on all VPP DUTs
+| | &{vxlan1}= | Create Dictionary | vni=24 | vtep=172.17.0.2
+| | &{vxlan2}= | Create Dictionary | vni=24 | vtep=172.27.0.2
+| | @{dut1_vxlans}= | Create List | ${vxlan1}
+| | @{dut2_vxlans}= | Create List | ${vxlan2}
+| | ${jumbo_frames}= | Set Variable If
+| | ... | ${max_pkt_size} < ${1522} | ${False} | ${True}
+| | Set interfaces in path in 3-node circular topology up
+| | Configure vhost interfaces for L2BD forwarding | ${dut1}
+| | ... | ${sock1} | ${sock2}
+| | When Init L2 bridge domains with single DUT with Vhost-User and VXLANoIPv4 in 3-node circular topology
+| | ... | 172.16.0.1 | 16 | 172.26.0.1 | 16 | 172.16.0.2 | 172.26.0.2
+| | ... | ${dut1_vxlans} | ${dut2_vxlans} | 172.17.0.0 | 16 | 172.27.0.0 | 16
+| | @{permit_list}= | Create List | 10.0.0.1/32 | 10.0.0.2/32
+| | Run Keyword If | '${acl_type}' != '${EMPTY}'
+| | ... | Configure ACLs on a single interface | ${dut1} | ${dut1_if2} | input
+| | ... | ${acl_type} | @{permit_list}
+| | ${vm1}= | And Configure guest VM with dpdk-testpmd connected via vhost-user
+| | ... | ${dut1} | ${sock1} | ${sock2} | DUT1_VM1
+| | ... | jumbo_frames=${jumbo_frames}
+| | Set Test Variable | &{dut1_vm_refs} | DUT1_VM1=${vm1}
+| | Set Test Variable | ${framesize} | ${pkt_framesize}
+| | ${pkt_framesize}= | Set Variable If | '${pkt_framesize}' == 'IMIX_v4_1' |
+| | ... | ${pkt_framesize} | ${pkt_framesize + ${vxlan_overhead}}
+| | Run Keyword If | '${search_type}' == 'NDR'
+| | ... | Find NDR using binary search and pps
+| | ... | ${pkt_framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
+| | ... | ${min_rate} | ${max_rate} | ${threshold}
+| | ... | ELSE IF | '${search_type}' == 'PDR'
+| | ... | Find PDR using binary search and pps
+| | ... | ${pkt_framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
+| | ... | ${min_rate} | ${max_rate} | ${threshold}
+| | ... | ${perf_pdr_loss_acceptance} | ${perf_pdr_loss_acceptance_type}
+
+*** Test Cases ***
+| tc01-64B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-ndrdisc
+| | [Tags] | 64B | 2T2C | STHREAD | NDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${64} | search_type=NDR
+
+| tc02-64B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-pdrdisc
+| | [Tags] | 64B | 2T2C | STHREAD | PDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${64} | search_type=PDR
+
+| tc03-150B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-ndrdisc
+| | [Tags] | 150B | 2T2C | STHREAD | NDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${150} | search_type=NDR
+
+| tc04-150B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-pdrdisc
+| | [Tags] | 150B | 2T2C | STHREAD | PDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${150} | search_type=PDR
+
+| tc05-200B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-ndrdisc
+| | [Tags] | 200B | 2T2C | STHREAD | NDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${200} | search_type=NDR
+
+| tc06-200B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-pdrdisc
+| | [Tags] | 200B | 2T2C | STHREAD | PDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${200} | search_type=PDR
+
+| tc07-IMIX-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-ndrdisc
+| | [Tags] | IMIX | 2T2C | STHREAD | NDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=IMIX_v4_1 | search_type=NDR
+
+| tc08-IMIX-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-pdrdisc
+| | [Tags] | IMIX | 2T2C | STHREAD | PDRDISC
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=IMIX_v4_1 | search_type=PDR
+
+| tc09-64B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-ndrdisc
+| | [Tags] | 64B | 2T2C | STHREAD | NDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${64} | search_type=NDR
+| | ... | acl_type=permit
+
+| tc10-64B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-pdrdisc
+| | [Tags] | 64B | 2T2C | STHREAD | PDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${64} | search_type=PDR
+| | ... | acl_type=permit
+
+| tc11-150B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-ndrdisc
+| | [Tags] | 150B | 2T2C | STHREAD | NDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${150} | search_type=NDR
+| | ... | acl_type=permit
+
+| tc12-150B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-pdrdisc
+| | [Tags] | 150B | 2T2C | STHREAD | PDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${150} | search_type=PDR
+| | ... | acl_type=permit
+
+| tc13-200B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-ndrdisc
+| | [Tags] | 200B | 2T2C | STHREAD | NDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${200} | search_type=NDR
+| | ... | acl_type=permit
+
+| tc14-200B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-pdrdisc
+| | [Tags] | 200B | 2T2C | STHREAD | PDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${200} | search_type=PDR
+| | ... | acl_type=permit
+
+| tc15-IMIX-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-ndrdisc
+| | [Tags] | IMIX | 2T2C | STHREAD | NDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=IMIX_v4_1 | search_type=NDR
+| | ... | acl_type=permit
+
+| tc16-IMIX-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-acl-pdrdisc
+| | [Tags] | IMIX | 2T2C | STHREAD | PDRDISC | ACL_PERMIT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=IMIX_v4_1 | search_type=PDR
+| | ... | acl_type=permit
+
+| tc17-64B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-ndrdisc
+| | [Tags] | 64B | 2T2C | STHREAD | NDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${64} | search_type=NDR
+| | ... | acl_type=permit+reflect
+
+| tc18-64B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-pdrdisc
+| | [Tags] | 64B | 2T2C | STHREAD | PDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${64} | search_type=PDR
+| | ... | acl_type=permit+reflect
+
+| tc19-150B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-ndrdisc
+| | [Tags] | 150B | 2T2C | STHREAD | NDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${150} | search_type=NDR
+| | ... | acl_type=permit+reflect
+
+| tc20-150B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-pdrdisc
+| | [Tags] | 150B | 2T2C | STHREAD | PDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${150} | search_type=PDR
+| | ... | acl_type=permit+reflect
+
+| tc21-200B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-ndrdisc
+| | [Tags] | 200B | 2T2C | STHREAD | NDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${200} | search_type=NDR
+| | ... | acl_type=permit+reflect
+
+| tc22-200B-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-pdrdisc
+| | [Tags] | 200B | 2T2C | STHREAD | PDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=${200} | search_type=PDR
+| | ... | acl_type=permit+reflect
+
+| tc23-IMIX-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-ndrdisc
+| | [Tags] | IMIX | 2T2C | STHREAD | NDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=IMIX_v4_1 | search_type=NDR
+| | ... | acl_type=permit+reflect
+
+| tc24-IMIX-1t1c-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-aclreflect-pdrdisc
+| | [Tags] | IMIX | 2T2C | STHREAD | PDRDISC | ACL_PERMIT_REFLECT
+| | ...
+| | [Template] | Discover NDR or PDR for IPv4 forwarding with VHOST/VXLAN and ACL
+| | num_of_threads=2 | rxq=2 | pkt_framesize=IMIX_v4_1 | search_type=PDR
+| | ... | acl_type=permit+reflect