blob: 5f602c5780cfeade45d899c5106a6f545bc52e71 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
|
# Copyright (c) 2016 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Variables***
| ${interface}= | ${node['interfaces']['port1']['name']}
| ${bd_name}= | bd_lisp
| ${bd2_name}= | bd2_lisp
| &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
| ... | unknown-unicast-flood=${True} | arp-termination=${True}
*** Settings ***
| Resource | resources/libraries/robot/default.robot
| Resource | resources/libraries/robot/honeycomb/honeycomb.robot
| Resource | resources/libraries/robot/honeycomb/lisp.robot
| Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
| Variables | resources/test_data/honeycomb/lisp.py
| Documentation | *Honeycomb Lisp test suite.*
| Suite Teardown | Run Keyword If Any Tests Failed
| ... | Restart Honeycomb And VPP And Clear Persisted Configuration | ${node}
| Force Tags | honeycomb_sanity
*** Test Cases ***
| TC01: Honeycomb enables Lisp feature
| | [Documentation] | Check if Honeycomb can enable the Lisp feature.
| | Given Lisp Should Not Be Configured | ${node}
| | When Honeycomb Enables Lisp | ${node}
| | Then Lisp state From Honeycomb Should Be | ${node} | enabled
| | And Lisp state From VAT Should Be | ${node} | enabled
| TC02: Honeycomb adds locator set and locator
| | [Documentation] | Check if Honeycomb can configure a locator set.
| | Given Lisp state From Honeycomb Should Be | ${node} | enabled
| | When Honeycomb adds locator set | ${node} | ${interface} | ${locator_set}
| | Then Locator Set From Honeycomb Should Be
| | ... | ${node} | ${interface} | ${locator_set}
| TC03: Honeycomb configures Lisp - remote mapping - Bridge Domain
| | [Documentation] | Check if Honeycomb can configure a remote Lisp mapping\
| | ... | with a bridge domain.
| | Given Lisp state From Honeycomb Should Be | ${node} | enabled
| | And Honeycomb creates first l2 bridge domain
| | ... | ${node} | ${bd_name} | ${bd_settings}
| | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_remote_bd}
| | Then Lisp mapping From Honeycomb Should Be
| | ... | ${node} | ${remote_bd_subtable}
| | And Lisp mapping From VAT Should Be
| | ... | ${node} | ${vat_remote_bd}
| TC04: Honeycomb can remove Lisp mapping
| | [Documentation] | Check if Honeycomb can remove a configured Lisp mapping.
| | Given Lisp mapping From Honeycomb Should Be
| | ... | ${node} | ${remote_bd_subtable}
| | And Lisp mapping From VAT Should Be
| | ... | ${node} | ${vat_remote_bd}
| | When Honeycomb removes all lisp mappings | ${node}
| | Then Lisp mappings from Honeycomb should not exist
| | ... | ${node}
| | And Lisp mappings from VAT should not exist
| | ... | ${node}
| TC05: Honeycomb configures Lisp - remote mapping - VRF
| | [Documentation] | Check if Honeycomb can configure a remote Lisp mapping\
| | ... | with VRF.
| | [Teardown] | Honeycomb removes all lisp mappings | ${node}
| | Given Lisp mappings from Honeycomb should not exist
| | ... | ${node}
| | And Lisp mappings from VAT should not exist
| | ... | ${node}
| | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_remote_vrf}
| | Then Lisp mapping From Honeycomb Should Be
| | ... | ${node} | ${remote_vrf_subtable}
| | And Lisp mapping From VAT Should Be | ${node} | ${vat_remote_vrf}
| TC06: Honeycomb configures Lisp - local mapping - Bridge Domain
| | [Documentation] | Check if Honeycomb can configure a local Lisp mapping\
| | ... | with a bridge domain.
| | [Teardown] | Honeycomb removes all lisp mappings | ${node}
| | Given Locator Set From Honeycomb Should Be
| | ... | ${node} | ${interface} | ${locator_set}
| | And Lisp mappings from Honeycomb should not exist
| | ... | ${node}
| | And Lisp mappings from VAT should not exist
| | ... | ${node}
| | And Honeycomb creates first l2 bridge domain
| | ... | ${node} | ${bd2_name} | ${bd_settings}
| | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_local_bd}
| | Then Lisp mapping From Honeycomb Should Be | ${node} | ${local_bd_subtable}
| | And Lisp mapping From VAT Should Be | ${node} | ${vat_local_bd}
| TC07: Honeycomb configures Lisp - local mapping - VRF
| | [Documentation] | Check if Honeycomb can configure a local Lisp mapping\
| | ... | with VRF.
| | [Teardown] | Honeycomb removes all lisp mappings | ${node}
| | Given Locator Set From Honeycomb Should Be
| | ... | ${node} | ${interface} | ${locator_set}
| | And Lisp mappings from Honeycomb should not exist
| | ... | ${node}
| | And Lisp mappings from VAT should not exist
| | ... | ${node}
| | When Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_local_vrf}
| | Then Lisp mapping From Honeycomb Should Be | ${node} | ${local_vrf_subtable}
| | And Lisp mapping From VAT Should Be | ${node} | ${vat_local_vrf}
| TC08: Honeycomb configures Lisp mapping with adjacency
| | [Documentation] | Check if Honeycomb can configure local and remote Lisp\
| | ... | mappings with VRF, and configure adjacency.
| | [Tags] | EXPECTED_FAILING
# Requests below "vrf-subtable" level fail on table-id lookup (HONEYCOMB-290)
| | [Teardown] | Honeycomb removes all lisp mappings | ${node}
| | Given Locator Set From Honeycomb Should Be
| | ... | ${node} | ${interface} | ${locator_set}
| | And Honeycomb creates first l2 bridge domain
| | ... | ${node} | ${bd2_name} | ${bd_settings}
| | And Lisp mappings from Honeycomb should not exist
| | ... | ${node}
| | And Lisp mappings from VAT should not exist
| | ... | ${node}
| | And Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_local_vrf}
| | And Honeycomb adds Lisp mapping | ${node} | ${lisp_settings_remote_vrf}
| | When Honeycomb adds Lisp adjacency | ${node} | ${4} | remote_map_vrf
| | ... | adj01 | ${remote_vrf_adjacency}
| | Then Lisp mapping from Honeycomb should be
| | ... | ${node} | ${remote_adj_subtable}
| TC09: Honeycomb configures Lisp map resolver
| | [Documentation] | Check if Honeycomb can configure a Lisp map resolver.
| | Given Lisp state From Honeycomb Should Be | ${node} | enabled
| | And Lisp state From VAT Should Be | ${node} | enabled
| | When Honeycomb adds Lisp Map resolver | ${node} | 192.168.0.4
| | Then Map resolver from Honeycomb should be | ${node} | 192.168.0.4
| | And Map resolver from VAT should be | ${node} | 192.168.0.4
| TC10: Honeycomb enabled Lisp PITR feature
| | [Documentation] | Check if Honeycomb can configure the Lisp PITR feature.
| | Given Locator Set From Honeycomb Should Be
| | ... | ${node} | ${interface} | ${locator_set}
| | When Honeycomb enables Lisp PITR feature | ${node} | ${locator_set}
| | Then PITR config from Honeycomb should be | ${node} | ${locator_set}
| | And PITR config from VAT should be | ${node} | ${locator_set}
| TC11: Honeycomb can remove configuration of Lisp features
| | [Documentation] | Check if Honeycomb can disable all Lisp features.
| | [Tags] | EXPECTED_FAILING
# Delete operation fails due to incorrect write order(HONEYCOMB-296),
# but returns code 200: OK (HONEYCOMB-297)
| | Given Map resolver from Honeycomb should be | ${node} | 192.168.0.4
| | And PITR config from Honeycomb should be | ${node} | ${locator_set}
| | When Honeycomb disables all Lisp features | ${node}
| | Then Lisp Should Not Be Configured | ${node}
|
