[HICN-114] Update Hicn Http Server to hicn fdio stack

Change-Id: Ic808c93c14f905fd403e60be82ce319757e84c9f
Signed-off-by: Angelo Mantellini <manangel@cisco.com>

2 files changed, 116 insertions, 0 deletions

diff --git a/cmake/Modules/FindCURL.cmake b/cmake/Modules/FindCURL.cmake
new file mode 100644
index 000000000..239b0e505
--- /dev/null
+++ b/cmake/Modules/FindCURL.cmake
@@ -0,0 +1,69 @@
+#.rst:
+# FindCURL
+# --------
+#
+# Find curl
+#
+# Find the native CURL headers and libraries.
+#
+# ::
+#
+#   CURL_INCLUDE_DIRS   - where to find curl_/curl_.h, etc.
+#   CURL_LIBRARIES      - List of libraries when using curl.
+#   CURL_FOUND          - True if curl found.
+#   CURL_VERSION_STRING - the version of curl found (since CMake 2.8.8)
+
+#=============================================================================
+# Copyright 2006-2009 Kitware, Inc.
+# Copyright 2012 Rolf Eike Beer <eike@sf-mail.de>
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+# Look for the header file.
+find_path(CURL_INCLUDE_DIR NAMES curl/curl.h)
+mark_as_advanced(CURL_INCLUDE_DIR)
+
+# Look for the library (sorted from most current/relevant entry to least).
+find_library(CURL_LIBRARY NAMES
+        curl
+        # Windows MSVC prebuilts:
+        curllib
+        libcurl_imp
+        curllib_static
+        # Windows older "Win32 - MSVC" prebuilts (libcurl.lib, e.g. libcurl-7.15.5-win32-msvc.zip):
+        libcurl
+        )
+mark_as_advanced(CURL_LIBRARY)
+
+if(CURL_INCLUDE_DIR)
+    foreach(_curl_version_header curlver.h curl.h)
+        if(EXISTS "${CURL_INCLUDE_DIR}/curl/${_curl_version_header}")
+            file(STRINGS "${CURL_INCLUDE_DIR}/curl/${_curl_version_header}" curl_version_str REGEX "^#define[\t ]+LIBCURL_VERSION[\t ]+\".*\"")
+
+            string(REGEX REPLACE "^#define[\t ]+LIBCURL_VERSION[\t ]+\"([^\"]*)\".*" "\\1" CURL_VERSION_STRING "${curl_version_str}")
+            unset(curl_version_str)
+            break()
+        endif()
+    endforeach()
+endif()
+
+# handle the QUIETLY and REQUIRED arguments and set CURL_FOUND to TRUE if
+# all listed variables are TRUE
+include(FindPackageHandleStandardArgs)
+
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(CURL
+        REQUIRED_VARS CURL_LIBRARY CURL_INCLUDE_DIR
+        VERSION_VAR CURL_VERSION_STRING)
+
+if(CURL_FOUND)
+    set(CURL_LIBRARIES ${CURL_LIBRARY})
+    set(CURL_INCLUDE_DIRS ${CURL_INCLUDE_DIR})
+endif()
diff --git a/cmake/Modules/FindJsoncpp.cmake b/cmake/Modules/FindJsoncpp.cmake
new file mode 100644
index 000000000..acde7b95b
--- /dev/null
+++ b/cmake/Modules/FindJsoncpp.cmake
@@ -0,0 +1,47 @@
+# Find jsoncpp
+#
+# Find the jsoncpp includes and library
+#
+# if you nee to add a custom library search path, do it via via CMAKE_PREFIX_PATH
+#
+# This module defines
+#  JSONCPP_INCLUDE_DIRS, where to find header, etc.
+#  JSONCPP_LIBRARIES, the libraries needed to use jsoncpp.
+#  JSONCPP_FOUND, If false, do not try to use jsoncpp.
+#  JSONCPP_INCLUDE_PREFIX, include prefix for jsoncpp
+
+# only look in default directories
+find_path(
+        JSONCPP_INCLUDE_DIR
+        NAMES jsoncpp/json/json.h json/json.h
+        DOC "jsoncpp include dir"
+)
+
+find_library(
+        JSONCPP_LIBRARY
+        NAMES jsoncpp
+        DOC "jsoncpp library"
+)
+
+set(JSONCPP_INCLUDE_DIRS ${JSONCPP_INCLUDE_DIR})
+set(JSONCPP_LIBRARIES ${JSONCPP_LIBRARY})
+
+# find JSONCPP_INCLUDE_PREFIX
+find_path(
+        JSONCPP_INCLUDE_PREFIX
+        NAMES json.h
+        PATH_SUFFIXES jsoncpp/json json
+)
+
+if (${JSONCPP_INCLUDE_PREFIX} MATCHES "jsoncpp")
+    set(JSONCPP_INCLUDE_PREFIX "jsoncpp/json")
+else()
+    set(JSONCPP_INCLUDE_PREFIX "json")
+endif()
+
+# handle the QUIETLY and REQUIRED arguments and set JSONCPP_FOUND to TRUE
+# if all listed variables are TRUE, hide their existence from configuration view
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(jsoncpp DEFAULT_MSG
+        JSONCPP_INCLUDE_DIR JSONCPP_LIBRARY)
+mark_as_advanced (JSONCPP_INCLUDE_DIR JSONCPP_LIBRARY)
\ No newline at end of file