VPP_Device - add baseline tests - part I

CSIT-1370

Add following baseline tests to VPP_Device:
- ip4
  eth2p-ethip4-ip4base-dev
- ip6
  eth2p-ethip6-ip6base-dev
- l2bd
  eth2p-eth-l2bdbasemaclrn-dev

Change-Id: Ic20000eb38c5511c27d020f3aa76b2620d7f7ef9
Signed-off-by: Jan Gelety <jgelety@cisco.com>

4 files changed, 345 insertions, 12 deletions

diff --git a/tests/vpp/device/ip4/eth2p-ethip4-ip4base-dev.robot b/tests/vpp/device/ip4/eth2p-ethip4-ip4base-dev.robot
new file mode 100644
index 0000000000..4ae23528f6
--- /dev/null
+++ b/tests/vpp/device/ip4/eth2p-ethip4-ip4base-dev.robot
@@ -0,0 +1,121 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/ip/ip4.robot
+| Resource | resources/libraries/robot/shared/default.robot
+| Resource | resources/libraries/robot/shared/interfaces.robot
+| Resource | resources/libraries/robot/shared/traffic.robot
+| ...
+| Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
+| ... | FUNCTEST | IP4FWD | BASE | ETH | IP4BASE
+| ...
+| Test Setup | Set up VPP device test
+| ...
+| Test Teardown | Tear down VPP device test
+| ...
+| Documentation | *IPv4 routing test cases*
+| ...
+| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
+| ... | with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for IPv4 routing on both\
+| ... | links.
+| ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and two\
+| ... | static IPv4 /24 route entries.
+| ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in\
+| ... | one direction by TG on links to DUT1; on receive TG verifies packets\
+| ... | for correctness and their IPv4 src-addr, dst-addr and MAC addresses.
+| ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
+
+*** Variables ***
+| ${tg_to_dut_if1_ip4}= | 10.10.10.2
+| ${tg_to_dut_if2_ip4}= | 20.20.20.2
+| ${dut_to_tg_if1_ip4}= | 10.10.10.1
+| ${dut_to_tg_if2_ip4}= | 20.20.20.1
+| ${remote_host1_ip4}= | 192.168.0.1
+| ${remote_host2_ip4}= | 192.168.0.2
+| ${remote_host_ip4_prefix}= | 32
+
+*** Test Cases ***
+| tc01-eth2p-ethicmpv4-ip4base-device_echo-req-to-dut-ingress-interface
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req to DUT1 ingress interface. Make TG\
+| | ... | verify ICMP Echo Reply is correct.
+| | ...
+| | ${hops}= | Set Variable | ${0}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv4 forwarding in circular topology | ${tg_to_dut_if1_ip4}
+| | ... | ${tg_to_dut_if2_ip4} | ${dut_to_tg_if1_ip4} | ${dut_to_tg_if2_ip4}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv4 ping packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${dut_node} | ${dut_to_tg_if1}
+| | ... | ${tg_to_dut_if1_ip4} | ${dut_to_tg_if1_ip4} | ${dut_to_tg_if1_mac}
+| | ... | ${hops}
+
+| tc02-eth2p-ethicmpv4-ip4base-device_echo-req-to-dut-egress-interface
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req towards DUT1 egress interface. Make TG\
+| | ... | verify ICMP Echo Reply is correct.
+| | ...
+| | ${hops}= | Set Variable | ${0}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv4 forwarding in circular topology | ${tg_to_dut_if1_ip4}
+| | ... | ${tg_to_dut_if2_ip4} | ${dut_to_tg_if1_ip4} | ${dut_to_tg_if2_ip4}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv4 ping packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${dut_node} | ${dut_to_tg_if2}
+| | ... | ${tg_to_dut_if1_ip4} | ${dut_to_tg_if2_ip4} | ${dut_to_tg_if1_mac}
+| | ... | ${hops}
+
+| tc03-eth2p-ethicmpv4-ip4base-device_echo-req-to-tg-interface-for-local-ipv4-address
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req between its interfaces across DUT1 for\
+| | ... | locally connected IPv4 addresses. Make TG verify ICMPv4 Echo Replies\
+| | ... | are correct.
+| | ...
+| | ${hops}= | Set Variable | ${1}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv4 forwarding in circular topology | ${tg_to_dut_if1_ip4}
+| | ... | ${tg_to_dut_if2_ip4} | ${dut_to_tg_if1_ip4} | ${dut_to_tg_if2_ip4}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv4 ping packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${tg_node} | ${tg_to_dut_if2}
+| | ... | ${tg_to_dut_if1_ip4} | ${tg_to_dut_if2_ip4} | ${dut_to_tg_if1_mac}
+| | ... | ${hops}
+
+| tc04-eth2p-ethicmpv4-ip4base-device_echo-req-to-tg-interface-for-remote-host-ipv4-address
+| | [Documentation]
+| | ... | Make TG send ICMPv4 Echo Req between its interfaces across DUT1 for\
+| | ... | remote host IPv4 addresses. Make TG verify ICMPv4 Echo Replies are\
+| | ... | correct.
+| | ...
+| | ${hops}= | Set Variable | ${1}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv4 forwarding in circular topology | ${tg_to_dut_if1_ip4}
+| | ... | ${tg_to_dut_if2_ip4} | ${dut_to_tg_if1_ip4} | ${dut_to_tg_if2_ip4}
+| | ... | remote_host1_ip4=${remote_host1_ip4}
+| | ... | remote_host2_ip4=${remote_host2_ip4}
+| | ... | remote_host_ip4_prefix=${remote_host_ip4_prefix}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv4 ping packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${tg_node} | ${tg_to_dut_if2}
+| | ... | ${remote_host1_ip4} | ${remote_host2_ip4} | ${dut_to_tg_if1_mac}
+| | ... | ${hops}
diff --git a/tests/vpp/device/ip6/eth2p-ethip6-ip6base-dev.robot b/tests/vpp/device/ip6/eth2p-ethip6-ip6base-dev.robot
new file mode 100644
index 0000000000..c045acd06b
--- /dev/null
+++ b/tests/vpp/device/ip6/eth2p-ethip6-ip6base-dev.robot
@@ -0,0 +1,125 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/ip/ip6.robot
+| Resource | resources/libraries/robot/shared/default.robot
+| Resource | resources/libraries/robot/shared/interfaces.robot
+| Resource | resources/libraries/robot/shared/traffic.robot
+| ...
+| Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
+| ... | FUNCTEST | IP6FWD | BASE | ETH | IP6BASE
+| ...
+| Test Setup | Set up VPP device test
+| ...
+| Test Teardown | Tear down VPP device test
+| ...
+| Documentation | *IPv6 routing test cases*
+| ...
+| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
+| ... | with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv6-ICMPv6 for IPv6 routing on both\
+| ... | links.
+| ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv6 routing and two\
+| ... | static IPv6 /64 route entries.
+| ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent in\
+| ... | one direction by TG on links to DUT1; on receive TG verifies packets\
+| ... | for correctness and their IPv6 src-addr, dst-addr and MAC addresses.
+| ... | *[Ref] Applicable standard specifications:* RFC2460, RFC4443, RFC4861
+
+*** Variables ***
+| ${tg_to_dut_if1_ip6}= | 2001:1::2
+| ${tg_to_dut_if2_ip6}= | 2001:2::2
+| ${dut_to_tg_if1_ip6}= | 2001:1::1
+| ${dut_to_tg_if2_ip6}= | 2001:2::1
+| ${remote_host1_ip6}= | 3ffe:5f::1
+| ${remote_host2_ip6}= | 3ffe:5f::2
+| ${remote_host_ip6_prefix}= | 128
+
+*** Test Cases ***
+| tc01-eth2p-ethicmpv6-ip6base-device_echo-req-to-dut-ingress-interface
+| | [Documentation]
+| | ... | Make TG send ICMPv6 Echo Req to DUT1 ingress interface. Make TG\
+| | ... | verify ICMPv6 Echo Reply is correct.
+| | ...
+| | ${hops}= | Set Variable | ${0}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv6 forwarding in circular topology | ${tg_to_dut_if1_ip6}
+| | ... | ${tg_to_dut_if2_ip6} | ${dut_to_tg_if1_ip6} | ${dut_to_tg_if2_ip6}
+| | And Suppress ICMPv6 router advertisement message | ${nodes}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv6 echo request packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${dut_node} | ${dut_to_tg_if1}
+| | ... | ${tg_to_dut_if1_ip6} | ${dut_to_tg_if1_ip6} | ${dut_to_tg_if1_mac}
+| | ... | ${hops}
+
+| tc02-eth2p-ethicmpv6-ip6base-device_echo-req-to-dut-egress-interface
+| | [Documentation]
+| | ... | Make TG send ICMPv6 Echo Req towards DUT1 egress interface. Make TG\
+| | ... | verify ICMPv6 Echo Reply is correct.
+| | ...
+| | ${hops}= | Set Variable | ${0}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv6 forwarding in circular topology | ${tg_to_dut_if1_ip6}
+| | ... | ${tg_to_dut_if2_ip6} | ${dut_to_tg_if1_ip6} | ${dut_to_tg_if2_ip6}
+| | And Suppress ICMPv6 router advertisement message | ${nodes}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv6 echo request packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${dut_node} | ${dut_to_tg_if2}
+| | ... | ${tg_to_dut_if1_ip6} | ${dut_to_tg_if2_ip6} | ${dut_to_tg_if1_mac}
+| | ... | ${hops}
+
+| tc03-eth2p-ethicmpv6-ip6base-device_echo-req-to-tg-interface-for-local-ipv4-address
+| | [Documentation]
+| | ... | Make TG send ICMPv6 Echo Req between its interfaces across DUT1 for\
+| | ... | locally connected IPv6 addresses. Make TG verify ICMPv6 Echo Replies\
+| | ... | are correct.
+| | ...
+| | ${hops}= | Set Variable | ${1}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv6 forwarding in circular topology | ${tg_to_dut_if1_ip6}
+| | ... | ${tg_to_dut_if2_ip6} | ${dut_to_tg_if1_ip6} | ${dut_to_tg_if2_ip6}
+| | And Suppress ICMPv6 router advertisement message | ${nodes}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv6 echo request packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${tg_node} | ${tg_to_dut_if2}
+| | ... | ${tg_to_dut_if1_ip6} | ${tg_to_dut_if2_ip6} | ${dut_to_tg_if1_mac}
+| | ... | ${hops} | ${dut_to_tg_if2_mac}
+
+| tc04-eth2p-ethicmpv6-ip6base-device_echo-req-to-tg-interface-for-remote-host-ipv4-address
+| | [Documentation]
+| | ... | Make TG send ICMPv6 Echo Req between its interfaces across DUT1 for\
+| | ... | remote host IPv6 addresses. Make TG verify ICMPv6 Echo Replies are\
+| | ... | correct.
+| | ...
+| | ${hops}= | Set Variable | ${1}
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Initialize IPv6 forwarding in circular topology | ${tg_to_dut_if1_ip6}
+| | ... | ${tg_to_dut_if2_ip6} | ${dut_to_tg_if1_ip6} | ${dut_to_tg_if2_ip6}
+| | ... | remote_host1_ip6=${remote_host1_ip6}
+| | ... | remote_host2_ip6=${remote_host2_ip6}
+| | ... | remote_host_ip6_prefix=${remote_host_ip6_prefix}
+| | And Suppress ICMPv6 router advertisement message | ${nodes}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send IPv6 echo request packet and verify headers | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${tg_node} | ${tg_to_dut_if2}
+| | ... | ${remote_host1_ip6} | ${remote_host2_ip6} | ${dut_to_tg_if1_mac}
+| | ... | ${hops} | ${dut_to_tg_if2_mac}
diff --git a/tests/vpp/device/l2bd/eth2p-eth-l2bdbasemaclrn-dev.robot b/tests/vpp/device/l2bd/eth2p-eth-l2bdbasemaclrn-dev.robot
new file mode 100644
index 0000000000..553ed17029
--- /dev/null
+++ b/tests/vpp/device/l2bd/eth2p-eth-l2bdbasemaclrn-dev.robot
@@ -0,0 +1,87 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
+| Resource | resources/libraries/robot/l2/l2_traffic.robot
+| Resource | resources/libraries/robot/shared/default.robot
+| Resource | resources/libraries/robot/shared/interfaces.robot
+| Resource | resources/libraries/robot/shared/testing_path.robot
+| ...
+| Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
+| ... | FUNCTEST | L2BDMACLRN | BASE | ETH | ICMP
+| ...
+| Test Setup | Set up VPP device test
+| ...
+| Test Teardown | Tear down VPP device test
+| ...
+| Documentation | *L2 bridge-domain test cases*
+| ...
+| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology\
+| ... | with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of\
+| ... | IPv4; Eth-IPv6-ICMPv6 for L2 switching of IPv6 use. Both apply to all\
+| ... | links.
+| ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge-domain\
+| ... | switching.
+| ... | *[Ver] TG verification:* Test ICMPv4 (or ICMPv6) Echo Request packets\
+| ... | are sent in both directions by TG on links to DUT1; on receive TG\
+| ... | verifies packets for correctness and their IPv4 (IPv6) src-addr,\
+| ... | dst-addr and MAC addresses.
+| ... | *[Ref] Applicable standard specifications:* RFC792
+
+*** Variables ***
+| ${bd_id}= | 1
+
+*** Test Cases ***
+| tc01-eth2p-ethicmpv4-l2bdbase-device
+| | [Documentation]
+| | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv4-ICMPv4.
+| | ... | [Cfg] Configure L2 bridge-domain (L2BD) with MAC learning enabled on\
+| | ... | DUT1. Add both interfaces towards TG to this L2BD.
+| | ... | [Ver] Make TG send ICMPv4 Echo Req in both directions between two of\
+| | ... | its interfaces to be switched by DUT1; verify all packets are\
+| | ... | received.
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Set interfaces in path up
+| | And Create bridge domain | ${dut_node} | ${bd_id}
+| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if1}
+| | ... | ${bd_id}
+| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if2}
+| | ... | ${bd_id}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send ICMPv4 bidirectionally and verify received packets | ${tg_node}
+| | ... | ${tg_to_dut_if1} | ${tg_to_dut_if2}
+
+| tc02-eth2p-ethicmpv6-l2bdbase-device
+| | [Documentation]
+| | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv6-ICMPv6.
+| | ... | [Cfg] Configure L2 bridge-domain (L2BD) with MAC learning enabled on\
+| | ... | DUT1. Add both interfaces towards TG to this L2BD.
+| | ... | [Ver] Make TG send ICMPv6 Echo Req in both directions between two of\
+| | ... | its interfaces to be switched by DUT1; verify all packets are\
+| | ... | received.
+| | ...
+| | Given Configure path in 2-node circular topology
+| | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
+| | And Set interfaces in path up
+| | And Create bridge domain | ${dut_node} | ${bd_id}
+| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if1}
+| | ... | ${bd_id}
+| | And Add interface to bridge domain | ${dut_node} | ${dut_to_tg_if2}
+| | ... | ${bd_id}
+| | When All Vpp Interfaces Ready Wait | ${nodes}
+| | Then Send ICMPv6 bidirectionally and verify received packets
+| | ... | ${tg_node} | ${tg_to_dut_if1} | ${tg_to_dut_if2}
diff --git a/tests/vpp/device/l2xc/eth2p-ethicmp-l2xcbase-device.robot b/tests/vpp/device/l2xc/eth2p-ethicmp-l2xcbase-dev.robot
index b18ce7bb77..19920e604c 100644
--- a/tests/vpp/device/l2xc/eth2p-ethicmp-l2xcbase-device.robot
+++ b/tests/vpp/device/l2xc/eth2p-ethicmp-l2xcbase-dev.robot
@@ -18,7 +18,7 @@
 | Resource | resources/libraries/robot/shared/testing_path.robot
 | ...
 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
-| ... | L2XCFWD | ICMP
+| ... | FUNCTEST | L2XCFWD | BASE | ETH | ICMP
 | ...
 | Test Setup | Set up VPP device test
 | ...
@@ -37,21 +37,21 @@
 | ... | are sent in both directions by TG on links to DUT1; on receive TG\
 | ... | verifies packets for correctness and their IPv4 (IPv6) src-addr,\
 | ... | dst-addr and MAC addresses.
-| ... | *[Ref] Applicable standard specifications: rfc792*
+| ... | *[Ref] Applicable standard specifications:* RFC792
 
 *** Test Cases ***
 | tc01-eth2p-ethicmpv4-l2xcbase-device
 | | [Documentation]
 | | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv4-ICMPv4.
-| | ... | [Cfg] On DUT1 configure L2 cross-connect (L2XC), with both interfaces\
-| | ... | to TG.
+| | ... | [Cfg] Configure L2 cross-connects (L2XC) between both interfaces\
+| | ... | towards TG on DUT1.
 | | ... | [Ver] Make TG send ICMPv4 Echo Req in both directions between two of\
-| | ... | its interfaces to be switched by DUT1; verify all packets are
+| | ... | its interfaces to be switched by DUT1; verify all packets are\
 | | ... | received.
 | | ...
 | | Given Configure path in 2-node circular topology
 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
-| | And Set Interfaces In 2-node Circular Topology Up
+| | And Set interfaces in path up
 | | And Configure L2XC | ${dut_node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
 | | When All Vpp Interfaces Ready Wait | ${nodes}
 | | Then Send ICMPv4 bidirectionally and verify received packets
@@ -59,16 +59,16 @@
 
 | tc02-eth2p-ethicmpv6-l2xcbase-device
 | | [Documentation]
-| | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv4-ICMPv6.
-| | ... | [Cfg] On DUT1 configure L2 cross-connect (L2XC), with both interfaces\
-| | ... | to TG.
-| | ... | [Ver] Make TG send ICMPv4 Echo Req in both directions between two of\
-| | ... | its interfaces to be switched by DUT1; verify all packets are
+| | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv6-ICMPv6.
+| | ... | [Cfg] Configure L2 cross-connects (L2XC) between both interfaces\
+| | ... | towards TG on DUT1.
+| | ... | [Ver] Make TG send ICMPv6 Echo Req in both directions between two of\
+| | ... | its interfaces to be switched by DUT1; verify all packets are\
 | | ... | received.
 | | ...
 | | Given Configure path in 2-node circular topology
 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
-| | And Set Interfaces In 2-node Circular Topology Up
+| | And Set interfaces in path up
 | | And Configure L2XC | ${dut_node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
 | | When All Vpp Interfaces Ready Wait | ${nodes}
 | | Then Send ICMPv6 bidirectionally and verify received packets