CSIT-687: Directory structure reorganization

Change-Id: I772c9e214be2461adf58124998d272e7d795220f
Signed-off-by: Tibor Frank <tifrank@cisco.com>
Signed-off-by: Maciek Konstantynowicz <mkonstan@cisco.com>

5 files changed, 0 insertions, 548 deletions

diff --git a/tests/func/ipv4/eth2p-ethip4-ip4base-eth-2vhost-1vm.robot b/tests/func/ipv4/eth2p-ethip4-ip4base-eth-2vhost-1vm.robot
deleted file mode 100644
index d3bf4b517d..0000000000
--- a/tests/func/ipv4/eth2p-ethip4-ip4base-eth-2vhost-1vm.robot
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright (c) 2016 Cisco and/or its affiliates.
-# Licensed under the Apache License, Version 2.0 (the "License");
-# you may not use this file except in compliance with the License.
-# You may obtain a copy of the License at:
-#
-#     http://www.apache.org/licenses/LICENSE-2.0
-#
-# Unless required by applicable law or agreed to in writing, software
-# distributed under the License is distributed on an "AS IS" BASIS,
-# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-# See the License for the specific language governing permissions and
-# limitations under the License.
-
-*** Settings ***
-| Library | resources.libraries.python.topology.Topology
-| Library | resources.libraries.python.NodePath
-| Library | resources.libraries.python.Trace
-| Library | resources.libraries.python.IPUtil
-| Library | resources.libraries.python.VPPUtil
-| Library | resources.libraries.python.InterfaceUtil
-| Library | resources.libraries.python.VhostUser
-| Resource | resources/libraries/robot/traffic.robot
-| Resource | resources/libraries/robot/default.robot
-| Resource | resources/libraries/robot/interfaces.robot
-| Resource | resources/libraries/robot/testing_path.robot
-| Resource | resources/libraries/robot/ipv4.robot
-| Resource | resources/libraries/robot/vrf.robot
-| Resource | resources/libraries/robot/qemu.robot
-| Resource | resources/libraries/robot/bridge_domain.robot
-| Force Tags | VM_ENV | HW_ENV | 3_NODE_DOUBLE_LINK_TOPO
-| Test Setup | Set up functional test
-| Test Teardown | Tear down functional test
-| Documentation | *IPv4 routing test cases with vhost user interface*
-| ...
-| ... | RFC791 IPv4, RFC826 ARP, RFC792 ICMPv4. Encapsulations: Eth-IPv4-ICMPv4
-| ... | on links TG=DUT1. IPv4 routing tests use circular 2-node
-| ... | topology TG - DUT1 - TG with two link between the nodes. DUT is
-| ... | configured with IPv4 routing and static routes. Test sends packets
-| ... | by TG on links to DUT and received on TG link on the other side of
-| ... | circular topology. On receive TG verifies packets IPv4 src-addr,
-| ... | dst-addr and MAC addresses.
-
-*** Variables ***
-| ${net1}= | 10.0.1.0
-| ${net3}= | 10.0.3.0
-| ${net1_ip1}= | 10.0.1.1
-| ${net1_ip2}= | 10.0.1.2
-| ${net2_ip1}= | 10.0.2.1
-| ${net2_ip2}= | 10.0.2.2
-| ${net3_ip1}= | 10.0.3.1
-| ${net3_ip2}= | 10.0.3.2
-| ${prefix_length}= | 24
-| ${fib_table_2}= | 20
-| ${sock1}= | /tmp/sock1
-| ${sock2}= | /tmp/sock2
-
-*** Test Cases ***
-| TC01: IPv4 forward via vhost to another VRF
-| | [Documentation]
-| | ... | Test uses VRF to route IPv4 traffic through 2 vhost user interfaces.
-| | ... | Both have IP addresses from same network. On VM is set bridge to pass
-| | ... | packet from a one vhost user interface to another one.
-| | [Teardown] | Run Keywords
-| | ... | Stop and clear QEMU | ${dut_node} | ${vm_node} | AND
-| | ... | Tear down functional test
-| |
-| | Given Configure path in 2-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
-| | And Set interfaces in 2-node circular topology up
-| | ${vhost1}= | And Vpp Create Vhost User Interface | ${dut_node} | ${sock1}
-| | ${vhost2}= | And Vpp Create Vhost User Interface | ${dut_node} | ${sock2}
-| | And Set Interface State | ${dut_node} | ${vhost1} | up
-| | And Set Interface State | ${dut_node} | ${vhost2} | up
-| | And Assign Interface To Fib Table | ${dut_node}
-| | ... | ${vhost2} | ${fib_table_2}
-| | And Assign Interface To Fib Table | ${dut_node}
-| | ... | ${dut_to_tg_if2} | ${fib_table_2}
-| | And Configure IP addresses on interfaces
-| | ... | ${dut_node} | ${dut_to_tg_if1} | ${net1_ip1} | ${prefix_length}
-| | ... | ${dut_node} | ${vhost1} | ${net2_ip1} | ${prefix_length}
-| | ... | ${dut_node} | ${vhost2} | ${net2_ip2} | ${prefix_length}
-| | ... | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip1} | ${prefix_length}
-| | ${vhost2_mac}= | And Get Vhost User Mac By SW Index
-| | ... | ${dut_node} | ${vhost2}
-| | And Vpp Route Add | ${dut_node} | ${net3} | 24 | ${net2_ip2}
-| | ... | ${vhost1} | resolve_attempts=${NONE} | count=${NONE}
-| | And Vpp Route Add | ${dut_node} | ${net1} | 24 | ${net2_ip1}
-| | ... | ${vhost2} | resolve_attempts=${NONE} | count=${NONE}
-| | ... | vrf=${fib_table_2}
-| | Add IP Neighbor | ${dut_node} | ${vhost1} | ${net2_ip2} | ${vhost2_mac}
-| | Add IP Neighbor | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip2}
-| | ... | ${tg_to_dut_if2_mac}
-| | When Configure VM for vhost L2BD forwarding
-| | ... | ${dut_node} | ${sock1} | ${sock2}
-| | Then Send packet and verify headers
-| | ... | ${tg_node} | ${net1_ip2} | ${net3_ip2}
-| | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac} | ${dut_to_tg_if1_mac}
-| | ... | ${tg_to_dut_if2} | ${dut_to_tg_if2_mac} | ${tg_to_dut_if2_mac}
diff --git a/tests/func/ipv4/eth2p-ethip4-ip4base-func.robot b/tests/func/ipv4/eth2p-ethip4-ip4base-func.robot
deleted file mode 100644
index eadcdee43d..0000000000
--- a/tests/func/ipv4/eth2p-ethip4-ip4base-func.robot
+++ /dev/null
@@ -1,138 +0,0 @@
-# Copyright (c) 2016 Cisco and/or its affiliates.
-# Licensed under the Apache License, Version 2.0 (the "License");
-# you may not use this file except in compliance with the License.
-# You may obtain a copy of the License at:
-#
-#     http://www.apache.org/licenses/LICENSE-2.0
-#
-# Unless required by applicable law or agreed to in writing, software
-# distributed under the License is distributed on an "AS IS" BASIS,
-# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-# See the License for the specific language governing permissions and
-# limitations under the License.
-
-*** Settings ***
-| Library | resources.libraries.python.NodePath
-| Library | resources.libraries.python.Trace
-| Resource | resources/libraries/robot/default.robot
-| Resource | resources/libraries/robot/interfaces.robot
-| Resource | resources/libraries/robot/ipv4.robot
-| Force Tags | 3_NODE_SINGLE_LINK_TOPO | HW_ENV | SKIP_VPP_PATCH
-| Suite Setup | Run Keywords
-| ... | Configure all DUTs before test | AND
-| ... | Configure all TGs for traffic script | AND
-| ... | Update All Interface Data On All Nodes | ${nodes} | AND
-| ... | Configure DUT nodes for IPv4 testing
-| Test Setup | Run Keywords | Save VPP PIDs | AND
-| ... | Reset VAT History On All DUTs | ${nodes} | AND
-| ... | Clear interface counters on all vpp nodes in topology | ${nodes}
-| Test Teardown | Run Keywords
-| ... | Show packet trace on all DUTs | ${nodes} | AND
-| ... | Show VAT History On All DUTs | ${nodes} | AND
-| ... | Verify VPP PID in Teardown
-| Documentation | *IPv4 routing test cases*
-| ...
-| ... | RFC791 IPv4, RFC826 ARP, RFC792 ICMPv4. Encapsulations: Eth-IPv4-ICMPv4
-| ... | on links TG-DUT1, TG-DUT2, DUT1-DUT2. IPv4 routing tests use circular
-| ... | 3-node topology TG - DUT1 - DUT2 - TG with one link between the nodes.
-| ... | DUT1 and DUT2 are configured with IPv4 routing and static routes. Test
-| ... | ICMPv4 Echo Request packets are sent in both directions by TG on links
-| ... | to DUT1 and DUT2 and received on TG links on the other side of circular
-| ... | topology. On receive TG verifies packets IPv4 src-addr, dst-addr and MAC
-| ... | addresses.
-
-*** Test Cases ***
-
-| TC01: DUT replies to ICMPv4 Echo Req to its ingress interface
-| | [Documentation]
-| | ... | Make TG send ICMPv4 Echo Req to DUT ingress interface. Make TG\
-| | ... | verify ICMP Echo Reply is correct.
-| | [Tags] | VM_ENV
-| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']}
-| | Compute Path
-| | ${src_port} | ${src_node}= | First Interface
-| | ${dst_port} | ${dst_node}= | Last Interface
-| | ${hops}= | Set Variable | ${0}
-| | Route traffic from interface '${src_port}' on node '${src_node}' to interface '${dst_port}' on node '${dst_node}' '${hops}' hops away using IPv4
-
-| TC02: DUT routes IPv4 to its egress interface
-| | [Tags] | VM_ENV
-| | [Documentation]
-| | ... | Make TG send ICMPv4 Echo Req towards DUT1 egress interface\
-| | ... | connected to DUT2. Make TG verify ICMPv4 Echo Reply is correct.
-| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
-| | Compute Path
-| | ${src_port} | ${src_node}= | First Interface
-| | ${dst_port} | ${dst_node}= | Last Egress Interface
-| | ${hops}= | Set Variable | ${0}
-| | Route traffic from interface '${src_port}' on node '${src_node}' to interface '${dst_port}' on node '${dst_node}' '${hops}' hops away using IPv4
-
-| TC03: DUT1 routes IPv4 to DUT2 ingress interface
-| | [Tags] | VM_ENV
-| | [Documentation]
-| | ... | Make TG send ICMPv4 Echo Req towards DUT2 ingress interface\
-| | ... | connected to DUT1. Make TG verify ICMPv4 Echo Reply is correct.
-| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
-| | Compute Path
-| | ${src_port} | ${src_node}= | First Interface
-| | ${dst_port} | ${dst_node}= | Last Interface
-| | ${hops}= | Set Variable | ${1}
-| | Route traffic from interface '${src_port}' on node '${src_node}' to interface '${dst_port}' on node '${dst_node}' '${hops}' hops away using IPv4
-
-| TC04: DUT1 routes IPv4 to DUT2 egress interface
-| | [Tags] | VM_ENV
-| | [Documentation]
-| | ... | Make TG send ICMPv4 Echo Req towards DUT2 egress interface\
-| | ... | connected to TG. Make TG verify ICMPv4 Echo Reply is correct.
-| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | Compute Path
-| | ${src_port} | ${src_node}= | First Interface
-| | ${dst_port} | ${dst_node}= | Last Egress Interface
-| | ${hops}= | Set Variable | ${1}
-| | Route traffic from interface '${src_port}' on node '${src_node}' to interface '${dst_port}' on node '${dst_node}' '${hops}' hops away using IPv4
-
-| TC05: DUT1 and DUT2 route IPv4 between TG interfaces
-| | [Tags] | VM_ENV
-| | [Documentation]
-| | ... | Make TG send ICMPv4 Echo Req between its interfaces across DUT1\
-| | ... | and DUT2. Make TG verify ICMPv4 Echo Replies are correct.
-| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | Compute Path
-| | ${src_port} | ${src_node}= | First Interface
-| | ${dst_port} | ${dst_node}= | Last Interface
-| | ${hops}= | Set Variable | ${2}
-| | Route traffic from interface '${src_port}' on node '${src_node}' to interface '${dst_port}' on node '${dst_node}' '${hops}' hops away using IPv4
-
-| TC06: DUT replies to ICMPv4 Echo Reqs with size 64B-to-1500B-incr-1B
-| | [Tags] | VM_ENV
-| | [Documentation]
-| | ... | Make TG send ICMPv4 Echo Reqs to DUT ingress interface,\
-| | ... | incrementating frame size from 64B to 1500B with increment step
-| | ... | of 1Byte. Make TG verify ICMP Echo Replies are correct.
-| | Execute IPv4 ICMP echo sweep | ${nodes['TG']} | ${nodes['DUT1']} | 0 | 1452 | 1
-
-| TC07: DUT replies to ICMPv4 Echo Reqs with size 1500B-to-9000B-incr-10B
-| | [Documentation]
-| | ... | Make TG send ICMPv4 Echo Reqs to DUT ingress interface,\
-| | ... | incrementating frame size from 1500B to 9000B with increment
-| | ... | step of 10Bytes. Make TG verify ICMPv4 Echo Replies are correct.
-| | [Setup] | Configure MTU on TG based on MTU on DUT | ${nodes['TG']} | ${nodes['DUT1']}
-| | [Teardown] | Run keywords
-| | ... | Set default Ethernet MTU on all interfaces on node | ${nodes['TG']}
-| | ... | AND | Verify VPP PID in Teardown
-| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']}
-| | Compute Path
-| | ${dut_port} | ${dut_node}= | Last Interface
-| | ${mtu}= | Get Interface MTU | ${dut_node} | ${dut_port}
-| | # ICMP payload size is frame size minus size of Ehternet header, FCS,
-| | # IPv4 header and ICMP header
-| | ${end_size}= | Evaluate | ${mtu} - 14 - 4 - 20 - 8
-| | Run Keyword If | ${mtu} > 1518
-| | ... | Execute IPv4 ICMP echo sweep | ${nodes['TG']} | ${nodes['DUT1']}
-| | ... | 1452 | ${end_size} | 10
-
-| TC08: DUT replies to ARP request
-| | [Tags] | VM_ENV | SKIP_VPP_PATCH
-| | [Documentation]
-| | ... | Make TG send ARP Request to DUT and verify ARP Reply is correct.\
-| | Send ARP request and verify response | ${nodes['TG']} | ${nodes['DUT1']}
diff --git a/tests/func/ipv4/eth2p-ethip4-ip4base-ip4arp-func.robot b/tests/func/ipv4/eth2p-ethip4-ip4base-ip4arp-func.robot
deleted file mode 100644
index f6b551e7a3..0000000000
--- a/tests/func/ipv4/eth2p-ethip4-ip4base-ip4arp-func.robot
+++ /dev/null
@@ -1,82 +0,0 @@
-# Copyright (c) 2016 Cisco and/or its affiliates.
-# Licensed under the Apache License, Version 2.0 (the "License");
-# you may not use this file except in compliance with the License.
-# You may obtain a copy of the License at:
-#
-#     http://www.apache.org/licenses/LICENSE-2.0
-#
-# Unless required by applicable law or agreed to in writing, software
-# distributed under the License is distributed on an "AS IS" BASIS,
-# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-# See the License for the specific language governing permissions and
-# limitations under the License.
-
-*** Settings ***
-| Resource | resources/libraries/robot/default.robot
-| Resource | resources/libraries/robot/counters.robot
-| Resource | resources/libraries/robot/interfaces.robot
-| Resource | resources/libraries/robot/testing_path.robot
-| Resource | resources/libraries/robot/ipv4.robot
-| Resource | resources/libraries/robot/l2_xconnect.robot
-| Resource | resources/libraries/robot/traffic.robot
-| Library | resources.libraries.python.Trace
-| Force Tags | HW_ENV | VM_ENV | 3_NODE_SINGLE_LINK_TOPO
-| Test Setup | Set up functional test
-| Test Teardown | Tear down functional test
-| Documentation | *IPv4 ARP test cases*
-| ...
-| ... | RFC826 ARP: Eth-IPv4 and Eth-ARP on links TG-DUT1, TG-DUT2, DUT1-DUT2:
-| ... | IPv4 ARP tests use 3-node topology TG - DUT1 - DUT2 - TG with one link
-| ... | between the nodes. DUT1 and DUT2 are configured with IPv4 routing and
-| ... | static routes. DUT ARP functionality is tested by making TG send ICMPv4
-| ... | Echo Requests towards its other interface via DUT1 and DUT2.
-
-*** Variables ***
-| ${dut1_to_tg_ip}= | 192.168.1.1
-| ${dut1_to_dut2_ip}= | 192.168.2.1
-| ${dut1_to_dut2_ip_GW}= | 192.168.2.2
-| ${test_dst_ip}= | 32.0.0.1
-| ${test_src_ip}= | 16.0.0.1
-| ${prefix_length}= | 24
-
-*** Test Cases ***
-| TC01: DUT sends ARP Request for unresolved locally connected IPv4 address
-| | [Documentation]
-| | ... | Make TG send test packet destined to IPv4 address of its other\
-| | ... | interface connected to DUT2. Make TG verify DUT2 sends ARP
-| | ... | Request for locally connected TG IPv4 address.
-| | Given Configure path in 3-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | And Set interfaces in 3-node circular topology up
-| | And Configure L2XC
-| | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_tg}
-| | When Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
-| | And Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_dut2} | ${dut1_to_dut2_ip} | ${prefix_length}
-| | Then Send packet and verify ARP request | ${tg_node}
-| | ... | ${test_src_ip} | ${dut1_to_dut2_ip_GW} | ${tg_to_dut1}
-| | ... | ${dut1_to_tg_mac} | ${tg_to_dut2} | ${dut1_to_dut2_mac}
-| | ... | ${dut1_to_dut2_ip} | ${dut1_to_dut2_ip_GW}
-
-| TC02: DUT sends ARP Request for route next hop IPv4 address
-| | [Documentation] |
-| | ... | Make TG send test packet destined to IPv4 address matching\
-| | ... | static route on DUT2. Make TG verify DUT2 sends ARP Request for
-| | ... | next hop of the static route.
-| | Given Configure path in 3-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | And Set interfaces in 3-node circular topology up
-| | And Configure L2XC
-| | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_tg}
-| | When Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
-| | And Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_dut2} | ${dut1_to_dut2_ip} | ${prefix_length}
-| | And Vpp Route Add
-| | ... | ${dut1_node} | ${test_dst_ip} | ${prefix_length}
-| | ... | ${dut1_to_dut2_ip_GW} | ${dut1_to_dut2} | resolve_attempts=${NONE}
-| | Then Send packet and verify ARP request | ${tg_node}
-| | ... | ${test_src_ip} | ${test_dst_ip} | ${tg_to_dut1}
-| | ... | ${dut1_to_tg_mac} | ${tg_to_dut2} | ${dut1_to_dut2_mac}
-| | ... | ${dut1_to_dut2_ip} | ${dut1_to_dut2_ip_GW}
diff --git a/tests/func/ipv4/eth2p-ethip4-ip4base-ip4ecmp-func.robot b/tests/func/ipv4/eth2p-ethip4-ip4base-ip4ecmp-func.robot
deleted file mode 100644
index 8c707fc18d..0000000000
--- a/tests/func/ipv4/eth2p-ethip4-ip4base-ip4ecmp-func.robot
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright (c) 2016 Cisco and/or its affiliates.
-# Licensed under the Apache License, Version 2.0 (the "License");
-# you may not use this file except in compliance with the License.
-# You may obtain a copy of the License at:
-#
-#     http://www.apache.org/licenses/LICENSE-2.0
-#
-# Unless required by applicable law or agreed to in writing, software
-# distributed under the License is distributed on an "AS IS" BASIS,
-# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-# See the License for the specific language governing permissions and
-# limitations under the License.
-
-
-*** Settings ***
-| Resource | resources/libraries/robot/default.robot
-| Resource | resources/libraries/robot/counters.robot
-| Resource | resources/libraries/robot/interfaces.robot
-| Resource | resources/libraries/robot/testing_path.robot
-| Resource | resources/libraries/robot/ipv4.robot
-| Resource | resources/libraries/robot/traffic.robot
-| Library | resources.libraries.python.Trace
-| Force Tags | HW_ENV | VM_ENV | 3_NODE_DOUBLE_LINK_TOPO
-| Test Setup | Set up functional test
-| Test Teardown | Tear down functional test
-| Documentation | *Ipv4 Multipath routing test cases*
-| ...
-| ... | *[Top] Network topologies:* TG=DUT 2-node topology with two links\
-| ... | between nodes.
-| ... | *[Cfg] DUT configuration:* On DUT configure interfaces IPv4 adresses,\
-| ... | and multipath routing.
-| ... | *[Ver] TG verification:* Test packets are sent from TG on the first\
-| ... | link to DUT. Packet is received on TG on the second link from DUT1.
-
-
-*** Variables ***
-| ${ip_1}= | 192.168.1.1
-| ${ip_2}= | 192.168.2.1
-| ${test_dst_ip}= | 32.0.0.1
-| ${test_src_ip}= | 16.0.0.1
-| ${prefix_length}= | 24
-| ${neighbor_1_ip}= | 192.168.2.10
-| ${neighbor_1_mac}= | 02:00:00:00:00:02
-| ${neighbor_2_ip}= | 192.168.2.20
-| ${neighbor_2_mac}= | 02:00:00:00:00:03
-
-*** Test Cases ***
-| TC01: IPv4 Equal-cost multipath routing
-| | [Documentation]
-| | ... | [Top] TG=DUT
-| | ... | [Cfg] On DUT configure multipath routing wiht two equal-cost paths.
-| | ... | [Ver] TG sends 100 IPv4 ICMP packets traffic on the first link to\
-| | ... | DUT. On second link to TG verify if traffic is divided into two paths.
-| | Given Configure path in 2-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
-| | And Set interfaces in 2-node circular topology up
-| | And Set Interface Address | ${dut_node}
-| | ... | ${dut_to_tg_if2} | ${ip_1} | ${prefix_length}
-| | And Set Interface Address | ${dut_node}
-| | ... | ${dut_to_tg_if1} | ${ip_2} | ${prefix_length}
-| | And Add Arp On Dut
-| | ... | ${dut_node} | ${dut_to_tg_if1} | ${neighbor_1_ip} | ${neighbor_1_mac}
-| | And Add Arp On Dut
-| | ... | ${dut_node} | ${dut_to_tg_if1} | ${neighbor_2_ip} | ${neighbor_2_mac}
-| | When Vpp Route Add
-| | ... | ${dut_node} | ${test_dst_ip} | ${prefix_length} | ${neighbor_1_ip}
-| | ... | ${dut_to_tg_if1} | resolve_attempts=${NONE} | multipath=${TRUE}
-| | And Vpp Route Add
-| | ... | ${dut_node} | ${test_dst_ip} | ${prefix_length} | ${neighbor_2_ip}
-| | ... | ${dut_to_tg_if1} | resolve_attempts=${NONE} | multipath=${TRUE}
-| | Then Send packets and verify multipath routing | ${tg_node}
-| | ... | ${tg_to_dut_if2} | ${tg_to_dut_if1} | ${test_src_ip} | ${test_dst_ip}
-| | ... | ${tg_to_dut_if2_mac} | ${dut_to_tg_if2_mac} | ${dut_to_tg_if1_mac}
-| | ... | ${neighbor_1_mac} | ${neighbor_2_mac}
diff --git a/tests/func/ipv4/eth2p-ethip4-ip4base-ip4proxyarp-func.robot b/tests/func/ipv4/eth2p-ethip4-ip4base-ip4proxyarp-func.robot
deleted file mode 100644
index afe4581b16..0000000000
--- a/tests/func/ipv4/eth2p-ethip4-ip4base-ip4proxyarp-func.robot
+++ /dev/null
@@ -1,156 +0,0 @@
-# Copyright (c) 2016 Cisco and/or its affiliates.
-# Licensed under the Apache License, Version 2.0 (the "License");
-# you may not use this file except in compliance with the License.
-# You may obtain a copy of the License at:
-#
-#     http://www.apache.org/licenses/LICENSE-2.0
-#
-# Unless required by applicable law or agreed to in writing, software
-# distributed under the License is distributed on an "AS IS" BASIS,
-# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-# See the License for the specific language governing permissions and
-# limitations under the License.
-
-*** Settings ***
-| Resource | resources/libraries/robot/default.robot
-| Resource | resources/libraries/robot/interfaces.robot
-| Resource | resources/libraries/robot/testing_path.robot
-| Resource | resources/libraries/robot/ipv4.robot
-| Resource | resources/libraries/robot/traffic.robot
-| Library | resources.libraries.python.Trace
-| Library | resources.libraries.python.ProxyArp
-| Force Tags | HW_ENV | VM_ENV | 3_NODE_SINGLE_LINK_TOPO
-| Test Setup | Set up functional test
-| Test Teardown | Tear down functional test
-| Documentation | *RFC1027 Proxy ARP test cases*
-| ...
-| ... | *[Top] Network topologies:* TG-DUT1 2-node topology with
-| ... | single link between nodes.
-| ... | *[Cfg] DUT configuration:* DUT1 is configured with Proxy ARP
-| ... | *[Ver] TG verification:* Test ARP Request packet is sent
-| ... | from TG on link to DUT1; on receive TG verifies ARP reply packet
-| ... | for correctness and their IPv4 src-addr, dst-addr and MAC addresses.
-| ... | *[Ref] Applicable standard specifications:* RFC1027.
-
-*** Variables ***
-| ${tg_to_dut1_ip}= | 10.0.0.100
-| ${dut1_to_tg_ip}= | 10.0.0.1
-| ${prefix_length}= | 24
-| ${lo_ip4_addr}= | 192.168.1.2
-| ${hi_ip4_addr}= | 192.168.1.10
-| ${pass_test_ip}= | 192.168.1.5
-| ${pass_test_lo_ip}= | 192.168.1.2
-| ${pass_test_hi_ip}= | 192.168.1.10
-| ${fail_test_lo_ip}= | 192.168.1.1
-| ${fail_test_hi_ip}= | 192.168.1.11
-
-*** Test Cases ***
-| TC01: DUT sends ARP reply on behalf of another machine from the IP range
-| | [Documentation]
-| | ... | [Top] TG-DUT1.
-| | ... | [Ref] RFC1027.
-| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
-| | ... | for IP range.
-| | ... | [Ver] Make TG send ARP request to DUT1 interface,
-| | ... | verify if DUT1 sends correct ARP reply on behalf of machine which
-| | ... | IP is in range.
-| | Given Configure path in 3-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | And Set interfaces in 3-node circular topology up
-| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
-| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
-| | When Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
-| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
-| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
-| | Then Send ARP Request | ${tg_node} | ${tg_to_dut1_name}
-| | ...                   | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
-| | ...                   | ${tg_to_dut1_ip} | ${pass_test_ip}
-
-| TC02: DUT sends ARP reply on behalf of another machine from beginning of the IP range
-| | [Documentation]
-| | ... | [Top] TG-DUT1.
-| | ... | [Ref] RFC1027.
-| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
-| | ... | for IP range.
-| | ... | [Ver] Make TG send ARP request to DUT1 interface,
-| | ... | verify if DUT1 sends correct ARP reply on behalf of machine which
-| | ... | IP is from beginning of the IP range.
-| | Given Configure path in 3-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | And Set interfaces in 3-node circular topology up
-| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
-| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
-| | When Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
-| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
-| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
-| | Then Send ARP Request | ${tg_node} | ${tg_to_dut1_name}
-| | ...                   | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
-| | ...                   | ${tg_to_dut1_ip} | ${pass_test_lo_ip}
-
-| TC03: DUT sends ARP reply on behalf of another machine from end of the IP range
-| | [Documentation]
-| | ... | [Top] TG-DUT1.
-| | ... | [Ref] RFC1027.
-| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
-| | ... | for IP range.
-| | ... | [Ver] Make TG send ARP request to DUT1 interface,
-| | ... | verify if DUT1 sends correct ARP reply on behalf of machine which
-| | ... | IP is from end of the IP range.
-| | Given Configure path in 3-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | And Set interfaces in 3-node circular topology up
-| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
-| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
-| | When Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
-| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
-| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
-| | Then Send ARP Request | ${tg_node} | ${tg_to_dut1_name}
-| | ...                   | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
-| | ...                   | ${tg_to_dut1_ip} | ${pass_test_hi_ip}
-
-| TC04: DUT does not send ARP reply on behalf of another machine from below of the IP range
-| | [Documentation]
-| | ... | [Top] TG-DUT1.
-| | ... | [Ref] RFC1027.
-| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
-| | ... | for IP range.
-| | ... | [Ver] Make TG send ARP request to DUT1 interface,
-| | ... | verify if DUT1 does not send ARP reply on behalf of machine which
-| | ... | IP is from below of the IP range.
-| | Given Configure path in 3-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | And Set interfaces in 3-node circular topology up
-| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
-| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
-| | When Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
-| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
-| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
-| | Then ARP request should fail | ${tg_node} | ${tg_to_dut1_name}
-| | ...                                 | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
-| | ...                                 | ${tg_to_dut1_ip} | ${fail_test_lo_ip}
-
-| TC05: DUT does not send ARP reply on behalf of another machine from above of the IP range
-| | [Documentation]
-| | ... | [Top] TG-DUT1.
-| | ... | [Ref] RFC1027.
-| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
-| | ... | for IP range.
-| | ... | [Ver] Make TG send ARP request to DUT1 interface,
-| | ... | verify if DUT1 does not send ARP reply on behalf of machine which
-| | ... | IP is from above of the IP range.
-| | Given Configure path in 3-node circular topology
-| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
-| | And Set interfaces in 3-node circular topology up
-| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
-| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
-| | When Set Interface Address | ${dut1_node}
-| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
-| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
-| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
-| | Then ARP request should fail | ${tg_node} | ${tg_to_dut1_name}
-| | ...                                 | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
-| | ...                                 | ${tg_to_dut1_ip} | ${fail_test_hi_ip}