blob: 2f2cfc50b4f49c6388d919d3dc1ecf9dc801eff3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
|
# Copyright (c) 2016 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Settings ***
| Library | resources.libraries.python.InterfaceUtil
| Library | resources.libraries.python.honeycomb.HcAPIKwInterfaces.InterfaceKeywords
*** Variables ***
# Translation table used to convert values received from Honeycomb to values
# received from VAT.
| &{protocols}=
| ... | -=0
| ... | ipv4=1
| ... | ipv6=2
| ... | ethernet=3
| ... | nsh=4
*** Keywords ***
| Honeycomb creates VxLAN GPE interface
| | [Documentation] | Uses Honeycomb API to configure a VxLAN tunnel.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - interface - name of an interface to be created. Type: string
| | ... | - base_settings - configuration data common for all interfaces.\
| | ... | Type: dictionary
| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
| | ...
| | ... | *Example:*
| | ... | \| Honeycomb creates VxLAN GPE interface \
| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${base_params} \
| | ... | \| ${vxlan_gpe_params} \|
| | ...
| | [Arguments] | ${node} | ${interface}
| | ... | ${base_settings} | ${vxlan_gpe_settings}
| | ...
| | Create VxLAN GPE interface
| | ... | ${node} | ${interface} | &{base_settings} | &{vxlan_gpe_settings}
| Honeycomb removes VxLAN GPE interface
| | [Documentation] | Uses Honeycomb API to remove VxLAN GPE interface from\
| | ... | node.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - interface - name of the interface to be removed. Type: string
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Honeycomb removes VxLAN GPE interface \
| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \|
| | ...
| | [Arguments] | ${node} | ${interface}
| | ...
| | Delete interface | ${node} | ${interface}
| VxLAN GPE Operational Data From Honeycomb Should Be
| | [Documentation] | Uses Honeycomb API to get operational data about the\
| | ... | given interface and compares them to the values provided as arguments.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - interface - name of an interface to be checked. Type: string
| | ... | - base_settings - configuration data common for all interfaces.\
| | ... | Type: dictionary
| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
| | ...
| | ... | *Example:*
| | ... | \| VxLAN GPE Operational Data From Honeycomb Should Be \
| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${base_params} \
| | ... | \| ${vxlan_gpe_params} \|
| | ...
| | [Arguments] | ${node} | ${interface}
| | ... | ${base_settings} | ${vxlan_gpe_settings}
| | ...
| | ${api_data}= | Get interface oper data | ${node} | ${interface}
| | Should be equal as strings
| | ... | ${api_data['name']} | ${base_settings['name']}
| | Should be equal as strings
| | ... | ${api_data['type']} | v3po:vxlan-gpe-tunnel
| | Run keyword if | $base_settings['enabled'] == True
| | ... | Run keywords
| | ... | Should be equal as strings | ${api_data['admin-status']} | up
| | ... | AND
| | ... | Should be equal as strings | ${api_data['oper-status']} | up
| | ... | ELSE
| | ... | Run keywords
| | ... | Should be equal as strings | ${api_data['admin-status']} | down
| | ... | AND
| | ... | Should be equal as strings | ${api_data['oper-status']} | down
| VxLAN GPE Operational Data From VAT Should Be
| | [Documentation] | Uses VAT to get operational data about the given\
| | ... | interface and compares them to the values provided as arguments.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - interface - name of an interface to be checked. Type: string
| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
| | ...
| | ... | *Example:*
| | ... | \| VxLAN GPE Operational Data From VAT Should Be \
| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${vxlan_gpe_params} \|
| | ...
| | [Arguments] | ${node} | ${interface} | ${vxlan_gpe_params}
| | ...
| | ${vat_data}= | VxLAN GPE Dump | ${node} | ${interface}
| | Should be equal as strings
| | ... | ${vat_data['local']} | ${vxlan_gpe_params['local']}
| | Should be equal as strings
| | ... | ${vat_data['remote']} | ${vxlan_gpe_params['remote']}
| | Should be equal as strings
| | ... | ${vat_data['vni']} | ${vxlan_gpe_params['vni']}
| | Should be equal as strings
| | ... | ${vat_data['encap_vrf_id']} | ${vxlan_gpe_params['encap-vrf-id']}
| | Should be equal as strings
| | ... | ${vat_data['decap_vrf_id']} | ${vxlan_gpe_params['decap-vrf-id']}
# VAT dump multiplies protocol value by 16777216
| | Should be equal as strings | ${vat_data['protocol']/16777216}
| | ... | ${protocols['${vxlan_gpe_params['next-protocol']}']}
| VxLAN GPE Interface indices from Honeycomb and VAT should correspond
| | [Documentation] | Uses VAT and Honeycomb to get operational data about the \
| | ... | given VxLAN GPE interface and compares the interface indexes. The \
| | ... | VxLAN GPE interface index from Honeycomb should be greater than \
| | ... | index from VAT by one.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - interface - name of the interface to be checked. Type: string
| | ...
| | ... | *Example:*
| | ...
| | ... | \| VxLAN GPE Interface indices from Honeycomb and VAT should \
| | ... | correspond \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \|
| | ...
| | [Arguments] | ${node} | ${interface}
| | ...
| | ${api_data}= | Get interface oper data | ${node} | ${interface}
| | ${vat_data}= | VxLAN GPE Dump | ${node} | ${interface}
| | ${sw_if_index}= | EVALUATE | ${vat_data['sw_if_index']} + 1
| | Should be equal as strings
| | ... | ${api_data['if-index']} | ${sw_if_index}
| VxLAN GPE Operational Data From Honeycomb Should Be empty
| | [Documentation] | Uses Honeycomb API to get operational data about\
| | ... | the given interface and expects to fail.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ...
| | ... | *Example:*
| | ... | \| VxLAN GPE Operational Data From Honeycomb Should Be empty\
| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \|
| | ...
| | [Arguments] | ${node} | ${interface}
| | ...
| | ${api_data}= | Get interface oper data | ${node} | ${interface}
| | Should be empty | ${api_data}
| VxLAN GPE Operational Data From VAT Should Be empty
| | [Documentation] | Uses VAT to get operational data about the given\
| | ... | interface and expects an empty dictionary.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ...
| | ... | *Example:*
| | ... | \| VxLAN GPE Operational Data From VAT Should Be empty\
| | ... | \| ${nodes['DUT1']} \|
| | ...
| | [Arguments] | ${node}
| | ...
| | Run Keyword And Expect Error | ValueError: No JSON object could be decoded
| | ... | VxLAN Dump | ${node}
| Honeycomb fails to create VxLAN GPE interface
| | [Documentation] | Uses Honeycomb API to configure a VxLAN tunnel with wrong\
| | ... | configuration data.
| | ...
| | ... | *Arguments:*
| | ... | - node - information about a DUT node. Type: dictionary
| | ... | - interface - name of an interface to be created. Type: string
| | ... | - base_settings - Configuration data common for all interfaces.\
| | ... | Type: dictionary
| | ... | - vxlan_gpe_settings - VxLAN GPE specific parameters. Type: dictionary
| | ...
| | ... | *Example:*
| | ... | \| Honeycomb fails to create VxLAN GPE interface \
| | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \| ${wrong_base_params} \
| | ... | \| ${vxlan_gpe_params} \|
| | ...
| | [Arguments] | ${node} | ${interface}
| | ... | ${base_settings} | ${vxlan_gpe_settings}
| | ...
| | Run keyword and expect error | *HoneycombError*not successful. * code: *00.
| | ... | Create VxLAN GPE interface
| | ... | ${node} | ${interface} | &{base_settings} | &{vxlan_gpe_settings}
|
