blob: 8d6bf311d06dfd6921cda8491171e2778e320449 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright (c) 2016 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Settings ***
| Documentation | Lisp State mapping suite keywords
| Resource | resources/libraries/robot/interfaces.robot
| Library | resources.libraries.python.NodePath
| Library | resources.libraries.python.LispSetup.LispLocatorSet
| Library | resources.libraries.python.LispSetup.LispLocator
| Library | resources.libraries.python.LispSetup.LispLocalEid
| Library | resources.libraries.python.LispSetup.LispRemoteMapping
| Library | resources.libraries.python.LispSetup.LispSetup
| Library | resources.libraries.python.LispUtil
*** Keywords ***
| Set up Lisp topology
| | [Documentation] | Set up Lisp static remote mapping topology.
| | ...
| | ... | *Arguments:*
| | ... | - ${dut1_node} - DUT1 node. Type: dictionary
| | ... | - ${dut1_int_name} - DUT1 node interface name. Type: string
| | ... | - ${dut1_int_index} - DUT1 node interface index. Type: integer
| | ... | - ${dut2_node} - DUT2 node. Type: dictionary
| | ... | - ${dut2_int_name} - DUT2 node interface name. Type: string
| | ... | - ${dut2_int_index} - DUT2 node interface index. Type: integer
| | ... | - ${locator_set} - Locator set values. Type: dict
| | ... | - ${dut1_eid} - Dut1 node eid address. Type: dict
| | ... | - ${dut2_eid} - Dut2 node eid address. Type: dict
| | ... | - ${dut1_static_mapping} - Dut1 static mapping address. Type: dict
| | ... | - ${dut2_static_mapping} - Dut2 static mapping address. Type: dict
| | ...
| | ... | *Return:*
| | ... | - No value returned
| | ...
| | ... | *Example:*
| | ... | \| Set up Lisp topology \| ${dut1_node} \| ${interface_name} \
| | ... | \| None \| ${dut2_node} \| ${interface_name} \| None \
| | ... | \| ${locator_set} \| ${dut1_eid} \| ${dut2_eid} \
| | ... | \| ${dut1_static_mapping} \| ${dut2_static_mapping} \|
| | ...
| | [Arguments] | ${dut1_node} | ${dut1_int_name} | ${dut1_int_index}
| | ... | ${dut2_node} | ${dut2_int_name} | ${dut2_int_index}
| | ... | ${locator_set} | ${dut1_eid} | ${dut2_eid}
| | ... | ${dut1_static_mapping} | ${dut2_static_mapping}
| | ${dut1_int_index}= | Run Keyword If | ${dut1_int_index} is None
| | | ... | Get Interface Sw Index | ${dut1_node}
| | | ... | ${dut1_int_name}
| | | ... | ELSE | Set Variable | ${dut1_int_index}
| | ${dut2_int_index}= | Run Keyword If | ${dut2_int_index} is None
| | | ... | Get Interface Sw Index | ${dut2_node}
| | | ... | ${dut2_int_name}
| | | ... | ELSE | Set Variable | ${dut2_int_index}
| | Vpp lisp state | ${dut1_node} | enable
| | Vpp Add Lisp Locator Set | ${dut1_node} | ${locator_set['locator_name']}
| | Vpp Add Lisp Locator | ${dut1_node} | ${locator_set['locator_name']}
| | ... | ${dut1_int_index} | ${locator_set['priority']}
| | ... | ${locator_set['weight']}
| | Vpp Add Lisp Local Eid | ${dut1_node} | ${dut1_eid['locator_name']} | ${dut1_eid['eid']}
| | ... | ${dut1_eid['prefix']}
| | Vpp Add Lisp Remote Mapping | ${dut1_node} | ${dut1_static_mapping['vni']}
| | ... | ${dut1_static_mapping['deid']}
| | ... | ${dut1_static_mapping['prefix']}
| | ... | ${dut1_static_mapping['seid']}
| | ... | ${dut1_static_mapping['prefix']}
| | ... | ${dut1_static_mapping['rloc']}
| | Vpp Lisp State | ${dut2_node} | enable
| | Vpp Add Lisp Locator Set | ${dut2_node} | ${locator_set['locator_name']}
| | Vpp Add Lisp Locator | ${dut2_node} | ${locator_set['locator_name']}
| | ... | ${dut2_int_index} | ${locator_set['priority']}
| | ... | ${locator_set['weight']}
| | Vpp Add Lisp Local Eid | ${dut2_node} | ${dut2_eid['locator_name']} | ${dut2_eid['eid']}
| | ... | ${dut2_eid['prefix']}
| | Vpp Add Lisp Remote Mapping | ${dut2_node} | ${dut2_static_mapping['vni']}
| | ... | ${dut2_static_mapping['deid']}
| | ... | ${dut2_static_mapping['prefix']}
| | ... | ${dut2_static_mapping['seid']}
| | ... | ${dut2_static_mapping['prefix']}
| | ... | ${dut2_static_mapping['rloc']}
|
