1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
|
# Copyright (c) 2016 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Settings ***
| Library | resources.libraries.python.honeycomb.HcAPIKwInterfaces.InterfaceKeywords
| Library | resources.libraries.python.telemetry.SPAN
| Library | resources.libraries.python.InterfaceUtil
| Library | resources.libraries.python.IPv4Util
| Library | resources.libraries.python.IPv4Setup
| Library | resources.libraries.python.Trace
*** Keywords ***
| Honeycomb configures SPAN on interface
| | [Documentation] | Uses Honeycomb API to configure SPAN on the specified\
| | ... | interface, mirroring one or more interfaces.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination interface. Type: string
| | ... | - src_interfaces - Mirroring source interfaces. Type: list \
| | ... | of dictionaries
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Honeycomb configures SPAN on interface \| ${nodes['DUT1']} \
| | ... | \| GigabitEthernet0/8/0 \| [{'iface-ref': 'GigabitEthernet0/10/0', \
| | ... | \| 'state': 'transmit'}, \
| | ... | \| {'iface-ref': 'local0', 'state': 'both'}] \|
| | ...
| | [Arguments] | ${node} | ${dst_interface} | @{src_interfaces}
| | Configure interface SPAN
| | ... | ${node} | ${dst_interface} | ${src_interfaces}
| Interface SPAN Operational Data From Honeycomb Should Be
| | [Documentation] | Retrieves interface operational data and verifies that\
| | ... | SPAN mirroring is configured with the provided interfaces.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination interface. Type: string
| | ... | - src_interfaces - Mirroring source interfaces. Type: Argument list -\
| | ... | any number of strings
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Interface SPAN Operational Data From Honeycomb Should Be \
| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| GigabitEthernet0/9/0 \|
| | ...
| | [Arguments] | ${node} | ${dst_interface} | @{src_interfaces}
| | ${data}= | Get interface oper data | ${node} | ${dst_interface}
| | ${data}= | Set Variable
| | ... | ${data['v3po:span']['mirrored-interfaces']['mirrored-interface']}
| | Sort list | ${data}
| | Sort list | ${src_interfaces}
| | Lists should be equal | ${data} | ${src_interfaces}
| Interface SPAN Operational Data From Honeycomb Should Be empty
| | [Documentation] | Checks whether SPAN configuration from Honeycomb is empty.
| | ...
| | ... | *Arguments:*
| | ... | - node - Information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination interface. Type: string
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Interface SPAN Operational Data From Honeycomb Should Be empty \
| | ... | \| ${node} \| GigabitEthernetO/8/0 \|
| | ...
| | [Arguments] | ${node} | ${dst_interface}
| | ${data}= | Get interface oper data | ${node} | ${dst_interface}
| | Variable should not exist
| | ... | ${data['v3po:span']['mirrored-interfaces']['mirrored-interface']}
| Interface SPAN Operational Data From VAT Should Be
| | [Documentation] | Retrieves SPAN configuration from VAT dump and verifies\
| | ... | that SPAN mirroring is configured with the provided interfaces.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination interface. Type: string
| | ... | - src_interfaces - Mirroring source interfaces. Type: Argument list -\
| | ... | any number of strings
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Interface SPAN Operational Data From VAT Should Be \
| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| GigabitEthernet0/9/0 \|
| | ...
| | [Arguments] | ${node} | ${dst_interface} | @{src_interfaces}
| | ${data}= | VPP get SPAN configuration by interface
| | ... | ${node} | ${dst_interface} | name
| | Sort list | ${data}
| | Sort list | ${src_interfaces}
| | Lists should be equal | ${data} | ${src_interfaces}
| Honeycomb removes interface SPAN configuration
| | [Documentation] | Uses Honeycomb API to remove SPAN configuration\
| | ... | from the specified interface.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination interface. Type: string
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Honeycomb removes interface SPAN configuration \
| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \|
| | ...
| | [Arguments] | ${node} | ${dst_interface}
| | Configure interface SPAN | ${node} | ${dst_interface}
| Interface SPAN Operational Data from Honeycomb should not exist
| | [Documentation] | Retrieves interface operational data and verifies that\
| | ... | SPAN mirroring is not configured.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination interface. Type: string
| | ...
| | ... | *Example:*
| | ...
| | ... | \|
| | [Arguments] | ${node} | ${dst_interface}
| | ${data}= | Get interface oper data | ${node} | ${dst_interface}
| | Run keyword and expect error | *KeyError* | Set Variable
| | ... | ${data['span']['mirrored-interfaces']['mirrored-interface']}
| SPAN Operational Data from VAT should not exist
| | [Documentation] | Attmepts to retrieve SPAN Operational Data from VAT dump,\
| | ... | and expects to fail with no data retrieved.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ...
| | ... | *Example:*
| | ...
| | ... | \| SPAN Operational Data from VAT should not exist \| ${nodes['DUT1']} \|
| | [Arguments] | ${node}
| | Run keyword and expect error | ValueError: No JSON object could be decoded
| | ... | VPP get SPAN configuration by interface | ${node} | local0
| Honeycomb Configures SPAN on sub-interface
| | [Documentation] | Uses Honeycomb API to configure SPAN on the specified\
| | ... | sub-interface, mirroring one or more interfaces.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination super-interface. Type: string
| | ... | - index - Index of mirroring destination sub-interface. Type: integer
| | ... | - src_interfaces - Mirroring source interfaces. Type: list \
| | ... | of dictionaries
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Honeycomb Configures SPAN on sub-interface \| ${nodes['DUT1']} \
| | ... | \| GigabitEthernet0/8/0 \| ${1} \
| | ... | \|[{'iface-ref': 'GigabitEthernet0/10/0', 'state': 'transmit'}, \
| | ... | \| {'iface-ref': 'local0', 'state': 'both'}] \|
| | ...
| | [Arguments] | ${node} | ${dst_interface} | ${index} | @{src_interfaces}
| | Configure sub interface SPAN
| | ... | ${node} | ${dst_interface} | ${index} | ${src_interfaces}
| Sub-Interface SPAN Operational Data from Honeycomb should be
| | [Documentation] | Retrieves sub-interface operational data and verifies\
| | ... | that SPAN mirroring is configured with the provided interfaces.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination super-interface. Type: string
| | ... | - index - Index of mirroring destination sub-interface. Type: integer
| | ... | - src_interfaces - Mirroring source interfaces. Type: Argument list -\
| | ... | any number of strings
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Sub-Interface SPAN Operational Data from Honeycomb should be \
| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| ${1} \
| | ... | \| GigabitEthernet0/9/0 \|
| | ...
| | [Arguments] | ${node} | ${dst_interface} | ${index} | @{src_interfaces}
| | ${data}= | Get sub interface oper data
| | ... | ${node} | ${dst_interface} | ${index}
| | ${data}= | Set Variable
| | ... | ${data['subinterface-span:span-state']['mirrored-interfaces']['mirrored-interface']}
| | Sort list | ${data}
| | Sort list | ${src_interfaces}
| | Lists should be equal | ${data} | ${src_interfaces}
| Sub-Interface SPAN Operational Data from Honeycomb should be empty
| | [Documentation] | Checks whether SPAN Operational Data from Honeycomb is empty.
| | ...
| | ... | *Arguments:*
| | ... | - node - Information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination super-interface. Type: string
| | ... | - index - Index of mirroring destination sub-interface. Type: integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Interface SPAN Operational Data from Honeycomb should be empty \
| | ... | \| ${node} \| GigabitEthernetO/8/0 \| ${1} \|
| | ...
| | [Arguments] | ${node} | ${dst_interface} | ${index}
| | ${data}= | Get sub interface oper data
| | ... | ${node} | ${dst_interface} | ${index}
| | Variable should not exist
| | ... | ${data['subinterface-span:span-state']['mirrored-interfaces']['mirrored-interface']}
| Honeycomb removes sub-interface SPAN configuration
| | [Documentation] | Uses Honeycomb API to remove SPAN Operational Data\
| | ... | from the specified sub-interface.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination super-interface. Type: string
| | ... | - index - Index of mirroring destination sub-interface. Type: integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Honeycomb removes sub-interface SPAN configuration \
| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| ${1} \|
| | ...
| | [Arguments] | ${node} | ${dst_interface} | ${index}
| | Configure sub interface SPAN
| | ... | ${node} | ${dst_interface} | ${index}
| Sub-Interface SPAN Operational Data from Honeycomb should not exist
| | [Documentation] | Retrieves sub-interface operational data and verifies
| | ... | that SPAN mirroring is not configured.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - dst_interface - Mirroring destination super-interface. Type: string
| | ... | - index - Index of mirroring destination sub-interface. Type: integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Sub-Interface SPAN Operational Data from Honeycomb should not exist \
| | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| ${1} \|
| | ....
| | [Arguments] | ${node} | ${dst_interface} | ${index}
| | ${data}= | Get sub interface oper data
| | ... | ${node} | ${dst_interface} | ${index}
| | Run keyword and expect error | *KeyError* | Set Variable
| | ... | ${data['subinterface-span:span-state']['mirrored-interfaces']['mirrored-interface']}
|
