blob: bb0ae5be4cdfded0a1f91227e33b8b22ae8264ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
|
# Copyright (c) 2019 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Settings ***
| Library | resources.libraries.python.InterfaceUtil
| Library | resources.libraries.python.IPv4Util.IPv4Util
| Library | resources.libraries.python.IPv4Setup.IPv4Setup
| Library | resources.libraries.python.NodePath
| Library | resources.libraries.python.Routing
| Library | resources.libraries.python.TrafficScriptExecutor
| Resource | resources/libraries/robot/shared/counters.robot
| Resource | resources/libraries/robot/shared/default.robot
| Resource | resources/libraries/robot/shared/testing_path.robot
| Variables | resources/libraries/python/IPv4NodeAddress.py | ${nodes}
| ...
| Documentation | IPv4 keywords
*** Keywords ***
| Show IP FIB On All DUTs
| | [Documentation] | Show IP FIB on all DUTs.
| | ...
| | ${duts}= | Get Matches | ${nodes} | DUT*
| | :FOR | ${dut} | IN | @{duts}
| | | VPP Show IP Table | ${nodes['${dut}']}
| Configure IPv4 addresses on all DUTs
| | [Documentation] | Setup IPv4 address on all DUTs in topology
| | [Arguments] | ${nodes} | ${nodes_addr}
| | ${interfaces}= | VPP nodes set ipv4 addresses | ${nodes} | ${nodes_addr}
| | :FOR | ${interface} | IN | @{interfaces}
| | | Set Interface State | @{interface} | up | if_type=name
| Get interface Ipv4 addresses
| | [Documentation] | Get IPv4 address for the given interface of the node.
| | ...
| | ... | *Arguments:*
| | ... | - node - DUT node data. Type: dictionary
| | ... | - interface - Name of the interface on the VPP node. Type: string
| | ...
| | [Arguments] | ${node} | ${interface}
| | ...
| | [Return] | ${ip_data}
| | ...
| | ${ip_data}= | VPP get interface ip addresses
| | ... | ${node} | ${interface} | ipv4
| Configure routes for IPv4 test
| | [Documentation] | Setup routing on all VPP nodes required for IPv4 tests
| | [Arguments] | ${nodes} | ${nodes_addr}
| | Append Nodes | ${nodes['DUT1']} | ${nodes['DUT2']}
| | Compute Path
| | ${tg}= | Set Variable | ${nodes['TG']}
| | ${dut1_if} | ${dut1}= | First Interface
| | ${dut2_if} | ${dut2}= | Last Interface
| | ${dut1_if_addr}= | Get IPv4 address of node "${dut1}" interface "${dut1_if}" from "${nodes_addr}"
| | ${dut2_if_addr}= | Get IPv4 address of node "${dut2}" interface "${dut2_if}" from "${nodes_addr}"
| | @{tg_dut1_links}= | Get active links connecting "${tg}" and "${dut1}"
| | @{tg_dut2_links}= | Get active links connecting "${tg}" and "${dut2}"
| | :FOR | ${link} | IN | @{tg_dut1_links}
| | | ${net}= | Get Link Address | ${link} | ${nodes_addr}
| | | ${prefix}= | Get Link Prefix | ${link} | ${nodes_addr}
| | | Vpp Route Add | ${dut2} | ${net} | ${prefix}
| | | ... | gateway=${dut1_if_addr} | interface=${dut2_if}
| | :FOR | ${link} | IN | @{tg_dut2_links}
| | | ${net}= | Get Link Address | ${link} | ${nodes_addr}
| | | ${prefix}= | Get Link Prefix | ${link} | ${nodes_addr}
| | | Vpp Route Add | ${dut1} | ${net} | ${prefix}
| | | ... | gateway=${dut2_if_addr} | interface=${dut1_if}
| Configure DUT nodes for IPv4 testing
| | Configure IPv4 addresses on all DUTs | ${nodes} | ${nodes_ipv4_addr}
| | Setup ARP on all DUTs | ${nodes} | ${nodes_ipv4_addr}
| | Configure routes for IPv4 test | ${nodes} | ${nodes_ipv4_addr}
| | All Vpp Interfaces Ready Wait | ${nodes}
| Route traffic from interface '${from_port}' on node '${from_node}' to interface '${to_port}' on node '${to_node}' '${hops}' hops away using IPv4
| | ${src_ip}= | Get IPv4 address of node "${from_node}" interface "${from_port}" from "${nodes_ipv4_addr}"
| | ${dst_ip}= | Get IPv4 address of node "${to_node}" interface "${to_port}" from "${nodes_ipv4_addr}"
| | ${src_mac}= | Get interface mac | ${from_node} | ${from_port}
| | ${dst_mac}= | Get interface mac | ${to_node} | ${to_port}
| | ${is_dst_tg}= | Is TG node | ${to_node}
| | ${adj_node} | ${adj_int}= | Get adjacent node and interface | ${nodes}
| | ... | ${from_node} | ${from_port}
| | ${from_port_name}= | Get interface name | ${from_node} | ${from_port}
| | ${to_port_name}= | Get interface name | ${to_node} | ${to_port}
| | ${adj_int_mac}= | Get interface MAC | ${adj_node} | ${adj_int}
| | ${args}= | Traffic Script Gen Arg | ${to_port_name} | ${from_port_name}
| | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
| | ${args}= | Catenate | ${args} | --hops ${hops}
| | ... | --first_hop_mac ${adj_int_mac} | --is_dst_tg ${is_dst_tg}
| | Run Traffic Script On Node | ipv4_ping_ttl_check.py | ${from_node} | ${args}
| Execute IPv4 ICMP echo sweep
| | [Documentation] | Type of the src_node must be TG and dst_node must be DUT
| | [Arguments] | ${src_node} | ${dst_node} | ${start_size} | ${end_size}
| | ... | ${step}
| | Append Nodes | ${src_node} | ${dst_node}
| | Compute Path
| | ${src_port} | ${src_node}= | First Interface
| | ${dst_port} | ${dst_node}= | Last Interface
| | ${src_ip}= | Get IPv4 address of node "${src_node}" interface "${src_port}" from "${nodes_ipv4_addr}"
| | ${dst_ip}= | Get IPv4 address of node "${dst_node}" interface "${dst_port}" from "${nodes_ipv4_addr}"
| | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
| | ${dst_mac}= | Get Interface Mac | ${dst_node} | ${dst_port}
| | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
| | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
| | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
| | ${args}= | Catenate | ${args} | --start_size ${start_size}
| | ... | --end_size ${end_size} | --step ${step}
| | Run Traffic Script On Node | ipv4_sweep_ping.py | ${src_node} | ${args}
| | ... | timeout=${180}
| Send ARP request and verify response
| | [Arguments] | ${tg_node} | ${vpp_node}
| | ${link_name}= | Get first active connecting link between node "${tg_node}" and "${vpp_node}"
| | ${src_if}= | Get interface by link name | ${tg_node} | ${link_name}
| | ${dst_if}= | Get interface by link name | ${vpp_node} | ${link_name}
| | ${src_ip}= | Get IPv4 address of node "${tg_node}" interface "${src_if}" from "${nodes_ipv4_addr}"
| | ${dst_ip}= | Get IPv4 address of node "${vpp_node}" interface "${dst_if}" from "${nodes_ipv4_addr}"
| | ${src_mac}= | Get node link mac | ${tg_node} | ${link_name}
| | ${dst_mac}= | Get node link mac | ${vpp_node} | ${link_name}
| | ${src_if_name}= | Get interface name | ${tg_node} | ${src_if}
| | ${args}= | Traffic Script Gen Arg | ${src_if_name} | ${src_if_name}
| | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
| | Run Traffic Script On Node | arp_request.py | ${tg_node} | ${args}
| Configure IP addresses on interfaces
| | [Documentation] | Iterates through @{args} list and Set Interface Address
| | ... | for every (${dut_node}, ${interface}, ${address},
| | ... | ${prefix}) tuple.
| | ...
| | ... | *Arguments:*
| | ... | - dut_node - Node where IP address should be set to.
| | ... | Type: dictionary
| | ... | - interface - Interface name. Type: string
| | ... | - address - IP address. Type: string
| | ... | - prefix - Prefix length. Type: integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Configure IP addresses on interfaces \
| | ... | \| ${dut1_node} \| ${dut1_to_dut2} \| 192.168.1.1 \| 24 \|
| | ... | \| ... \| ${dut1_node} \| ${dut1_to_tg} \| 192.168.2.1 \| 24 \|
| | ...
| | [Arguments] | @{args}
| | :FOR | ${dut_node} | ${interface} | ${address} | ${prefix} | IN | @{args}
| | | Set Interface Address | ${dut_node} | ${interface} | ${address}
| | | ... | ${prefix}
| Send ICMP echo request and verify answer
| | [Documentation] | Run traffic script that waits for ICMP reply and ignores
| | ... | all other packets.
| | ...
| | ... | *Arguments:*
| | ... | - tg_node - TG node where run traffic script. Type: dictionary
| | ... | - tg_interface - TG interface where send ICMP echo request.
| | ... | Type: string
| | ... | - dst_mac - Destination MAC address. Type: string
| | ... | - src_mac - Source MAC address. Type: string
| | ... | - dst_ip - Destination IP address. Type: string
| | ... | - src_ip - Source IP address. Type: string
| | ... | - timeout - Wait timeout in seconds (Default: 10). Type: integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Send ICMP echo request and verify answer \
| | ... | \| ${nodes['TG']} \| eth2 \
| | ... | \| 08:00:27:46:2b:4c \| 08:00:27:66:b8:57 \
| | ... | \| 192.168.23.10 \| 192.168.23.1 \| 10 \|
| | ...
| | [Arguments] | ${tg_node} | ${tg_interface}
| | ... | ${dst_mac} | ${src_mac} | ${dst_ip} | ${src_ip} | ${timeout}=${10}
| | ...
| | ${tg_interface_name}= | Get interface name | ${tg_node} | ${tg_interface}
| | ${args}= | Catenate | --rx_if ${tg_interface_name}
| | ... | --tx_if ${tg_interface_name} | --dst_mac ${dst_mac}
| | ... | --src_mac ${src_mac} | --dst_ip ${dst_ip} | --src_ip ${src_ip}
| | ... | --timeout ${timeout}
| | Run Traffic Script On Node | send_icmp_wait_for_reply.py
| | ... | ${tg_node} | ${args}
| Configure IPv4 forwarding in circular topology
| | [Documentation]
| | ... | Set UP state on VPP interfaces in path on nodes in 2-node / 3-node
| | ... | circular topology. Get the interface MAC addresses and setup ARP on
| | ... | all VPP interfaces. Setup IPv4 addresses with /24 prefix on DUT-TG
| | ... | links. In case of 3-node topology setup IPv4 adresses with /30 prefix
| | ... | on DUT1-DUT2 link and set routing on both DUT nodes with prefix /24
| | ... | and next hop of neighbour DUT interface IPv4 address. Configure route
| | ... | entries for remote hosts IPv4 addresses if required.
| | ...
| | ... | *Arguments:*
| | ... | - tg_if1_ip4 - IP address of TG interface1. Type: string
| | ... | - tg_if2_ip4 - IP address of TG interface2. Type: string
| | ... | - dut1_if1_ip4 - IP address of DUT1 interface1. Type: string
| | ... | - dut1_if2_ip4 - IP address of DUT1 interface1. Type: string
| | ... | - dut2_if1_ip4 - IP address of DUT2 interface1 (Optional).
| | ... | Type: string
| | ... | - dut2_if2_ip4 - IP address of DUT2 interface2 (Optional).
| | ... | Type: string
| | ... | - remote_host1_ip4 - IP address of remote host1 (Optional).
| | ... | Type: string
| | ... | - remote_host2_ip4 - IP address of remote host2 (Optional).
| | ... | Type: string
| | ... | - remote_host_ip4_prefix - IP address prefix for host IP addresses
| | ... | (Optional). Type: string or integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \|
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \
| | ... | \| remote_host1_ip4=192.168.0.1 \| remote_host2_ip4=192.168.0.2 \
| | ... | \| remote_host_ip4_prefix=32 \|
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
| | ... | \| 20.20.20.1 \|
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
| | ... | \| 20.20.20.1 \| remote_host1_ip4=192.168.0.1 \
| | ... | \| remote_host2_ip4=192.168.0.2 \| remote_host_ip4_prefix=32 \|
| | ...
| | [Arguments] | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4}
| | ... | ${dut1_if2_ip4} | ${dut2_if1_ip4}=${NONE} | ${dut2_if2_ip4}=${NONE}
| | ... | ${remote_host1_ip4}=${NONE} | ${remote_host2_ip4}=${NONE}
| | ... | ${remote_host_ip4_prefix}=${NONE}
| | ...
| | Configure interfaces in path up
| | ...
| | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
| | ... | Variable Should Exist | ${dut2_node}
| | ...
| | Run Keyword If | '${dut2_status}' == 'PASS'
| | ... | Configure IPv4 forwarding in 3-node circular topology
| | ... | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4} | ${dut1_if2_ip4}
| | ... | ${dut2_if1_ip4} | ${dut2_if2_ip4} | ${remote_host1_ip4}
| | ... | ${remote_host2_ip4} | ${remote_host_ip4_prefix}
| | ... | ELSE
| | ... | Configure IPv4 forwarding in 2-node circular topology
| | ... | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4} | ${dut1_if2_ip4}
| | ... | remote_host1_ip4=${remote_host1_ip4}
| | ... | remote_host2_ip4=${remote_host2_ip4}
| | ... | remote_host_ip4_prefix=${remote_host_ip4_prefix}
| Configure IPv4 forwarding in 2-node circular topology
| | [Documentation]
| | ... | Set UP state on VPP interfaces on DUT node in 2-node circular
| | ... | topology. Get the interface MAC addresses and setup ARP on
| | ... | all VPP interfaces. Setup IPv4 addresses with /24 prefix on DUT-TG
| | ... | links. Configure route entries for remote hosts IPv4 addresses
| | ... | if required.
| | ...
| | ... | *Arguments:*
| | ... | - tg_if1_ip4 - IP address of TG interface1. Type: string
| | ... | - tg_if2_ip4 - IP address of TG interface2. Type: string
| | ... | - dut1_if1_ip4 - IP address of DUT1 interface1. Type: string
| | ... | - dut1_if2_ip4 - IP address of DUT1 interface1. Type: string
| | ... | - remote_host1_ip4 - IP address of remote host1 (Optional).
| | ... | Type: string
| | ... | - remote_host2_ip4 - IP address of remote host2 (Optional).
| | ... | Type: string
| | ... | - remote_host_ip4_prefix - IP address prefix for host IP addresses
| | ... | (Optional). Type: string or integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \|
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \
| | ... | \| 192.168.0.1 \| 192.168.0.2 \| 32 \|
| | ...
| | [Arguments] | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4}
| | ... | ${dut1_if2_ip4} | ${remote_host1_ip4}=${NONE}
| | ... | ${remote_host2_ip4}=${NONE} | ${remote_host_ip4_prefix}=${NONE}
| | ...
| | ${dut_tg_ip4_prefix}= | Set Variable | 24
| | ...
| | Add arp on dut | ${dut_node} | ${dut_to_tg_if1} | ${tg_if1_ip4}
| | ... | ${tg_to_dut_if1_mac}
| | Add arp on dut | ${dut_node} | ${dut_to_tg_if2} | ${tg_if2_ip4}
| | ... | ${tg_to_dut_if2_mac}
| | ...
| | Configure IP addresses on interfaces | ${dut_node} | ${dut_to_tg_if1}
| | ... | ${dut1_if1_ip4} | ${dut_tg_ip4_prefix}
| | Configure IP addresses on interfaces | ${dut_node} | ${dut_to_tg_if2}
| | ... | ${dut1_if2_ip4} | ${dut_tg_ip4_prefix}
| | ...
| | Run Keyword Unless | '${remote_host1_ip4}' == '${NONE}'
| | ... | Vpp Route Add | ${dut_node} | ${remote_host1_ip4}
| | ... | ${remote_host_ip4_prefix} | gateway=${tg_if1_ip4}
| | ... | interface=${dut_to_tg_if1}
| | Run Keyword Unless | '${remote_host2_ip4}' == '${NONE}'
| | ... | Vpp Route Add | ${dut_node} | ${remote_host2_ip4}
| | ... | ${remote_host_ip4_prefix} | gateway=${tg_if2_ip4}
| | ... | interface=${dut_to_tg_if2}
| Configure IPv4 forwarding in 3-node circular topology
| | [Documentation]
| | ... | Set UP state on VPP interfaces in path on nodes in 3-node circular
| | ... | topology. Get the interface MAC addresses and setup ARP on all VPP
| | ... | interfaces. Setup IPv4 addresses with /24 prefix on DUT-TG links.
| | ... | Configure IPv4 adresses with /30 prefix on DUT1-DUT2 link and set
| | ... | routing on both DUT nodes with prefix /24 and next hop of neighbour
| | ... | DUT interface IPv4 address. Configure route entries for remote hosts
| | ... | IPv4 addresses if required.
| | ...
| | ... | *Arguments:*
| | ... | - tg_if1_ip4 - IP address of TG interface1. Type: string
| | ... | - tg_if2_ip4 - IP address of TG interface2. Type: string
| | ... | - dut1_if1_ip4 - IP address of DUT1 interface1. Type: string
| | ... | - dut1_if2_ip4 - IP address of DUT1 interface1. Type: string
| | ... | - dut2_if1_ip4 - IP address of DUT2 interface1. Type: string
| | ... | - dut2_if2_ip4 - IP address of DUT2 interface2. Type: string
| | ... | - remote_host1_ip4 - IP address of remote host1 (Optional).
| | ... | Type: string
| | ... | - remote_host2_ip4 - IP address of remote host2 (Optional).
| | ... | Type: string
| | ... | - remote_host_ip4_prefix - IP address prefix for host IP addresses
| | ... | (Optional). Type: string or integer
| | ...
| | ... | *Example:*
| | ...
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
| | ... | \| 20.20.20.1 \|
| | ... | \| Configure IPv4 forwarding in circular topology \
| | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
| | ... | \| 20.20.20.1 \| 192.168.0.1 \| 192.168.0.2 \| 32 \|
| | ...
| | [Arguments] | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4}
| | ... | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut2_if2_ip4}
| | ... | ${remote_host1_ip4}=${NONE} | ${remote_host2_ip4}=${NONE}
| | ... | ${remote_host_ip4_prefix}=${NONE}
| | ...
| | ${dut_tg_ip4_prefix}= | Set Variable | 24
| | ${dut_link_ip4_prefix}= | Set Variable | 30
| | ...
| | Add arp on dut | ${dut1_node} | ${dut1_to_tg} | ${tg_if1_ip4}
| | ... | ${tg_to_dut1_mac}
| | Add arp on dut | ${dut1_node} | ${dut1_to_dut2} | ${dut2_if1_ip4}
| | ... | ${dut2_to_dut1_mac}
| | Add arp on dut | ${dut2_node} | ${dut2_to_dut1} | ${dut1_if2_ip4}
| | ... | ${dut1_to_dut2_mac}
| | Add arp on dut | ${dut2_node} | ${dut2_to_tg} | ${tg_if2_ip4}
| | ... | ${tg_to_dut2_mac}
| | ...
| | Configure IP addresses on interfaces | ${dut1_node} | ${dut1_to_tg}
| | ... | ${dut1_if1_ip4} | ${dut_tg_ip4_prefix}
| | Configure IP addresses on interfaces | ${dut1_node} | ${dut1_to_dut2}
| | ... | ${dut1_if2_ip4} | ${dut_link_ip4_prefix}
| | Configure IP addresses on interfaces | ${dut2_node} | ${dut2_to_dut1}
| | ... | ${dut2_if1_ip4} | ${dut_link_ip4_prefix}
| | Configure IP addresses on interfaces | ${dut2_node} | ${dut2_to_tg}
| | ... | ${dut2_if2_ip4} | ${dut_tg_ip4_prefix}
| | ...
| | Vpp Route Add | ${dut1_node} | ${tg_if2_ip4} | ${dut_tg_ip4_prefix}
| | ... | gateway=${dut2_if1_ip4} | interface=${dut1_to_dut2}
| | Vpp Route Add | ${dut2_node} | ${tg_if1_ip4} | ${dut_tg_ip4_prefix}
| | ... | gateway=${dut1_if2_ip4} | interface=${dut2_to_dut1}
| | ...
| | Run Keyword Unless | '${remote_host1_ip4}' == '${NONE}'
| | ... | Vpp Route Add | ${dut1_node} | ${remote_host1_ip4}
| | ... | ${remote_host_ip4_prefix} | gateway=${tg_if1_ip4}
| | ... | interface=${dut1_to_tg}
| | Run Keyword Unless | '${remote_host2_ip4}' == '${NONE}'
| | ... | Vpp Route Add | ${dut1_node} | ${remote_host2_ip4}
| | ... | ${remote_host_ip4_prefix} | gateway=${dut2_if1_ip4}
| | ... | interface=${dut1_to_dut2}
| | Run Keyword Unless | '${remote_host1_ip4}' == '${NONE}'
| | ... | Vpp Route Add | ${dut2_node} | ${remote_host1_ip4}
| | ... | ${remote_host_ip4_prefix} | gateway=${dut1_if2_ip4}
| | ... | interface=${dut2_to_dut1}
| | Run Keyword Unless | '${remote_host2_ip4}' == '${NONE}'
| | ... | Vpp Route Add | ${dut2_node} | ${remote_host2_ip4}
| | ... | ${remote_host_ip4_prefix} | gateway=${tg_if2_ip4}
| | ... | interface=${dut2_to_tg}
|
