blob: c281d958192e63bef9bef8dada21e3a4025e608f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
# Copyright (c) 2016 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Variables***
| ${interface}= | ${node['interfaces']['port1']['name']}
*** Settings ***
| Resource | resources/libraries/robot/default.robot
| Resource | resources/libraries/robot/honeycomb/nat.robot
| Resource | resources/libraries/robot/honeycomb/honeycomb.robot
| Variables | resources/test_data/honeycomb/nat.py | ${node} | ${interface}
| ...
| Documentation | *Honeycomb NAT test suite.*
| ...
| Suite Setup | Set Up Honeycomb Functional Test Suite | ${node}
| ...
| Suite Teardown | Tear Down Honeycomb Functional Test Suite | ${node}
| ...
| Force Tags | HC_FUNC
*** Test Cases ***
| TC01: Honeycomb configures NAT entry
| | [Documentation] | Honeycomb configures a static NAT entry.
| | ...
| | Given NAT Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${nat_empty}
| | When Honeycomb Configures NAT Entry | ${node} | ${entry1}
| | Then NAT Entries From Honeycomb Should Be | ${node} | ${entry1}
| TC02: Honeycomb removes NAT entry
| | [Documentation] | Honeycomb removes a configured static NAT entry.
| | ...
| | Given NAT Entries From Honeycomb Should Be | ${node} | ${entry1}
| | When Honeycomb Configures NAT Entry | ${node} | ${NONE}
| | Then NAT Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${nat_empty}
| TC03: Honeycomb configures multiple NAT entries
| | [Documentation] | Honeycomb configures two static NAT entries.
| | ...
| | [Teardown] | Honeycomb Configures NAT Entry | ${node} | ${NONE}
| | ...
| | Given NAT Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${nat_empty}
| | When Honeycomb Configures NAT Entry | ${node} | ${entry1} | ${0} | ${1}
| | And Honeycomb Configures NAT Entry | ${node} | ${entry2} | ${0} | ${2}
| | Then NAT Entries From Honeycomb Should Be
| | ... | ${node} | ${entry1_2_oper} | ${0}
| TC04: Honeycomb enables NAT on interface - inbound
| | [Documentation] | Honeycomb configures NAT on an interface\
| | ... | in inbound direction.
| | ...
| | Given NAT Interface Operational Data From Honeycomb Should Be Empty
| | ... | ${node} | ${interface} | inbound
| | And NAT Interface Operational Data From Honeycomb Should Be Empty
| | ... | ${node} | ${interface} | outbound
| | When Honeycomb Configures NAT On Interface
| | ... | ${node} | ${interface} | inbound
| | Then NAT Interface Operational Data From Honeycomb Should Be
| | ... | ${node} | ${interface} | inbound
| | And NAT Interface Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${interface} | outbound
| TC05: Honeycomb removes NAT interface configuration
| | [Documentation] | Honeycomb removes NAT configuration from an interface.
| | ...
| | Given NAT Interface Operational Data From Honeycomb Should Be
| | ... | ${node} | ${interface} | inbound
| | And NAT Interface Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${interface} | outbound
| | When Honeycomb removes NAT interface configuration
| | ... | ${node} | ${interface} | inbound
| | Then NAT Interface Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${interface} | inbound
| | And NAT Interface Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${interface} | outbound
| TC06: Honeycomb enables NAT on interface - outbound
| | [Documentation] | Honeycomb configures NAT on an interface\
| | ... | in outbound direction.
| | ...
| | [Teardown] | Honeycomb removes NAT interface configuration
| | ... | ${node} | ${interface} | outbound
| | ...
| | Given NAT Interface Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${interface} | inbound
| | And NAT Interface Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${interface} | outbound
| | When Honeycomb Configures NAT on Interface
| | ... | ${node} | ${interface} | outbound
| | Then NAT Interface Operational Data From Honeycomb Should Be empty
| | ... | ${node} | ${interface} | inbound
| | And NAT Interface Operational Data From Honeycomb Should Be
| | ... | ${node} | ${interface} | outbound
|
