Add Honeycomb bridge domain management tests

JIRA: CSIT-41, CSIT-42, CSIT-43

 - add test cases for Honecomb bridge domain management
 - add keywords used by these tests
 - prefix the names of Honeycomb test suites with numbers, so that they
   execute in a specific order
 - moved suite teardown with "Stop Honeycomb service" to bridge domain
   suite

Note: Due to time constraints, the Honeycomb service cannot be restarted
between executions of individual Honeycomb test suites. Therefore
Honeycomb will be setup in the first test suite and shut down after the
last one.

Change-Id: I36b7f8335e5ba54985da5bd83730cf856d5ab48b
Signed-off-by: selias <samelias@cisco.com>

1 files changed, 100 insertions, 0 deletions

diff --git a/tests/suites/honeycomb/1 - interface_management.robot b/tests/suites/honeycomb/1 - interface_management.robot
new file mode 100644
index 0000000000..50eaa4edeb
--- /dev/null
+++ b/tests/suites/honeycomb/1 - interface_management.robot
@@ -0,0 +1,100 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Variables ***
+# Node and interface to run tests on.
+| ${node}= | ${nodes['DUT1']}
+| ${interface}= | ${node['interfaces'].values()[0]['name']}
+# Configuration which will be set and verified during tests.
+| @{ipv4_address}= | 192.168.0.2 | 255.255.255.0
+| @{ipv4_neighbor}= | 192.168.0.3 | 08:00:27:c0:5d:37
+| &{ipv4_settings}= | enabled=${True} | forwarding=${True} | mtu=9000
+| @{ipv6_address}= | 10::10 | 64
+| @{ipv6_neighbor}= | 10::11 | 08:00:27:c0:5d:37
+| &{ipv6_settings}= | enabled=${True} | forwarding=${True} | mtu=9000
+| ... | dup-addr-detect-transmits=5
+| &{ethernet}= | mtu=9000
+| &{routing}= | vrf-id=27
+| &{vxlan_settings}= | src=10.0.1.20 | dst=10.0.3.20 | vni=1000
+| ... | encap-vrf-id=1000
+
+*** Settings ***
+| Resource | resources/libraries/robot/default.robot
+| Resource | resources/libraries/robot/honeycomb/honeycomb.robot
+| Resource | resources/libraries/robot/honeycomb/interfaces.robot
+| Suite Setup | Run keywords | Setup all DUTs before test | AND
+| ... | Setup Honeycomb service on DUTs | ${node}
+| Documentation | *Honeycomb interface management test suite.*
+| ...
+| ... | Test suite uses the first interface of the first DUT node.
+
+*** Test Cases ***
+| Honeycomb configures and reads interface state
+| | [Documentation] | Check if Honeycomb API can modify the admin state of\
+| | ... | VPP interfaces.
+| | [Tags] | honeycomb_sanity
+| | Given Interface state is | ${node} | ${interface} | down
+| | When Honeycomb sets interface state | ${node} | ${interface} | up
+| | Then Interface state from Honeycomb should be
+| | ... | ${node} | ${interface} | up
+| | And Interface state from VAT should be | ${node} | ${interface} | up
+| | When Honeycomb sets interface state | ${node} | ${interface} | down
+| | Then Interface state from Honeycomb should be
+| | ... | ${node} | ${interface} | down
+| | And Interface state from VAT should be | ${node} | ${interface} | down
+
+| Honeycomb modifies interface configuration - ipv4
+| | [Documentation] | Check if Honeycomb API can configure interfaces for ipv4.
+| | [Tags] | honeycomb_sanity
+| | When Honeycomb sets interface ipv4 configuration
+| | ... | ${node} | ${interface} | @{ipv4_address} | @{ipv4_neighbor}
+| | ... | ${ipv4_settings}
+| | Then IPv4 config from Honeycomb should be
+| | ... | ${node} | ${interface} | @{ipv4_address} | @{ipv4_neighbor}
+| | ... | ${ipv4_settings}
+| | And IPv4 config from VAT should be
+| | ... | ${node} | ${interface} | @{ipv4_address}
+
+| Honeycomb modifies interface configuration - ipv6
+| | [Documentation] | Check if Honeycomb API can configure interfaces for ipv6.
+| | [Tags] | honeycomb_sanity
+| | When Honeycomb sets interface ipv6 configuration
+| | ... | ${node} | ${interface} | @{ipv6_address} | @{ipv6_neighbor}
+| | ... | ${ipv6_settings}
+| | Then IPv6 config from Honeycomb should be
+| | ... | ${node} | ${interface} | @{ipv6_address} | @{ipv6_neighbor}
+| | ... | ${ipv6_settings}
+| | And IPv6 config from VAT should be
+| | ... | ${node} | ${interface} | @{ipv6_address}
+
+| Honeycomb modifies interface configuration - ethernet,routing
+| | [Documentation] | Check if Honeycomb API can configure interface ethernet\
+| | ... | and routing settings.
+| | [Tags] | honeycomb_sanity
+| | When Honeycomb sets interface ethernet and routing configuration
+| | ... | ${node} | ${interface} | ${ethernet} | ${routing}
+| | Then Interface ethernet and routing configuration from Honeycomb should be
+| | ... | ${node} | ${interface} | ${ethernet} | ${routing}
+| | And Interface ethernet and routing configuration from VAT should be
+| | ... | ${node} | ${interface} | ${ethernet['mtu']} | ${routing['vrf-id']}
+
+| Honeycomb modifies interface configuration - VxLAN
+| | [Documentation] | Check if Honeycomb API can configure interface VxLAN \
+| | ... | settings.
+| | [Tags] | honeycomb_sanity
+| | When Honeycomb sets interface VxLAN configuration
+| | ... | ${node} | ${interface} | &{vxlan_settings}
+| | Then VxLAN configuration from Honeycomb should be
+| | ... | ${node} | ${interface} | &{vxlan_settings}
+| | And VxLAN configuration from VAT should be
+| | ... | ${node} | ${interface} | &{vxlan_settings}