CSIT-1178: Prepare for bursty MRR

+ All suites and tests still refer to MRR instead of BMRR (or FRMOBL).
+ API change: Traffic should pass with maximum rate
  first argument got a default value,
  thus it needs to be moved towards the end of argument list.
+ Consequently, the value for it has been deleted from suites.
+ Test message is now compatible only with BMRR parsing.
- Reporting of transmit rate is left as TODO.
+ Global test __init__ with new way of giving defaults to global variables.
+ The new keyword is put into robot_enhancements.robot resource.
+ Number of trials and trial duration are now configurable.
- Bootstrap scripts have no support for overriding the defaults yet.

Change-Id: I4b108cc9c256730e62c03fbacba0a1c314f8ae88
Signed-off-by: Vratko Polak <vrpolak@cisco.com>

1 files changed, 55 insertions, 0 deletions

diff --git a/resources/libraries/robot/robot_enhancements.robot b/resources/libraries/robot/robot_enhancements.robot
new file mode 100644
index 0000000000..7b337eafeb
--- /dev/null
+++ b/resources/libraries/robot/robot_enhancements.robot
@@ -0,0 +1,55 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Documentation
+| ... | Place to store general keywords, similar to ones in BuiltIn library.
+| Library | OperatingSystem
+| Library | String
+
+*** Keywords ***
+| Ensure Global Variable
+| | [Documentation] | Give default value (from environment or code) to variable.
+| | ...
+| | ... | Ideally we would just use Variables table to set global variables.
+| | ... | Unfortunately, __init__ files are special (among other things)
+| | ... | by the fact that variables set in the table are not available
+| | ... | for (sub)directory suites.
+| | ... | Therefore we are using BuiltIn.Set_Global_Variable explicitly.
+| | ... | While we are running code here, we allow environment variables
+| | ... | to override the default values.
+| | ... | If environment variable name is not specified (or empty),
+| | ... | the upper case of the variable name is used, prefixed by "CSIT_".
+| | ... | The --variable parameter to pybot takes precedence to environment.
+| | ...
+| | ... | *Arguments:*
+| | ... | - variable_name - Name of global variable to set. Type: string
+| | ... | - default_value - Value to set if not set otherwise. Type: string
+| | ... | - env_var_name - Name of environment variable to read. Type: string
+| | ... | - application - Prefix for default environment variable. Type: string
+| | ...
+| | ... | *Example:*
+| | ... | \| Ensure Global Variable \| perf_trial_duration \| 10.0 \| TRIAL_DUR
+| | ...
+| | [Arguments] | ${variable_name} | ${default_value} | ${env_var_name}=${EMPTY}
+| | ... | ${application}=CSIT
+| | ...
+| | ${env_var_length} = | Get Length | ${env_var_name}
+| | ${default_env_var} = | Convert To Uppercase | ${variable_name}
+| | ${env_var} = | Set Variable If | ${env_var_length}
+| | ... | ${env_var_name} | ${application}_${default_env_var}
+| | ${updated_default} = | Get Environment Variable
+| | ... | ${env_var} | ${default_value}
+| | ${final_value} = | Get Variable Value
+| | ... | \${${variable_name}} | ${updated_default}
+| | Set Global Variable | \${${variable_name}} | ${final_value}