blob: b37836ea05c5152adb888f0856d982e52bced1db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Copyright (c) 2020 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Settings ***
| Resource | resources/libraries/robot/shared/default.robot
|
| Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
| ... | NIC_Virtual | ETH | L2XCFWD | BASE | STATS | DRV_VFIO_PCI
| ... | RXQ_SIZE_0 | TXQ_SIZE_0
| ... | ethipv4-l2xcbase-stats
|
| Suite Setup | Setup suite topology interfaces | scapy
| Test Setup | Setup test
| Test Teardown | Tear down test | packet_trace
|
| Test Template | Local Template
|
| Documentation | *VPP statistic commands test cases*
|
| ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology \
| ... | with single links between nodes.
| ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.\
| ... | Both apply to all links.
| ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-connect \
| ... | switching.
| ... | *[Ver] TG verification:* Test IPv4 packets with IP protocol=61 \
| ... | are sent in both directions by TG on links to DUT1; on receive TG \
| ... | verifies packets for correctness and their IPv4 src-addr, dst-addr \
| ... | and MAC addresses. Run VPP statistic commands used in performance tests.
| ... | *[Ref] Applicable standard specifications:* RFC792
*** Variables ***
| @{plugins_to_enable}= | dpdk_plugin.so
| ${crypto_type}= | ${None}
| ${nic_name}= | virtual
| ${nic_driver}= | vfio-pci
| ${nic_rxq_size}= | 0
| ${nic_txq_size}= | 0
| ${nic_pfs}= | 2
| ${nic_vfs}= | 0
| ${overhead}= | ${0}
*** Keywords ***
| Local Template
| | [Documentation]
| | ... | [Ver] Make TG send IPv4 packets in both directions between two\
| | ... | of its interfaces to be switched by DUT to and from docker; verify\
| | ... | all packets are received. Run VPP statistic commands.
| |
| | ... | *Arguments:*
| | ... | - frame_size - Framesize in Bytes in integer. Type: integer
| | ... | - phy_cores - Number of physical cores. Type: integer
| | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
| |
| | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
| |
| | Set Test Variable | \${frame_size}
| |
| | Given Set Max Rate And Jumbo
| | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
| | And Pre-initialize layer driver | ${nic_driver}
| | And Apply startup configuration on all VPP DUTs | with_trace=${True}
| | When Initialize layer driver | ${nic_driver}
| | And Initialize layer interface
| | And Initialize L2 cross connect
| | VPP Enable Elog Traces On All DUTs | ${nodes}
| | Then Send IPv4 bidirectionally and verify received packets
| | ... | ${tg} | ${TG_pf1}[0] | ${TG_pf2}[0]
| | And Verify statistic commands
| Verify statistic commands
| | ${results}= | Create List
| | ${status} | ${value}= | Run Keyword And Ignore Error
| | ... | VPP Show Runtime On All DUTs | ${nodes}
| | Append To List | ${results} | ${status}
| | ${status} | ${value}= | Run Keyword And Ignore Error
| | ... | Show Statistics On All DUTs | ${nodes}
| | Append To List | ${results} | ${status}
| | ${status} | ${value}= | Run Keyword And Ignore Error
| | ... | Show Event Logger On All DUTs | ${nodes}
| | Append To List | ${results} | ${status}
| | ${status} | ${value}= | Run Keyword And Ignore Error
| | ... | VPP Clear Runtime On All DUTs | ${nodes}
| | Append To List | ${results} | ${status}
| | ${status} | ${value}= | Run Keyword And Ignore Error
| | ... | Clear Statistics On All DUTs | ${nodes}
| | Append To List | ${results} | ${status}
| | Should Not Contain Match | ${results} | FAIL
| | ... | msg=At least one of statistic commands failed!
*** Test Cases ***
| 64B-ethipv4-l2xcbase-stats-dev
| | [Tags] | 64B
| | frame_size=${64} | phy_cores=${0}
|
