CSIT-220: Rename directories in tests directory

- Move performance directory one level up and rename it to “perf”
- Rename “suites” directory to “func”
- Create __init__.py in “perf” directory
- Rename fds_related_tests to fds

Change-Id: I59f06afe1c5b95dd8a48417b8fbfd1fca8797097
Signed-off-by: Matej Klotton <mklotton@cisco.com>

3 files changed, 388 insertions, 0 deletions

diff --git a/tests/func/ipv4/ipv4_arp_untagged.robot b/tests/func/ipv4/ipv4_arp_untagged.robot
new file mode 100644
index 0000000000..5bec624262
--- /dev/null
+++ b/tests/func/ipv4/ipv4_arp_untagged.robot
@@ -0,0 +1,86 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/counters.robot
+| Resource | resources/libraries/robot/interfaces.robot
+| Resource | resources/libraries/robot/testing_path.robot
+| Resource | resources/libraries/robot/ipv4.robot
+| Resource | resources/libraries/robot/l2_xconnect.robot
+| Resource | resources/libraries/robot/traffic.robot
+| Library | resources.libraries.python.Trace
+
+| Force Tags | HW_ENV | VM_ENV | 3_NODE_SINGLE_LINK_TOPO
+| Suite Setup | Run Keywords | Setup all TGs before traffic script
+| ...         | AND          | Update All Interface Data On All Nodes | ${nodes}
+| Test Setup | Setup all DUTs before test
+| Test Teardown | Run Keywords | Show packet trace on all DUTs | ${nodes}
+| ...           | AND          | Show vpp trace dump on all DUTs
+| Documentation | *IPv4 ARP test cases*
+| ...
+| ... | RFC826 ARP: Eth-IPv4 and Eth-ARP on links TG-DUT1, TG-DUT2, DUT1-DUT2:
+| ... | IPv4 ARP tests use 3-node topology TG - DUT1 - DUT2 - TG with one link
+| ... | between the nodes. DUT1 and DUT2 are configured with IPv4 routing and
+| ... | static routes. DUT ARP functionality is tested by making TG send ICMPv4
+| ... | Echo Requests towards its other interface via DUT1 and DUT2.
+
+*** Variables ***
+| ${dut1_to_tg_ip}= | 192.168.1.1
+| ${dut1_to_dut2_ip}= | 192.168.2.1
+| ${dut1_to_dut2_ip_GW}= | 192.168.2.2
+| ${test_dst_ip}= | 32.0.0.1
+| ${test_src_ip}= | 16.0.0.1
+| ${prefix_length}= | 24
+
+*** Test Cases ***
+| TC01: DUT sends ARP Request for unresolved locally connected IPv4 address
+| | [Documentation]
+| | ... | Make TG send test packet destined to IPv4 address of its other\
+| | ... | interface connected to DUT2. Make TG verify DUT2 sends ARP
+| | ... | Request for locally connected TG IPv4 address.
+| | Given Path for 3-node testing is set
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in 3-node path are up
+| | And L2 setup xconnect on DUT
+| | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_tg}
+| | When Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
+| | And Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_dut2} | ${dut1_to_dut2_ip} | ${prefix_length}
+| | Then Send Packet And Check ARP Request | ${tg_node}
+| | ... | ${test_src_ip} | ${dut1_to_dut2_ip_GW} | ${tg_to_dut1}
+| | ... | ${dut1_to_tg_mac} | ${tg_to_dut2} | ${dut1_to_dut2_mac}
+| | ... | ${dut1_to_dut2_ip} | ${dut1_to_dut2_ip_GW}
+
+| TC02: DUT sends ARP Request for route next hop IPv4 address
+| | [Documentation] |
+| | ... | Make TG send test packet destined to IPv4 address matching\
+| | ... | static route on DUT2. Make TG verify DUT2 sends ARP Request for
+| | ... | next hop of the static route.
+| | Given Path for 3-node testing is set
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in 3-node path are up
+| | And L2 setup xconnect on DUT
+| | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_tg}
+| | When Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
+| | And Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_dut2} | ${dut1_to_dut2_ip} | ${prefix_length}
+| | And Vpp Route Add
+| | ... | ${dut1_node} | ${test_dst_ip} | ${prefix_length}
+| | ... | ${dut1_to_dut2_ip_GW} | ${dut1_to_dut2} | resolve_attempts=${NONE}
+| | Then Send Packet And Check ARP Request | ${tg_node}
+| | ... | ${test_src_ip} | ${test_dst_ip} | ${tg_to_dut1}
+| | ... | ${dut1_to_tg_mac} | ${tg_to_dut2} | ${dut1_to_dut2_mac}
+| | ... | ${dut1_to_dut2_ip} | ${dut1_to_dut2_ip_GW}
diff --git a/tests/func/ipv4/ipv4_proxy_arp_untagged.robot b/tests/func/ipv4/ipv4_proxy_arp_untagged.robot
new file mode 100644
index 0000000000..716a84b900
--- /dev/null
+++ b/tests/func/ipv4/ipv4_proxy_arp_untagged.robot
@@ -0,0 +1,158 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/interfaces.robot
+| Resource | resources/libraries/robot/testing_path.robot
+| Resource | resources/libraries/robot/ipv4.robot
+| Resource | resources/libraries/robot/traffic.robot
+| Library | resources.libraries.python.Trace
+| Library | resources.libraries.python.ProxyArp
+| Force Tags | HW_ENV | VM_ENV | 3_NODE_SINGLE_LINK_TOPO
+| Suite Setup | Run Keywords | Setup all TGs before traffic script
+| ...         | AND          | Update All Interface Data On All Nodes | ${nodes}
+| Test Setup | Setup all DUTs before test
+| Test Teardown | Show packet trace on all DUTs | ${nodes}
+| Documentation | *RFC1027 Proxy ARP test cases*
+| ...
+| ... | *[Top] Network topologies:* TG-DUT1 2-node topology with
+| ... | single link between nodes.
+| ... | *[Cfg] DUT configuration:* DUT1 is configured with Proxy ARP
+| ... | *[Ver] TG verification:* Test ARP Request packet is sent
+| ... | from TG on link to DUT1; on receive TG verifies ARP reply packet
+| ... | for correctness and their IPv4 src-addr, dst-addr and MAC addresses.
+| ... | *[Ref] Applicable standard specifications:* RFC1027.
+
+*** Variables ***
+| ${tg_to_dut1_ip}= | 10.0.0.100
+| ${dut1_to_tg_ip}= | 10.0.0.1
+| ${prefix_length}= | 24
+| ${lo_ip4_addr}= | 192.168.1.2
+| ${hi_ip4_addr}= | 192.168.1.10
+| ${pass_test_ip}= | 192.168.1.5
+| ${pass_test_lo_ip}= | 192.168.1.2
+| ${pass_test_hi_ip}= | 192.168.1.10
+| ${fail_test_lo_ip}= | 192.168.1.1
+| ${fail_test_hi_ip}= | 192.168.1.11
+
+*** Test Cases ***
+| TC01: DUT sends ARP reply on behalf of another machine from the IP range
+| | [Documentation]
+| | ... | [Top] TG-DUT1.
+| | ... | [Ref] RFC1027.
+| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
+| | ... | for IP range.
+| | ... | [Ver] Make TG send ARP request to DUT1 interface,
+| | ... | verify if DUT1 sends correct ARP reply on behalf of machine which
+| | ... | IP is in range.
+| | Given Path for 3-node testing is set
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in 3-node path are up
+| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
+| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
+| | When Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
+| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
+| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
+| | Then Send ARP Request | ${tg_node} | ${tg_to_dut1_name}
+| | ...                   | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
+| | ...                   | ${tg_to_dut1_ip} | ${pass_test_ip}
+
+| TC02: DUT sends ARP reply on behalf of another machine from beginning of the IP range
+| | [Documentation]
+| | ... | [Top] TG-DUT1.
+| | ... | [Ref] RFC1027.
+| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
+| | ... | for IP range.
+| | ... | [Ver] Make TG send ARP request to DUT1 interface,
+| | ... | verify if DUT1 sends correct ARP reply on behalf of machine which
+| | ... | IP is from beginning of the IP range.
+| | Given Path for 3-node testing is set
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in 3-node path are up
+| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
+| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
+| | When Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
+| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
+| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
+| | Then Send ARP Request | ${tg_node} | ${tg_to_dut1_name}
+| | ...                   | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
+| | ...                   | ${tg_to_dut1_ip} | ${pass_test_lo_ip}
+
+| TC03: DUT sends ARP reply on behalf of another machine from end of the IP range
+| | [Documentation]
+| | ... | [Top] TG-DUT1.
+| | ... | [Ref] RFC1027.
+| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
+| | ... | for IP range.
+| | ... | [Ver] Make TG send ARP request to DUT1 interface,
+| | ... | verify if DUT1 sends correct ARP reply on behalf of machine which
+| | ... | IP is from end of the IP range.
+| | Given Path for 3-node testing is set
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in 3-node path are up
+| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
+| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
+| | When Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
+| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
+| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
+| | Then Send ARP Request | ${tg_node} | ${tg_to_dut1_name}
+| | ...                   | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
+| | ...                   | ${tg_to_dut1_ip} | ${pass_test_hi_ip}
+
+| TC04: DUT does not send ARP reply on behalf of another machine from below of the IP range
+| | [Documentation]
+| | ... | [Top] TG-DUT1.
+| | ... | [Ref] RFC1027.
+| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
+| | ... | for IP range.
+| | ... | [Ver] Make TG send ARP request to DUT1 interface,
+| | ... | verify if DUT1 does not send ARP reply on behalf of machine which
+| | ... | IP is from below of the IP range.
+| | Given Path for 3-node testing is set
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in 3-node path are up
+| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
+| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
+| | When Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
+| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
+| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
+| | Then Send ARP Request should failed | ${tg_node} | ${tg_to_dut1_name}
+| | ...                                 | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
+| | ...                                 | ${tg_to_dut1_ip} | ${fail_test_lo_ip}
+
+| TC05: DUT does not send ARP reply on behalf of another machine from above of the IP range
+| | [Documentation]
+| | ... | [Top] TG-DUT1.
+| | ... | [Ref] RFC1027.
+| | ... | [Cfg] On DUT1 configure interface IPv4 address and proxy ARP
+| | ... | for IP range.
+| | ... | [Ver] Make TG send ARP request to DUT1 interface,
+| | ... | verify if DUT1 does not send ARP reply on behalf of machine which
+| | ... | IP is from above of the IP range.
+| | Given Path for 3-node testing is set
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | And Interfaces in 3-node path are up
+| | ${dut1_to_tg_name}= | Get interface name | ${dut1_node} | ${dut1_to_tg}
+| | ${tg_to_dut1_name}= | Get interface name | ${tg_node} | ${tg_to_dut1}
+| | When Set Interface Address | ${dut1_node}
+| | ... | ${dut1_to_tg} | ${dut1_to_tg_ip} | ${prefix_length}
+| | And Vpp Add Proxy ARP | ${dut1_node} | ${lo_ip4_addr} | ${hi_ip4_addr}
+| | And Vpp Proxy ARP Interface Enable | ${dut1_node} | ${dut1_to_tg_name}
+| | Then Send ARP Request should failed | ${tg_node} | ${tg_to_dut1_name}
+| | ...                                 | ${tg_to_dut1_mac} | ${dut1_to_tg_mac}
+| | ...                                 | ${tg_to_dut1_ip} | ${fail_test_hi_ip}
diff --git a/tests/func/ipv4/ipv4_untagged.robot b/tests/func/ipv4/ipv4_untagged.robot
new file mode 100644
index 0000000000..3b6716d858
--- /dev/null
+++ b/tests/func/ipv4/ipv4_untagged.robot
@@ -0,0 +1,144 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Library | resources.libraries.python.NodePath
+| Library | resources.libraries.python.Trace
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/interfaces.robot
+| Resource | resources/libraries/robot/ipv4.robot
+| Force Tags | HW_ENV
+| Suite Setup | Run Keywords | Setup all DUTs before test
+| ...         | AND          | Setup all TGs before traffic script
+| ...         | AND          | Update All Interface Data On All Nodes | ${nodes}
+| ...         | AND          | Setup DUT nodes for IPv4 testing
+| Test Setup | Clear interface counters on all vpp nodes in topology | ${nodes}
+| Test Teardown | Run Keyword If Test Failed | Show packet trace on all DUTs | ${nodes}
+| ...           | AND                        | Show vpp trace dump on all DUTs
+| Documentation | *IPv4 routing test cases*
+| ...
+| ... | RFC791 IPv4, RFC826 ARP, RFC792 ICMPv4. Encapsulations: Eth-IPv4-ICMPv4
+| ... | on links TG-DUT1, TG-DUT2, DUT1-DUT2. IPv4 routing tests use circular
+| ... | 3-node topology TG - DUT1 - DUT2 - TG with one link between the nodes.
+| ... | DUT1 and DUT2 are configured with IPv4 routing and static routes. Test
+| ... | ICMPv4 Echo Request packets are sent in both directions by TG on links
+| ... | to DUT1 and DUT2 and received on TG links on the other side of circular
+| ... | topology. On receive TG verifies packets IPv4 src-addr, dst-addr and MAC
+| ... | addresses.
+
+*** Test Cases ***
+
+| TC01: DUT replies to ICMPv4 Echo Req to its ingress interface
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req to DUT ingress interface. Make TG\
+| | ... | verify ICMP Echo Reply is correct.
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO | VM_ENV
+| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']}
+| | Compute Path
+| | ${src_port} | ${src_node}= | First Interface
+| | ${dst_port} | ${dst_node}= | Last Interface
+| | ${hops}= | Set Variable | ${0}
+| | Node "${src_node}" interface "${src_port}" can route to node "${dst_node}" interface "${dst_port}" ${hops} hops away using IPv4
+
+| TC02: DUT routes IPv4 to its egress interface
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req towards DUT1 egress interface\
+| | ... | connected to DUT2. Make TG verify ICMPv4 Echo Reply is correct.
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO | VM_ENV
+| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
+| | Compute Path
+| | ${src_port} | ${src_node}= | First Interface
+| | ${dst_port} | ${dst_node}= | Last Egress Interface
+| | ${hops}= | Set Variable | ${0}
+| | Node "${src_node}" interface "${src_port}" can route to node "${dst_node}" interface "${dst_port}" ${hops} hops away using IPv4
+
+| TC03: DUT1 routes IPv4 to DUT2 ingress interface
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req towards DUT2 ingress interface\
+| | ... | connected to DUT1. Make TG verify ICMPv4 Echo Reply is correct.
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO | VM_ENV
+| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
+| | Compute Path
+| | ${src_port} | ${src_node}= | First Interface
+| | ${dst_port} | ${dst_node}= | Last Interface
+| | ${hops}= | Set Variable | ${1}
+| | Node "${src_node}" interface "${src_port}" can route to node "${dst_node}" interface "${dst_port}" ${hops} hops away using IPv4
+
+| TC04: DUT1 routes IPv4 to DUT2 egress interface
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req towards DUT2 egress interface\
+| | ... | connected to TG. Make TG verify ICMPv4 Echo Reply is correct.
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO | VM_ENV
+| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | Compute Path
+| | ${src_port} | ${src_node}= | First Interface
+| | ${dst_port} | ${dst_node}= | Last Egress Interface
+| | ${hops}= | Set Variable | ${1}
+| | Node "${src_node}" interface "${src_port}" can route to node "${dst_node}" interface "${dst_port}" ${hops} hops away using IPv4
+
+| TC05: DUT1 and DUT2 route IPv4 between TG interfaces
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req between its interfaces across DUT1\
+| | ... | and DUT2. Make TG verify ICMPv4 Echo Replies are correct.
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO | VM_ENV
+| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
+| | Compute Path
+| | ${src_port} | ${src_node}= | First Interface
+| | ${dst_port} | ${dst_node}= | Last Interface
+| | ${hops}= | Set Variable | ${2}
+| | Node "${src_node}" interface "${src_port}" can route to node "${dst_node}" interface "${dst_port}" ${hops} hops away using IPv4
+| | ${port} | ${node}= | Next Interface
+| | ${port} | ${node}= | Next Interface
+| | ${exp_counter_val}= | Set Variable | ${1}
+| | Vpp dump stats table | ${node}
+| | Check ipv4 interface counter | ${node} | ${port} | ${exp_counter_val}
+| | ${port} | ${node}= | Next Interface
+| | Check ipv4 interface counter | ${node} | ${port} | ${exp_counter_val}
+| | ${port} | ${node}= | Next Interface
+| | Vpp dump stats table | ${node}
+| | Check ipv4 interface counter | ${node} | ${port} | ${exp_counter_val}
+| | ${port} | ${node}= | Next Interface
+| | Check ipv4 interface counter | ${node} | ${port} | ${exp_counter_val}
+
+| TC06: DUT replies to ICMPv4 Echo Reqs with size 64B-to-1500B-incr-1B
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Reqs to DUT ingress interface,\
+| | ... | incrementating frame size from 64B to 1500B with increment step
+| | ... | of 1Byte. Make TG verify ICMP Echo Replies are correct.
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO | VM_ENV
+| | Ipv4 icmp echo sweep | ${nodes['TG']} | ${nodes['DUT1']} | 0 | 1452 | 1
+
+| TC07: DUT replies to ICMPv4 Echo Reqs with size 1500B-to-9000B-incr-10B
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Reqs to DUT ingress interface,\
+| | ... | incrementating frame size from 1500B to 9000B with increment
+| | ... | step of 10Bytes. Make TG verify ICMPv4 Echo Replies are correct.
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO
+| | [Setup] | Setup MTU on TG based on MTU on DUT | ${nodes['TG']} | ${nodes['DUT1']}
+| | [Teardown] | Set default Ethernet MTU on all interfaces on node | ${nodes['TG']}
+| | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']}
+| | Compute Path
+| | ${dut_port} | ${dut_node}= | Last Interface
+| | ${mtu}= | Get Interface MTU | ${dut_node} | ${dut_port}
+| | # ICMP payload size is frame size minus size of Ehternet header, FCS,
+| | # IPv4 header and ICMP header
+| | ${end_size}= | Evaluate | ${mtu} - 14 - 4 - 20 - 8
+| | Run Keyword If | ${mtu} > 1518
+| | ... | Ipv4 icmp echo sweep | ${nodes['TG']} | ${nodes['DUT1']}
+| | ... | 1452 | ${end_size} | 10
+
+| TC08: DUT replies to ARP request
+| | [Documentation]
+| | ... | Make TG send ARP Request to DUT and verify ARP Reply is correct.\
+| | [Tags] | 3_NODE_SINGLE_LINK_TOPO | VM_ENV
+| | Send ARP request and validate response | ${nodes['TG']} | ${nodes['DUT1']}