VPPD: Cop, iACL, Policer

- Alignment with PERF

Change-Id: Id7b2cb91c88e44cf9265c3376330f6aa579abf7a
Signed-off-by: Peter Mikus <pmikus@cisco.com>

1 files changed, 133 insertions, 0 deletions

diff --git a/tests/vpp/perf/ip6/2n1l-10ge2p1x710-ethip6-ip6base-copwhtlistbase-ndrpdr.robot b/tests/vpp/perf/ip6/2n1l-10ge2p1x710-ethip6-ip6base-copwhtlistbase-ndrpdr.robot
new file mode 100644
index 0000000000..818d435545
--- /dev/null
+++ b/tests/vpp/perf/ip6/2n1l-10ge2p1x710-ethip6-ip6base-copwhtlistbase-ndrpdr.robot
@@ -0,0 +1,133 @@
+# Copyright (c) 2019 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/shared/default.robot
+| Library | resources.libraries.python.Cop
+| ...
+| Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
+| ... | NIC_Intel-X710 | ETH | IP6FWD | FEATURE | COPWHLIST
+| ...
+| Suite Setup | Setup suite single link | performance
+| Suite Teardown | Tear down suite | performance
+| Test Setup | Setup test
+| Test Teardown | Tear down test | performance
+| ...
+| Test Template | Local Template
+| ...
+| Documentation | *RFC2544: Pkt throughput IPv6 whitelist test cases*
+| ...
+| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology
+| ... | with single links between nodes.
+| ... | *[Enc] Packet Encapsulations:* Eth-IPv6 for IPv6 routing.
+| ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv6
+| ... | routing, two static IPv6 /64 routes and IPv6 COP security whitelist
+| ... | ingress /64 filter entries applied on links TG - DUT1.
+| ... | DUT1 is tested with ${nic_name}.\
+| ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
+| ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
+| ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
+| ... | of packets transmitted. NDR and PDR are discovered for different\
+| ... | Ethernet L2 frame sizes using MLRsearch library.\
+| ... | Test packets are generated by TG on
+| ... | links to DUTs. TG traffic profile contains two L3 flow-groups
+| ... | (flow-group per direction, 253 flows per flow-group) with all packets
+| ... | containing Ethernet header, IPv6 header and static
+| ... | payload. MAC addresses are matching MAC addresses of the TG node
+| ... | interfaces.
+| ... | *[Ref] Applicable standard specifications:* RFC2544.
+
+*** Variables ***
+| @{plugins_to_enable}= | dpdk_plugin.so
+| ${osi_layer}= | L3
+| ${nic_name}= | Intel-X710
+| ${overhead}= | ${0}
+# Traffic profile:
+| ${traffic_profile}= | trex-sl-2n-ethip6-ip6src253
+
+*** Keywords ***
+| Local Template
+| | [Documentation]
+| | ... | [Cfg] DUT runs IPv6 routing and whitelist filters config with
+| | ... | ${phy_cores} phy core(s).
+| | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
+| | ...
+| | ... | *Arguments:*
+| | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
+| | ... | Type: integer, string
+| | ... | - phy_cores - Number of physical cores. Type: integer
+| | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
+| | ...
+| | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
+| | ...
+| | Set Test Variable | \${frame_size}
+| | ...
+| | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
+| | And Add PCI devices to all DUTs
+| | And Set Max Rate And Jumbo And Handle Multi Seg
+| | And Apply startup configuration on all VPP DUTs
+| | When Initialize IPv6 forwarding in circular topology
+| | And Add Fib Table | ${dut1} | 1 | ipv6=${TRUE}
+| | And Vpp Route Add | ${dut1} | 2001:1:: | 64 | vrf=1 | local=${TRUE}
+| | And COP Add whitelist Entry | ${dut1} | ${dut1_if1} | ip6 | 1
+| | And COP interface enable or disable | ${dut1} | ${dut1_if1} | enable
+| | Then Find NDR and PDR intervals using optimized search
+
+*** Test Cases ***
+| tc01-78B-1c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 78B | 1C
+| | frame_size=${78} | phy_cores=${1}
+
+| tc02-78B-2c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 78B | 2C
+| | frame_size=${78} | phy_cores=${2}
+
+| tc03-78B-4c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 78B | 4C
+| | frame_size=${78} | phy_cores=${4}
+
+| tc04-1518B-1c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 1518B | 1C
+| | frame_size=${1518} | phy_cores=${1}
+
+| tc05-1518B-2c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 1518B | 2C
+| | frame_size=${1518} | phy_cores=${2}
+
+| tc06-1518B-4c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 1518B | 4C
+| | frame_size=${1518} | phy_cores=${4}
+
+| tc07-9000B-1c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 9000B | 1C
+| | frame_size=${9000} | phy_cores=${1}
+
+| tc08-9000B-2c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 9000B | 2C
+| | frame_size=${9000} | phy_cores=${2}
+
+| tc09-9000B-4c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | 9000B | 4C
+| | frame_size=${9000} | phy_cores=${4}
+
+| tc10-IMIX-1c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | IMIX | 1C
+| | frame_size=IMIX_v4_1 | phy_cores=${1}
+
+| tc11-IMIX-2c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | IMIX | 2C
+| | frame_size=IMIX_v4_1 | phy_cores=${2}
+
+| tc12-IMIX-4c-ethip6-ip6base-copwhtlistbase-ndrpdr
+| | [Tags] | IMIX | 4C
+| | frame_size=IMIX_v4_1 | phy_cores=${4}