New version of RF tests.

Change-Id: I241a2b7a7706e65f71cfd4a62e2a40f053fc5d07
Signed-off-by: Stefan Kobza <skobza@cisco.com>

7 files changed, 380 insertions, 0 deletions

diff --git a/resources/libraries/robot/bridge_domain.robot b/resources/libraries/robot/bridge_domain.robot
new file mode 100644
index 0000000000..fc3705700e
--- /dev/null
+++ b/resources/libraries/robot/bridge_domain.robot
@@ -0,0 +1,54 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Library | resources/libraries/python/VatExecutor.py
+| Library | resources/libraries/python/VatConfigGenerator.py
+| Library | resources.libraries.python.topology.Topology
+| Library | resources/libraries/python/TrafficScriptExecutor.py
+| Variables | resources/libraries/python/constants.py
+
+*** Variables ***
+| ${VAT_BD_TEMPLATE} | ${Constants.RESOURCES_TPL_VAT}/l2_bridge_domain.vat
+| ${VAT_BD_GEN_FILE} | ${Constants.RESOURCES_TPL_VAT}/l2_bridge_domain_gen.vat
+| ${VAT_BD_REMOTE_PATH} | ${Constants.REMOTE_FW_DIR}/l2_bridge_domain_gen.vat
+
+*** Keywords ***
+| Setup l2 bridge on node "${node}" via links "${link_names}"
+| | ${interface_config}= | Get Interfaces By Link Names | ${node} | ${link_names}
+| | ${commands}= | Generate Vat Config File | ${VAT_BD_TEMPLATE} | ${interface_config} | ${VAT_BD_GEN_FILE}
+| | Copy Config To Remote | ${node} | ${VAT_BD_GEN_FILE} | ${VAT_BD_REMOTE_PATH}
+# TODO: will be removed once v4 is merged to master.
+| | Execute Script | l2_bridge_domain_gen.vat | ${node} | json_out=False
+| | Script Should Have Passed
+
+| Send traffic on node "${node}" from link "${link1}" to link "${link2}"
+| | ${src_port}= | Get Interface By Link Name | ${node} | ${link1}
+| | ${dst_port}= | Get Interface By Link Name | ${node} | ${link2}
+| | ${src_ip}= | Set Variable | 192.168.100.1
+| | ${dst_ip}= | Set Variable | 192.168.100.2
+| | ${src_mac}= | Get Node Link Mac | ${node} | ${link1}
+| | ${dst_mac}= | Get Node Link Mac | ${node} | ${link2}
+| | ${args}= | Traffic Script Gen Arg | ${src_port} | ${src_port} | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | Run Traffic Script On Node | send_ip_icmp.py | ${node} | ${args}
+
+| Setup TG "${tg}" DUT1 "${dut1}" and DUT2 "${dut2}" for 3 node l2 bridge domain test
+| | ${DUT1_DUT2_link}= | Get first active connecting link between node "${dut1}" and "${dut2}"
+| | ${DUT1_TG_link}= | Get first active connecting link between node "${dut1}" and "${tg}"
+| | ${DUT2_TG_link}= | Get first active connecting link between node "${dut2}" and "${tg}"
+| | ${tg_traffic_links}= | Create List | ${DUT1_TG_link} | ${DUT2_TG_link}
+| | ${DUT1_BD_links}= | Create_list | ${DUT1_DUT2_link} | ${DUT1_TG_link}
+| | ${DUT2_BD_links}= | Create_list | ${DUT1_DUT2_link} | ${DUT2_TG_link}
+| | Setup l2 bridge on node "${dut1}" via links "${DUT1_BD_links}"
+| | Setup l2 bridge on node "${dut2}" via links "${DUT2_BD_links}"
+| | [Return] | ${tg_traffic_links}
\ No newline at end of file
diff --git a/resources/libraries/robot/counters.robot b/resources/libraries/robot/counters.robot
new file mode 100644
index 0000000000..a8897685ad
--- /dev/null
+++ b/resources/libraries/robot/counters.robot
@@ -0,0 +1,39 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Documentation | VPP counters keywords
+| Library | resources/libraries/python/VppCounters.py
+
+*** Keywords ***
+| Clear interface counters on all vpp nodes in topology
+| | [Documentation] | Clear interface counters on all VPP nodes in topology
+| | [Arguments] | ${nodes}
+| | Vpp Nodes Clear Interface Counters | ${nodes}
+
+| Vpp dump stats
+| | [Documentation] | Dump stats table on VPP node
+| | [Arguments] | ${node}
+| | Vpp Dump Stats Table | ${node}
+
+| Vpp get interface ipv6 counter
+| | [Documentation] | Return IPv6 statistics for node interface
+| | [Arguments] | ${node} | ${interface}
+| | ${ipv6_counter}= | Vpp Get Ipv6 Interface Counter | ${node} | ${interface}
+| | [Return] | ${ipv6_counter}
+
+| Check ipv4 interface counter
+| | [Documentation] | Check that ipv4 interface counter has right value
+| | [Arguments] | ${node} | ${interface} | ${value}
+| | ${ipv4_counter}= | Vpp get ipv4 interface counter | ${node} | ${interface}
+| | Should Be Equal | ${ipv4_counter} | ${value}
diff --git a/resources/libraries/robot/default.robot b/resources/libraries/robot/default.robot
new file mode 100644
index 0000000000..0c9341580e
--- /dev/null
+++ b/resources/libraries/robot/default.robot
@@ -0,0 +1,26 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Variables | resources/libraries/python/topology.py
+| Library | resources/libraries/python/DUTSetup.py
+| Library | resources/libraries/python/TGSetup.py
+
+*** Keywords ***
+| Setup all DUTs before test
+| | [Documentation] | Setup all DUTs in topology before test execution
+| | Setup All DUTs | ${nodes}
+
+| Setup all TGs before traffic script
+| | [Documentation] | Prepare all TGs before traffic scripts execution
+| | All TGs Set Interface Default Driver | ${nodes}
diff --git a/resources/libraries/robot/interfaces.robot b/resources/libraries/robot/interfaces.robot
new file mode 100644
index 0000000000..18c9c0cc81
--- /dev/null
+++ b/resources/libraries/robot/interfaces.robot
@@ -0,0 +1,20 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+*** Settings ***
+| Resource | resources/libraries/robot/vat/interfaces.robot
+
+*** Keywords ***
+| VPP reports interfaces on | [Arguments] | ${node}
+| | VPP reports interfaces through VAT on | ${node}
+#| | VPP reports interfaces through ODL on | ${node}
+#| | VPP reports interfaces through DEBUGCLI on | ${node}
diff --git a/resources/libraries/robot/ipv4.robot b/resources/libraries/robot/ipv4.robot
new file mode 100644
index 0000000000..a4e1086d38
--- /dev/null
+++ b/resources/libraries/robot/ipv4.robot
@@ -0,0 +1,51 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/counters.robot
+| Library | resources/libraries/python/IPv4Util.py
+| Variables | resources/libraries/python/IPv4NodeAddress.py
+
+*** Keywords ***
+
+| Setup IPv4 adresses on all nodes in topology
+| | [Documentation] | Setup IPv4 address on all DUTs and TG in topology
+| | [Arguments] | ${nodes} | ${nodes_addr}
+| | Nodes setup IPv4 addresses | ${nodes} | ${nodes_addr}
+
+| Interfaces needed for IPv4 testing are in "${state}" state
+| | Node "${nodes['DUT1']}" interface "${nodes['DUT1']['interfaces']['port1']['name']}" is in "${state}" state
+| | Node "${nodes['DUT1']}" interface "${nodes['DUT1']['interfaces']['port3']['name']}" is in "${state}" state
+| | Node "${nodes['DUT2']}" interface "${nodes['DUT2']['interfaces']['port1']['name']}" is in "${state}" state
+| | Node "${nodes['DUT2']}" interface "${nodes['DUT2']['interfaces']['port3']['name']}" is in "${state}" state
+
+| Routes are set up for IPv4 testing
+| | ${gateway} = | Get IPv4 address of node "${nodes['DUT2']}" interface "${nodes['DUT2']['interfaces']['port3']['name']}"
+| | ${subnet} = | Get IPv4 subnet of node "${nodes['DUT2']}" interface "${nodes['DUT2']['interfaces']['port1']['name']}"
+| | ${prefix_length} = | Get IPv4 address prefix of node "${nodes['DUT2']}" interface "${nodes['DUT2']['interfaces']['port1']['name']}"
+| | Node "${nodes['DUT1']}" routes to IPv4 network "${subnet}" with prefix length "${prefix_length}" using interface "${nodes['DUT1']['interfaces']['port3']['name']}" via "${gateway}"
+| | ${gateway} = | Get IPv4 address of node "${nodes['DUT1']}" interface "${nodes['DUT1']['interfaces']['port3']['name']}"
+| | ${subnet} = | Get IPv4 subnet of node "${nodes['DUT1']}" interface "${nodes['DUT1']['interfaces']['port1']['name']}"
+| | ${prefix_length} = | Get IPv4 address prefix of node "${nodes['DUT1']}" interface "${nodes['DUT1']['interfaces']['port1']['name']}"
+| | Node "${nodes['DUT2']}" routes to IPv4 network "${subnet}" with prefix length "${prefix_length}" using interface "${nodes['DUT2']['interfaces']['port3']['name']}" via "${gateway}"
+
+| Setup nodes for IPv4 testing
+| | Interfaces needed for IPv4 testing are in "up" state
+| | Setup IPv4 adresses on all nodes in topology | ${nodes} | ${nodes_ipv4_addr}
+| | Routes are set up for IPv4 testing
+
+| TG interface "${tg_port}" can route to node "${node}" interface "${port}" "${hops}" hops away using IPv4
+| | Node "${nodes['TG']}" interface "${tg_port}" can route to node "${node}" interface "${port}" "${hops}" hops away using IPv4
+
+| Node "${from_node}" interface "${from_port}" can route to node "${to_node}" interface "${to_port}" "${hops}" hops away using IPv4
+| | After ping is sent from node "${from_node}" interface "${from_port}" with destination IPv4 address of node "${to_node}" interface "${to_port}" a ping response arrives and TTL is decreased by "${hops}"
diff --git a/resources/libraries/robot/ipv6.robot b/resources/libraries/robot/ipv6.robot
new file mode 100644
index 0000000000..f45ba7c220
--- /dev/null
+++ b/resources/libraries/robot/ipv6.robot
@@ -0,0 +1,167 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""IPv6 keywords"""
+
+*** Settings ***
+| Library | resources/libraries/python/IPv6Util.py
+| Library | resources/libraries/python/IPv6Setup.py
+| Library | resources/libraries/python/TrafficScriptExecutor.py
+| Library | resources.libraries.python.topology.Topology
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/counters.robot
+| Documentation | IPv6 keywords
+
+*** Keywords ***
+| Ipv6 icmp echo
+| | [Documentation] | Type of the src_node must be TG and dst_node must be DUT
+| | [Arguments] | ${src_node} | ${dst_node} | ${nodes_addr}
+| | ${link}= | Get first active connecting link between node "${src_node}" and "${dst_node}"
+| | ${src_port}= | Get Interface By Link Name | ${src_node} | ${link}
+| | ${dst_port}= | Get Interface By Link Name | ${dst_node} | ${link}
+| | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port} | ${nodes_addr}
+| | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port} | ${nodes_addr}
+| | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
+| | ${dst_mac}= | Get Interface Mac | ${dst_node} | ${dst_port}
+| | ${args}= | Traffic Script Gen Arg | ${src_port} | ${src_port} | ${src_mac}
+| |          | ...                    | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | Run Traffic Script On Node | icmpv6_echo.py | ${src_node} | ${args}
+| | Vpp dump stats | ${dst_node}
+| | ${ipv6_counter}= | Vpp get interface ipv6 counter | ${dst_node} | ${dst_port}
+| | Should Be Equal | ${ipv6_counter} | ${2} | #ICMPv6 neighbor advertisment + ICMPv6 echo request
+
+| Ipv6 icmp echo sweep
+| | [Documentation] | Type of the src_node must be TG and dst_node must be DUT
+| | [Arguments] | ${src_node} | ${dst_node} | ${nodes_addr}
+| | ${link}= | Get first active connecting link between node "${src_node}" and "${dst_node}"
+| | ${src_port}= | Get Interface By Link Name | ${src_node} | ${link}
+| | ${dst_port}= | Get Interface By Link Name | ${dst_node} | ${link}
+| | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port} | ${nodes_addr}
+| | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port} | ${nodes_addr}
+| | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
+| | ${dst_mac}= | Get Interface Mac | ${dst_node} | ${dst_port}
+| | ${args}= | Traffic Script Gen Arg | ${src_port} | ${src_port} | ${src_mac}
+| |          | ...                    | ${dst_mac} | ${src_ip} | ${dst_ip}
+| # TODO: end_size is currently minimum MTU size for IPv6 minus IPv6 and ICMPv6
+| # echo header size, MTU info is not in VAT sw_interface_dump output
+| | ${args}= | Set Variable | ${args} --start_size 0 --end_size 1232 --step 1
+| | Run Traffic Script On Node | ipv6_sweep_ping.py | ${src_node} | ${args} | ${20}
+
+| Ipv6 tg to dut1 egress
+| | [Documentation] | Send traffic from TG to first DUT egress interface
+| | [Arguments] | ${tg_node} | ${first_dut} | ${nodes_addr}
+| | ${link}= | Get first active connecting link between node "${tg_node}" and "${first_dut}"
+| | ${src_port}= | Get Interface By Link Name | ${tg_node} | ${link}
+| | ${first_hop_port}= | Get Interface By Link Name | ${first_dut} | ${link}
+| | ${dst_port}= | Get first egress interface on "${first_dut}" for link with "${tg_node}"
+| | ${src_ip}= | Get Node Port Ipv6 Address | ${tg_node} | ${src_port} | ${nodes_addr}
+| | ${dst_ip}= | Get Node Port Ipv6 Address | ${first_dut} | ${dst_port} | ${nodes_addr}
+| | ${src_mac}= | Get Interface Mac | ${tg_node} | ${src_port}
+| | ${dst_mac}= | Get Interface Mac | ${first_dut} | ${first_hop_port}
+| | ${args}= | Traffic Script Gen Arg | ${src_port} | ${src_port} | ${src_mac}
+| |          | ...                    | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | Run Traffic Script On Node | icmpv6_echo.py | ${tg_node} | ${args}
+
+
+| Ipv6 tg to dut2 via dut1
+| | [Documentation] | Send traffic from TG to second DUT through first DUT
+| | [Arguments] | ${tg_node} | ${first_dut} | ${second_dut} | ${nodes_addr}
+| | ${link1}= | Get first active connecting link between node "${tg_node}" and "${first_dut}"
+| | ${src_port}= | Get Interface By Link Name | ${tg_node} | ${link1}
+| | ${first_hop_port}= | Get Interface By Link Name | ${first_dut} | ${link1}
+| | ${link2}= | Get first active connecting link between node "${first_dut}" and "${second_dut}"
+| | ${dst_port}= | Get Interface By Link Name | ${second_dut} | ${link2}
+| | ${src_ip}= | Get Node Port Ipv6 Address | ${tg_node} | ${src_port} | ${nodes_addr}
+| | ${dst_ip}= | Get Node Port Ipv6 Address | ${second_dut} | ${dst_port} | ${nodes_addr}
+| | ${src_mac}= | Get Interface Mac | ${tg_node} | ${src_port}
+| | ${dst_mac}= | Get Interface Mac | ${first_dut} | ${first_hop_port}
+| | ${args}= | Traffic Script Gen Arg | ${src_port} | ${src_port} | ${src_mac}
+| |          | ...                    | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | Run Traffic Script On Node | icmpv6_echo.py | ${tg_node} | ${args}
+
+| Ipv6 tg to dut2 egress via dut1
+| | [Documentation] | Send traffic from TG to second DUT egress interface through first DUT
+| | [Arguments] | ${tg_node} | ${first_dut} | ${second_dut} | ${nodes_addr}
+| | ${link}= | Get first active connecting link between node "${tg_node}" and "${first_dut}"
+| | ${src_port}= | Get Interface By Link Name | ${tg_node} | ${link}
+| | ${first_hop_port}= | Get Interface By Link Name | ${first_dut} | ${link}
+| | ${dst_port}= | Get first egress interface on "${first_dut}" for link with "${second_dut}"
+| | ${src_ip}= | Get Node Port Ipv6 Address | ${tg_node} | ${src_port} | ${nodes_addr}
+| | ${dst_ip}= | Get Node Port Ipv6 Address | ${second_dut} | ${dst_port} | ${nodes_addr}
+| | ${src_mac}= | Get Interface Mac | ${tg_node} | ${src_port}
+| | ${dst_mac}= | Get Interface Mac | ${first_dut} | ${first_hop_port}
+| | ${args}= | Traffic Script Gen Arg | ${src_port} | ${src_port} | ${src_mac}
+| |          | ...                    | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | Run Traffic Script On Node | icmpv6_echo.py | ${tg_node} | ${args}
+
+| Ipv6 tg to tg routed
+| | [Documentation] | Send traffic from one TG port to another through DUT nodes
+| | ...             | and send reply back, also verify hop limit processing
+| | [Arguments] | ${tg_node} | ${first_dut} | ${second_dut} | ${nodes_addr}
+| | ${link1}= | Get first active connecting link between node "${tg_node}" and "${first_dut}"
+| | ${src_port}= | Get Interface By Link Name | ${tg_node} | ${link1}
+| | ${src_nh_port}= | Get Interface By Link Name | ${first_dut} | ${link1}
+| | ${link2}= | Get first active connecting link between node "${tg_node}" and "${second_dut}"
+| | ${dst_port}= | Get Interface By Link Name | ${tg_node} | ${link2}
+| | ${dst_nh_port}= | Get Interface By Link Name | ${second_dut} | ${link2}
+| | ${src_ip}= | Get Node Port Ipv6 Address | ${tg_node} | ${src_port} | ${nodes_addr}
+| | ${dst_ip}= | Get Node Port Ipv6 Address | ${tg_node} | ${dst_port} | ${nodes_addr}
+| | ${src_mac}= | Get Interface Mac | ${tg_node} | ${src_port}
+| | ${dst_mac}= | Get Interface Mac | ${tg_node} | ${dst_port}
+| | ${src_nh_mac}= | Get Interface Mac | ${first_dut} | ${src_nh_port}
+| | ${dst_nh_mac}= | Get Interface Mac | ${second_dut} | ${dst_nh_port}
+| | ${args}= | Traffic Script Gen Arg | ${src_port} | ${dst_port} | ${src_mac}
+| |          | ...                    | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | ${args}= | Set Variable | ${args} --src_nh_mac ${src_nh_mac} --dst_nh_mac ${dst_nh_mac} --h_num 2
+| | Run Traffic Script On Node | icmpv6_echo_req_resp.py | ${tg_node} | ${args}
+
+| Ipv6 neighbor solicitation
+| | [Documentation] | Send IPv6 neighbor solicitation from TG to DUT
+| | [Arguments] | ${tg_node} | ${dut_node} | ${nodes_addr}
+| | ${link}= | Get first active connecting link between node "${tg_node}" and "${dut_node}"
+| | ${tg_port}= | Get Interface By Link Name | ${tg_node} | ${link}
+| | ${dut_port}= | Get Interface By Link Name | ${dut_node} | ${link}
+| | ${src_ip}= | Get Node Port Ipv6 Address | ${tg_node} | ${tg_port} | ${nodes_addr}
+| | ${dst_ip}= | Get Node Port Ipv6 Address | ${dut_node} | ${dut_port} | ${nodes_addr}
+| | ${src_mac}= | Get Interface Mac | ${tg_node} | ${tg_port}
+| | ${dst_mac}= | Get Interface Mac | ${dut_node} | ${dut_port}
+| | ${args}= | Traffic Script Gen Arg | ${tg_port} | ${tg_port} | ${src_mac}
+| |          | ...                    | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | Run Traffic Script On Node | ipv6_ns.py | ${tg_node} | ${args}
+
+| Setup ipv6 to all dut in topology
+| | [Documentation] | Setup IPv6 address on all DUTs
+| | [Arguments] | ${nodes} | ${nodes_addr}
+| | Setup all DUTs before test
+| | Nodes Setup Ipv6 Addresses | ${nodes} | ${nodes_addr}
+
+| Clear ipv6 on all dut in topology
+| | [Documentation] | Remove IPv6 address on all DUTs
+| | [Arguments] | ${nodes} | ${nodes_addr}
+| | Nodes Clear Ipv6 Addresses | ${nodes} | ${nodes_addr}
+
+| Vpp nodes ra supress link layer
+| | [Documentation] | Supress ICMPv6 router advertisement message for link scope address
+| | [Arguments] | ${nodes}
+| | Vpp All Ra Supress Link Layer | ${nodes}
+
+| Vpp nodes setup ipv6 routing
+| | [Documentation] | Setup routing on all VPP nodes required for IPv6 tests
+| | [Arguments] | ${nodes} | ${nodes_addr}
+| | ${link_tg_dut1}= | Get first active connecting link between node "${nodes['TG']}" and "${nodes['DUT1']}"
+| | ${link_tg_dut2}= | Get first active connecting link between node "${nodes['TG']}" and "${nodes['DUT2']}"
+| | ${link_dut1_dut2}= | Get first active connecting link between node "${nodes['DUT1']}" and "${nodes['DUT2']}"
+| | ${dut1_if}= | Get Interface By Link Name | ${nodes['DUT1']} | ${link_dut1_dut2}
+| | ${dut2_if}= | Get Interface By Link Name | ${nodes['DUT2']} | ${link_dut1_dut2}
+| | Vpp Ipv6 Route Add | ${nodes['DUT1']} | ${link_tg_dut2} | ${dut1_if} | ${nodes_addr}
+| | Vpp Ipv6 Route Add | ${nodes['DUT2']} | ${link_tg_dut1} | ${dut2_if} | ${nodes_addr}
diff --git a/resources/libraries/robot/vat/interfaces.robot b/resources/libraries/robot/vat/interfaces.robot
new file mode 100644
index 0000000000..1342f6326b
--- /dev/null
+++ b/resources/libraries/robot/vat/interfaces.robot
@@ -0,0 +1,23 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+*** Settings ***
+| Library | resources/libraries/python/VatExecutor.py
+
+*** Variables ***
+| ${VAT_DUMP_INTERFACES} | dump_interfaces.vat
+
+*** Keywords ***
+| VPP reports interfaces through VAT on
+| | [Arguments] | ${node}
+| | Execute Script | ${VAT_DUMP_INTERFACES} | ${node}
+| | Script Should Have Passed