1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
|
# Copyright (c) 2019 Cisco and/or its affiliates.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at:
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
*** Settings ***
| Library | resources.libraries.python.IPUtil
| Library | resources.libraries.python.Trace
| ...
| Resource | resources/libraries/robot/ip/ip4.robot
| Resource | resources/libraries/robot/ip/ip6.robot
| Resource | resources/libraries/robot/l2/l2_traffic.robot
| Resource | resources/libraries/robot/shared/default.robot
| Resource | resources/libraries/robot/shared/interfaces.robot
| Resource | resources/libraries/robot/shared/testing_path.robot
| Resource | resources/libraries/robot/shared/traffic.robot
| ...
| Force Tags | HW_ENV | VM_ENV | 3_NODE_DOUBLE_LINK_TOPO | SKIP_VPP_PATCH
| ...
| Test Setup | Set up functional test
| ...
| Test Teardown | Tear down functional test
| ...
| Documentation | *Vpn routed forwarding - baseline IPv6*
| ... | *[Top] Network Topologies:* TG=DUT1=DUT2=TG 3-node topology with two
| ... | links in between nodes.
| ... | *[Enc] Packet Encapsulations:* Eth-IPv6-ICMPv6
| ... | *[Cfg] DUT configuration:* Each DUT is configured with two VRF tables;
| ... | Separation of traffic is tested by IP packets; Neighbors and Routes are
| ... | set on DUT nodes; IP addresses are set on DUT interfaces.
| ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets
| ... | are sent by TG on link to DUT1, DUT2 or back to TG; On receipt TG
| ... | verifies packets for correctness and their IPv6 src-addr, dst-addr,
| ... | and MAC addresses.
| ... | *[Ref] Applicable standard specifications:*
*** Variables ***
| ${fib_table_1}= | 9
| ${fib_table_2}= | 99
| ${dut1_to_tg_ip1}= | 2001:62::3
| ${dut1_to_tg_ip2}= | 2001:62::4
| ${dut2_to_tg_ip1}= | 2003:62::3
| ${dut2_to_tg_ip2}= | 2003:62::4
| ${dut1_to_dut2_ip1}= | 2002:62::1
| ${dut1_to_dut2_ip2}= | 2002:62::2
| ${dut2_to_dut1_ip1}= | 2002:62::3
| ${dut2_to_dut1_ip2}= | 2002:62::4
| ${tg_dut1_ip1}= | 2001:62::1
| ${tg_dut1_ip2}= | 2001:62::2
| ${tg_dut2_ip1}= | 2003:62::1
| ${tg_dut2_ip2}= | 2003:62::2
| ${ip_prefix}= | 64
| ${timeout}= | 5
*** Test Cases ***
| TC01: TG packets routed to DUT ingress interface, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT1->TG-if1 and from
| | ... | TG->DUT1-if2 to DUT1->TG-if2 and checked if arrived.
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if1} | ${dut1_to_tg_if1_mac}
| | ... | ${tg_to_dut1_if1_mac} | ${dut1_to_tg_ip1}
| | ... | ${tg_dut1_ip1} | ${timeout}
| | And Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if2} | ${dut1_to_tg_if2_mac}
| | ... | ${tg_to_dut1_if2_mac} | ${dut1_to_tg_ip2}
| | ... | ${tg_dut1_ip2} | ${timeout}
| TC02: TG packets routed to DUT egress interface, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT1->DUT2-if1 and from
| | ... | TG->DUT1-if2 to DUT1->DUT2-if2 and checked if arrived.
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if1} | ${dut1_to_tg_if1_mac} | ${tg_to_dut1_if1_mac}
| | ... | ${dut1_to_dut2_ip1} | ${tg_dut1_ip1} | ${timeout}
| | And Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if2} | ${dut1_to_tg_if2_mac} | ${tg_to_dut1_if2_mac}
| | ... | ${dut1_to_dut2_ip2} | ${tg_dut1_ip2} | ${timeout}
| TC03: TG packets routed to DUT2 ingress interface through DUT1, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT2->DUT1-if1 and from
| | ... | TG->DUT1-if2 to DUT2->DUT1-if2 and checked if arrived.
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if1} | ${dut1_to_tg_if1_mac} | ${tg_to_dut1_if1_mac}
| | ... | ${dut2_to_dut1_ip1} | ${tg_dut1_ip1} | ${timeout}
| | And Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if2} | ${dut1_to_tg_if2_mac} | ${tg_to_dut1_if2_mac}
| | ... | ${dut2_to_dut1_ip2} | ${tg_dut1_ip2} | ${timeout}
| TC04: TG packets routed to DUT2 egress interface through DUT1, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT2->TG-if1 and from
| | ... | TG->DUT1-if2 to DUT2->TG-if2 and checked if arrived.
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if1} | ${dut1_to_tg_if1_mac} | ${tg_to_dut1_if1_mac}
| | ... | ${dut2_to_tg_ip1} | ${tg_dut1_ip1} | ${timeout}
| | And Send ICMP echo request and verify answer | ${tg_node}
| | ... | ${tg_to_dut1_if2} | ${dut1_to_tg_if2_mac} | ${tg_to_dut1_if2_mac}
| | ... | ${dut2_to_tg_ip2} | ${tg_dut1_ip2} | ${timeout}
| TC05: TG packets routed to TG through DUT1 and DUT2, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to TG->DUT2-if1 and from
| | ... | TG->DUT1-if2 to TG->DUT2-if2 and checked if arrived.
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Send packet and verify headers | ${tg_node} | ${tg_dut1_ip1}
| | ... | ${tg_dut2_ip1} | ${tg_to_dut1_if1} | ${tg_to_dut1_if1_mac}
| | ... | ${dut1_to_tg_if1_mac} | ${tg_to_dut2_if1} | ${dut2_to_tg_if1_mac}
| | ... | ${tg_to_dut2_if1_mac}
| | And Send packet and verify headers | ${tg_node}
| | ... | ${tg_dut1_ip2} | ${tg_dut2_ip2} | ${tg_to_dut1_if2}
| | ... | ${tg_to_dut1_if2_mac} | ${dut1_to_tg_if2_mac} | ${tg_to_dut2_if2}
| | ... | ${dut2_to_tg_if2_mac} | ${tg_to_dut2_if2_mac}
| TC06: TG packets not routed to DUT ingress interface in different VRF, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT1->TG-if2 where it
| | ... | should not arrive.
| | [Tags] | SKIP_PATCH
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if1}
| | ... | ${dut1_to_tg_if1_mac} | ${tg_to_dut1_if1_mac}
| | ... | ${dut1_to_tg_ip2} | ${tg_dut1_ip1} | ${timeout}
| | And Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if2}
| | ... | ${dut1_to_tg_if2_mac} | ${tg_to_dut1_if2_mac}
| | ... | ${dut1_to_tg_ip1} | ${tg_dut1_ip2} | ${timeout}
| TC07: TG packets not routed to DUT egress interface in different VRF, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT1->DUT2-if2 where it
| | ... | should not arrive.
| | [Tags] | SKIP_PATCH
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if1}
| | ... | ${dut1_to_tg_if1_mac} | ${tg_to_dut1_if1_mac}
| | ... | ${dut1_to_dut2_ip2} | ${tg_dut1_ip1} | ${timeout}
| | And Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if2}
| | ... | ${dut1_to_tg_if2_mac} | ${tg_to_dut1_if2_mac}
| | ... | ${dut1_to_dut2_ip1} | ${tg_dut1_ip2} | ${timeout}
| TC08: TG packets not routed to DUT2 ingress interface in different VRF through DUT1, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT2->DUT1-if2 where it
| | ... | should not arrive.
| | [Tags] | SKIP_PATCH
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if1}
| | ... | ${dut1_to_tg_if1_mac} | ${tg_to_dut1_if1_mac}
| | ... | ${dut2_to_dut1_ip2} | ${tg_dut1_ip1} | ${timeout}
| | And Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if2}
| | ... | ${dut1_to_tg_if2_mac} | ${tg_to_dut1_if2_mac}
| | ... | ${dut2_to_dut1_ip1} | ${tg_dut1_ip2} | ${timeout}
| TC09: TG packets not routed to DUT2 egress interface in different VRF through DUT1, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to DUT2->TG-if2 where it
| | ... | should not arrive.
| | [Tags] | SKIP_PATCH
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if1}
| | ... | ${dut1_to_tg_if1_mac} | ${tg_to_dut1_if1_mac}
| | ... | ${dut2_to_tg_ip2} | ${tg_dut1_ip1} | ${timeout}
| | And Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send ICMP echo request and verify answer
| | ... | ${tg_node} | ${tg_to_dut1_if2}
| | ... | ${dut1_to_tg_if2_mac} | ${tg_to_dut1_if2_mac}
| | ... | ${dut2_to_tg_ip1} | ${tg_dut1_ip2} | ${timeout}
| TC10: TG packets not routed to TG in different VRF through DUT1 and DUT2, VPP configured with two VRFs
| | [Documentation]
| | ... | [Top] TG=DUT1=DUT2=TG.
| | ... | [Enc] Eth-IPv6-ICMPv6.
| | ... | [Cfg] DUT1 and DUT2 are both configured with two fib tables. Each
| | ... | table is assigned to 2 interfaces to separate the traffic. Interfaces
| | ... | are configured with IP addresses from *Variables*. Neighbors are
| | ... | configured for each DUTs ingress/egress ports, and each VRF is
| | ... | configured with just one route.
| | ... | [Ver] Packet is sent from TG->DUT1-if1 to TG->DUT2-if2 where it
| | ... | should not arrive.
| | [Tags] | SKIP_PATCH
| | Given Configure path in double-link 3-node circular topology
| | ... | ${nodes['TG']} | ${nodes['DUT1']}
| | ... | ${nodes['DUT2']} | ${nodes['TG']}
| | And Set interfaces in double-link 3-node circular topology up
| | When Setup Env - 2xVRF Each Node
| | Then Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send packet and verify headers | ${tg_node} | ${tg_dut1_ip1}
| | ... | ${tg_dut2_ip2} | ${tg_to_dut1_if1}
| | ... | ${tg_to_dut1_if1_mac} | ${dut1_to_tg_if1_mac} | ${tg_to_dut2_if2}
| | ... | ${dut2_to_tg_if2_mac} | ${tg_to_dut2_if2_mac}
| | And Run Keyword And Expect Error | ICMP echo Rx timeout
| | ... | Send packet and verify headers | ${tg_node} | ${tg_dut1_ip2}
| | ... | ${tg_dut2_ip1} | ${tg_to_dut1_if2}
| | ... | ${tg_to_dut1_if2_mac} | ${dut1_to_tg_if2_mac} | ${tg_to_dut2_if1}
| | ... | ${dut2_to_tg_if1_mac} | ${tg_to_dut2_if1_mac}
*** Keywords ***
| Setup Env - 2xVRF Each Node
| | [Documentation]
| | ... | Environment is set up with 2 fib tables on each DUT. DUT1-TG-IF1 and \
| | ... | DUT1-DUT2-IF1 are assigned to FIB1, and DUT1-TG-IF2 and DUT1-DUT2-IF2
| | ... | are assigned to FIB2 (the same done on DUT2, just opposite).
| | ... | IP addresses and IP Neighbors are subsequently set for interfaces.
| | ... | The last setting is route for each fib table.
| | ...
| | ${dut1_if1_idx}= | Get Interface SW Index
| | ... | ${dut1_node} | ${dut1_to_dut2_if1}
| | ${dut1_if2_idx}= | Get Interface SW Index
| | ... | ${dut1_node} | ${dut1_to_dut2_if2}
| | ${dut2_if1_idx}= | Get Interface SW Index
| | ... | ${dut2_node} | ${dut2_to_dut1_if1}
| | ${dut2_if2_idx}= | Get Interface SW Index
| | ... | ${dut2_node} | ${dut2_to_dut1_if2}
| | And Add Fib Table | ${dut1_node} | ${fib_table_1} | ipv6=${TRUE}
| | And Add Fib Table | ${dut1_node} | ${fib_table_2} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut1_node} | ${dut1_to_dut2_if1} | ${fib_table_1} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut1_node} | ${dut1_to_dut2_if2} | ${fib_table_2} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut1_node} | ${dut1_to_tg_if1} | ${fib_table_1} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut1_node} | ${dut1_to_tg_if2} | ${fib_table_2} | ipv6=${TRUE}
| | And Add Fib Table | ${dut2_node} | ${fib_table_1} | ipv6=${TRUE}
| | And Add Fib Table | ${dut2_node} | ${fib_table_2} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut2_node} | ${dut2_to_dut1_if1} | ${fib_table_1} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut2_node} | ${dut2_to_dut1_if2} | ${fib_table_2} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut2_node} | ${dut2_to_tg_if1} | ${fib_table_1} | ipv6=${TRUE}
| | Assign Interface To Fib Table
| | ... | ${dut2_node} | ${dut2_to_tg_if2} | ${fib_table_2} | ipv6=${TRUE}
| | And VPP Interface Set IP Address
| | ... | ${dut1_node} | ${dut1_to_tg_if1} | ${dut1_to_tg_ip1} | ${ip_prefix}
| | And VPP Interface Set IP Address
| | ... | ${dut1_node} | ${dut1_to_tg_if2} | ${dut1_to_tg_ip2} | ${ip_prefix}
| | And VPP Interface Set IP Address
| | ... | ${dut1_node} | ${dut1_to_dut2_if1}
| | ... | ${dut1_to_dut2_ip1} | ${ip_prefix}
| | And VPP Interface Set IP Address
| | ... | ${dut1_node} | ${dut1_to_dut2_if2}
| | ... | ${dut1_to_dut2_ip2} | ${ip_prefix}
| | And VPP Interface Set IP Address
| | ... | ${dut2_node} | ${dut2_to_tg_if1} | ${dut2_to_tg_ip1} | ${ip_prefix}
| | And VPP Interface Set IP Address
| | ... | ${dut2_node} | ${dut2_to_tg_if2} | ${dut2_to_tg_ip2} | ${ip_prefix}
| | And VPP Interface Set IP Address
| | ... | ${dut2_node} | ${dut2_to_dut1_if1}
| | ... | ${dut2_to_dut1_ip1} | ${ip_prefix}
| | And VPP Interface Set IP Address
| | ... | ${dut2_node} | ${dut2_to_dut1_if2}
| | ... | ${dut2_to_dut1_ip2} | ${ip_prefix}
| | And VPP Add IP Neighbor | ${dut1_node} | ${dut1_to_tg_if1}
| | ... | ${tg_dut1_ip1} | ${tg_to_dut1_if1_mac}
| | And VPP Add IP Neighbor | ${dut1_node} | ${dut1_to_dut2_if1}
| | ... | ${dut2_to_dut1_ip1} | ${dut2_to_dut1_if1_mac}
| | And VPP Add IP Neighbor | ${dut2_node} | ${dut2_to_tg_if1}
| | ... | ${tg_dut2_ip1} | ${tg_to_dut2_if1_mac}
| | And VPP Add IP Neighbor | ${dut2_node} | ${dut2_to_dut1_if1}
| | ... | ${dut1_to_dut2_ip1} | ${dut1_to_dut2_if1_mac}
| | And VPP Add IP Neighbor | ${dut1_node} | ${dut1_to_tg_if2}
| | ... | ${tg_dut1_ip2} | ${tg_to_dut1_if2_mac}
| | And VPP Add IP Neighbor | ${dut1_node} | ${dut1_to_dut2_if2}
| | ... | ${dut2_to_dut1_ip2} | ${dut2_to_dut1_if2_mac}
| | And VPP Add IP Neighbor | ${dut2_node} | ${dut2_to_tg_if2}
| | ... | ${tg_dut2_ip2} | ${tg_to_dut2_if2_mac}
| | And VPP Add IP Neighbor | ${dut2_node} | ${dut2_to_dut1_if2}
| | ... | ${dut1_to_dut2_ip2} | ${dut1_to_dut2_if2_mac}
| | And Vpp Route Add | ${dut1_node} | ${tg_dut2_ip1} | ${ip_prefix}
| | ... | gateway=${dut2_to_dut1_ip1} | interface=${dut1_to_dut2_if1}
| | ... | vrf=${fib_table_1}
| | And Vpp Route Add | ${dut2_node} | ${tg_dut1_ip1} | ${ip_prefix}
| | ... | gateway=${dut1_to_dut2_ip1} | interface=${dut2_to_dut1_if1}
| | ... | vrf=${fib_table_1}
| | And Vpp Route Add | ${dut1_node} | ${tg_dut2_ip2} | ${ip_prefix}
| | ... | gateway=${dut2_to_dut1_ip2} | interface=${dut1_to_dut2_if2}
| | ... | vrf=${fib_table_2}
| | And Vpp Route Add | ${dut2_node} | ${tg_dut1_ip2} | ${ip_prefix}
| | ... | gateway=${dut1_to_dut2_ip2} | interface=${dut2_to_dut1_if2}
| | ... | vrf=${fib_table_2}
| | Vpp All RA Suppress Link Layer | ${nodes}
|
