CSIT-1165 Create DPDK tests for 2-node topology

Create DPDK tests for 2-node topology
- x710, xxv710 only
- l3fwd, testpmd
- standard pkt.size group

Change-Id: I2fbf6c38a427775da9b289faaa8fe1b8c03d5527
Signed-off-by: Peter Mikus <pmikus@cisco.com>

1 files changed, 126 insertions, 0 deletions

diff --git a/tests/dpdk/perf/2n1l-25ge2p1xxv710-eth-l2xcbase-testpmd-ndrpdr.robot b/tests/dpdk/perf/2n1l-25ge2p1xxv710-eth-l2xcbase-testpmd-ndrpdr.robot
new file mode 100644
index 0000000000..60a9e4a052
--- /dev/null
+++ b/tests/dpdk/perf/2n1l-25ge2p1xxv710-eth-l2xcbase-testpmd-ndrpdr.robot
@@ -0,0 +1,126 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/performance/performance_setup.robot
+| Resource | resources/libraries/robot/dpdk/default.robot
+| Library | resources.libraries.python.topology.Topology
+| Library | resources.libraries.python.NodePath
+| Library | resources.libraries.python.InterfaceUtil
+| Library | resources.libraries.python.DPDK.DPDKTools
+| ...
+| Force Tags | 2_NODE_SINGLE_LINK_TOPO | HW_ENV | PERFTEST | NDRPDR | 1NUMA
+| ... | NIC_Intel-XXV710 | DPDK | ETH | L2XCFWD | BASE
+| ...
+| Suite Setup | Set up DPDK 2-node performance topology with DUT's NIC model
+| ... | L2 | Intel-XXV710
+| Suite Teardown | Tear down DPDK 2-node performance topology
+| ...
+| Test template | Local template
+| ...
+| Documentation | *Raw results L2 routing test cases*
+| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
+| ... | with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 frame forwarding.
+| ... | *[Cfg] DUT configuration:* DUT1 run the DPDK testpmd\
+| ... | application and use the io forwarding mode. DUT1 tested with\
+| ... | 2p25GE NIC XXV710 by Intel.
+| ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
+| ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
+| ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
+| ... | of packets transmitted. NDR and PDR are discovered for different\
+| ... | Ethernet L2 frame sizes using MLRsearch library\
+| ... | Test packets are generated by TG on\
+| ... | links to DUTs. TG traffic profile contains two L3 flow-groups\
+| ... | (flow-group per direction, 254 flows per flow-group) with\
+| ... | all packets containing Ethernet header,IPv4 header with static payload.\
+| ... | MAC addresses are matching MAC addresses of the TG node interfaces.
+
+*** Variables ***
+# XXV10-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
+| ${s_24.5G}= | ${24500000000}
+# XXV710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
+| ${s_18.75Mpps}= | ${18750000}
+# Traffic profile:
+| ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
+
+*** Keywords ***
+| Local template
+| | [Documentation]
+| | ... | [Cfg] DUT runs L2 frame forwarding config.\
+| | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
+| | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.
+| | ...
+| | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
+| | ...
+| | Set Test Variable | ${framesize}
+| | Set Test Variable | ${min_rate} | ${20000}
+| | ${get_framesize}= | Get Frame Size | ${framesize}
+| | ${max_rate}= | Calculate pps | ${s_24.5G} | ${get_framesize}
+| | ${max_rate}= | Set Variable If
+| | ... | ${max_rate} > ${s_18.75Mpps} | ${s_18.75Mpps} | ${max_rate}
+| | ${jumbo_frames}= | Set Variable If
+| | ... | ${get_framesize} < ${1522} | ${False} | ${True}
+| | ...
+| | Given Start L2FWD on all DUTs | ${phy_cores} | ${rxq} | ${jumbo_frames}
+| | Then Find NDR and PDR intervals using optimized search
+| | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
+
+*** Test Cases ***
+| tc01-64B-1t1c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 64B | 1C
+| | framesize=${64} | phy_cores=${1}
+
+| tc02-1518B-1t1c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 1518B | 1C
+| | framesize=${1518} | phy_cores=${1}
+
+| tc03-9000B-1t1c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 9000B | 1C
+| | framesize=${9000} | phy_cores=${1}
+
+| tc04-IMIX-1t1c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | IMIX | 1C
+| | framesize=IMIX_v4_1 | phy_cores=${1}
+
+| tc05-64B-2t2c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 64B | 2C
+| | framesize=${64} | phy_cores=${2}
+
+| tc06-1518B-2t2c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 1518B | 2C
+| | framesize=${1518} | phy_cores=${2}
+
+| tc07-9000B-2t2c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 9000B | 2C
+| | framesize=${9000} | phy_cores=${2}
+
+| tc08-IMIX-2t2c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | IMIX | 2C
+| | framesize=IMIX_v4_1 | phy_cores=${2}
+
+| tc09-64B-4t4c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 64B | 4C
+| | framesize=${64} | phy_cores=${4}
+
+| tc10-1518B-4t4c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 1518B | 4C
+| | framesize=${1518} | phy_cores=${4}
+
+| tc11-9000B-4t4c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | 9000B | 4C
+| | framesize=${9000} | phy_cores=${4}
+
+| tc12-IMIX-4t4c-eth-l2xcbase-testpmd-ndrpdr
+| | [Tags] | IMIX | 4C
+| | framesize=IMIX_v4_1 | phy_cores=${4}