CSIT-687: Directory structure reorganization

Change-Id: I772c9e214be2461adf58124998d272e7d795220f
Signed-off-by: Tibor Frank <tifrank@cisco.com>
Signed-off-by: Maciek Konstantynowicz <mkonstan@cisco.com>

3 files changed, 399 insertions, 0 deletions

diff --git a/resources/libraries/robot/features/dhcp_client.robot b/resources/libraries/robot/features/dhcp_client.robot
new file mode 100644
index 0000000000..efc016741a
--- /dev/null
+++ b/resources/libraries/robot/features/dhcp_client.robot
@@ -0,0 +1,141 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Library  | Collections
+| Resource | resources/libraries/robot/shared/default.robot
+| Library  | resources.libraries.python.Dhcp.DhcpClient
+| Library  | resources.libraries.python.TrafficScriptExecutor
+| Documentation | DHCP Client specific keywords.
+
+*** Keywords ***
+| Verify DHCP DISCOVER header
+| | [Documentation] | Check if DHCP DISCOVER message contains all required
+| | ... | fields.
+| | ...
+| | ... | *Arguments:*
+| | ... | - tg_node - TG node. Type: dictionary
+| | ... | - interface - TG interface where listen for DHCP DISCOVER message.
+| | ... |   Type: string
+| | ... | - src_mac - DHCP client MAC address. Type: string
+| | ... | - hostname - DHCP client hostname (Optional, Default="", if not
+| | ... |   specified, the hostname is not checked). Type: string
+| | ...
+| | ... | *Return:*
+| | ... | - No value returned.
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Verify DHCP DISCOVER header \| ${nodes['TG']} \
+| | ... | \| eth2 \| 08:00:27:66:b8:57 \|
+| | ... | \| Verify DHCP DISCOVER header \| ${nodes['TG']} \
+| | ... | \| eth2 \| 08:00:27:66:b8:57 \| client-hostname \|
+| | ...
+| | [Arguments] | ${tg_node} | ${interface} | ${src_mac} | ${hostname}=${EMPTY}
+| | ${interface_name}= | Get interface name | ${tg_node} | ${interface}
+| | ${args}= | Catenate | --rx_if | ${interface_name} | --rx_src_mac | ${src_mac}
+| | ${args}= | Run Keyword If | "${hostname}" == "" | Set Variable | ${args}
+| | ...      | ELSE | Catenate | ${args} | --hostname | ${hostname}
+| | Run Traffic Script On Node | dhcp/check_dhcp_discover.py
+| | ... | ${tg_node} | ${args}
+
+
+| Verify DHCP REQUEST after OFFER
+| | [Documentation] | Check if DHCP REQUEST message contains all required
+| | ... | fields. DHCP REQUEST should be send by a client after DHCP OFFER
+| | ... | message sent by a server.
+| | ...
+| | ... | *Arguments:*
+| | ... | - tg_node - TG node. Type: dictionary
+| | ... | - tg_interface - TG interface where listen for DHCP DISCOVER,
+| | ... |   send DHCP OFFER and listen for DHCP REQUEST messages. Type: string
+| | ... | - server_mac - DHCP server MAC address. Type: string
+| | ... | - server_ip - DHCP server IP address. Type: string
+| | ... | - client_mac - DHCP client MAC address. Type: string
+| | ... | - client_ip - IP address that should be offered to client.
+| | ... |   Type: string
+| | ... | - client_mask - IP netmask that should be offered to client.
+| | ... |   Type: string
+| | ... | - hostname - DHCP client hostname (Optional, Default="", if not
+| | ... |   specified, the hostname is not checked). Type: string
+| | ... | - offer_xid - Transaction ID (Optional, Default="", if not specified
+| | ... |   xid field in DHCP OFFER is same as in DHCP DISCOVER message).
+| | ... |   Type: integer
+| | ...
+| | ... | *Return:*
+| | ... | - No value returned.
+| | ...
+| | ... | *Raises:*
+| | ... | - DHCP REQUEST Rx timeout - if no DHCP REQUEST is received.
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Verify DHCP REQUEST after OFFER \| ${nodes['TG']} \
+| | ... | \| eth2 \| 08:00:27:66:b8:57 \| 192.168.23.1 \
+| | ... | \| 08:00:27:46:2b:4c \| 192.168.23.10 \| 255.255.255.0 \|
+| | ...
+| | ... | \| Run Keyword And Expect Error \| DHCP REQUEST Rx timeout \
+| | ... | \| Verify DHCP REQUEST after OFFER \
+| | ... | \| ${nodes['TG']} \| eth2 \| 08:00:27:66:b8:57 \| 192.168.23.1 \
+| | ... | \| 08:00:27:46:2b:4c \| 192.168.23.10 \| 255.255.255.0 \
+| | ... | \| offer_xid=11113333 \|
+| | ...
+| | [Arguments] | ${tg_node} | ${tg_interface} | ${server_mac} | ${server_ip}
+| | ... | ${client_mac} | ${client_ip} | ${client_mask}
+| | ... | ${hostname}=${EMPTY} | ${offer_xid}=${EMPTY}
+| | ${tg_interface_name}= | Get interface name | ${tg_node} | ${tg_interface}
+| | ${args}= | Catenate | --rx_if | ${tg_interface_name} | --server_mac
+| | ... | ${server_mac} | --server_ip | ${server_ip} | --client_mac
+| | ... | ${client_mac} | --client_ip | ${client_ip} | --client_mask
+| | ... | ${client_mask}
+| | ${args}= | Run Keyword If | "${hostname}" == "" | Set Variable | ${args}
+| | ...      | ELSE | Catenate | ${args} | --hostname | ${hostname}
+| | ${args}= | Run Keyword If | "${offer_xid}" == "" | Set Variable | ${args}
+| | ...      | ELSE | Catenate | ${args} | --offer_xid | ${offer_xid}
+| | Run Traffic Script On Node | dhcp/check_dhcp_request.py
+| | ... | ${tg_node} | ${args}
+
+
+| Configure IP on client via DHCP
+| | [Documentation] | Run script that sends IP configuration to the DHCP client.
+| | ...
+| | ... | *Arguments:*
+| | ... | - tg_node - TG node. Type: dictionary
+| | ... | - tg_interface - TG interface where listen for DHCP DISCOVER,
+| | ... |   send DHCP OFFER and DHCP ACK after DHCP REQUEST messages.
+| | ... |   Type: string
+| | ... | - server_mac - DHCP server MAC address. Type: string
+| | ... | - server_ip - DHCP server IP address. Type: string
+| | ... | - client_ip - IP address that is offered to client. Type: string
+| | ... | - client_mask - IP netmask that is offered to client. Type: string
+| | ... | - lease_time - IP lease time in seconds. Type: integer
+| | ...
+| | ... | *Return:*
+| | ... | - No value returned.
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Configure IP on client via DHCP \| ${nodes['TG']} \
+| | ... | \| eth2 \| 08:00:27:66:b8:57 \| 192.168.23.1 \
+| | ... | \| 192.168.23.10 \| 255.255.255.0 \| 86400 \|
+| | ...
+| | [Arguments] | ${tg_node} | ${tg_interface}
+| | ... | ${server_mac} | ${server_ip} | ${client_ip} | ${client_mask}
+| | ... | ${lease_time}
+| | ${tg_interface_name}= | Get interface name | ${tg_node} | ${tg_interface}
+| | ${args}= | Catenate | --rx_if | ${tg_interface_name}
+| | ... | --server_mac | ${server_mac} | --server_ip | ${server_ip}
+| | ... | --client_ip | ${client_ip} | --client_mask | ${client_mask}
+| | ... | --lease_time | ${lease_time}
+| | Run Traffic Script On Node | dhcp/check_dhcp_request_ack.py
+| | ... | ${tg_node} | ${args}
diff --git a/resources/libraries/robot/features/dhcp_proxy.robot b/resources/libraries/robot/features/dhcp_proxy.robot
new file mode 100644
index 0000000000..e6ea69d5d0
--- /dev/null
+++ b/resources/libraries/robot/features/dhcp_proxy.robot
@@ -0,0 +1,159 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Library  | Collections
+| Resource | resources/libraries/robot/shared/default.robot
+| Library  | resources.libraries.python.Dhcp.DhcpProxy
+| Library  | resources.libraries.python.TrafficScriptExecutor
+| Documentation | DHCP Proxy specific keywords.
+
+*** Keywords ***
+| Send DHCP messages and check answer
+| | [Documentation] | Send and receive DHCP messages between client
+| | ...             | and server through DHCP proxy.
+| | ...
+| | ... | *Arguments:*
+| | ... | - tg_node - TG node. Type: dictionary
+| | ... | - tg_interface1 - TG interface. Type: string
+| | ... | - tg_interface2 - TG interface. Type: string
+| | ... | - server_ip - DHCP server IP address. Type: string
+| | ... | - server_mac - DHCP server MAC address. Type: string
+| | ... | - client_ip - Client IP address. Type: string
+| | ... | - client_mac - Client MAC address. Type: string
+| | ... | - proxy_ip - DHCP proxy IP address. Type: string
+| | ...
+| | ... | *Return:*
+| | ... | - No value returned.
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Send DHCP messages and check answer \| ${nodes['TG']} \
+| | ... | \| eth3 \| eth4 \| 192.168.0.100 \| 08:00:27:cc:4f:54 \
+| | ... | \| 172.16.0.2 \| 08:00:27:64:18:d2 \| 172.16.0.1 \|
+| | ...
+| | [Arguments] | ${tg_node} | ${tg_interface1} | ${tg_interface2}
+| | ... | ${server_ip} | ${server_mac} | ${client_ip} | ${client_mac}
+| | ... | ${proxy_ip} |
+| | ${tg_interface_name1}= | Get interface name | ${tg_node} | ${tg_interface1}
+| | ${tg_interface_name2}= | Get interface name | ${tg_node} | ${tg_interface2}
+| | ${args}= | Catenate | --tx_if | ${tg_interface_name1}
+| | ...                 | --rx_if | ${tg_interface_name2}
+| | ...                 | --server_ip | ${server_ip}
+| | ...                 | --server_mac | ${server_mac}
+| | ...                 | --client_ip | ${client_ip}
+| | ...                 | --client_mac | ${client_mac}
+| | ...                 | --proxy_ip | ${proxy_ip}
+| | Run Traffic Script On Node | dhcp/send_and_check_proxy_messages.py
+| | ... | ${tg_node} | ${args}
+
+| Send DHCP DISCOVER and check answer
+| | [Documentation] | Send and receive DHCP DISCOVER.
+| | ...
+| | ... | *Arguments:*
+| | ... | - tg_node - TG node. Type: dictionary
+| | ... | - tg_interface1 - TG interface. Type: string
+| | ... | - tg_interface2 - TG interface. Type: string
+| | ... | - tx_src_ip - Source address of DHCP DISCOVER packet. Type: string
+| | ... | - tx_dst_ip - Destination address of DHCP DISCOVER packet. Type: string
+| | ...
+| | ... | *Return:*
+| | ... | - No value returned.
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Send DHCP DISCOVER and check answer \| ${nodes['TG']} \
+| | ... | \| eth3 \| eth4 \| 0.0.0.0 \| 255.255.255.255 \|
+| | ...
+| | [Arguments] | ${tg_node} | ${tg_interface1} | ${tg_interface2}
+| | ... | ${tx_src_ip} | ${tx_dst_ip} |
+| | ${tg_interface_name1}= | Get interface name | ${tg_node} | ${tg_interface1}
+| | ${tg_interface_name2}= | Get interface name | ${tg_node} | ${tg_interface2}
+| | ${args}= | Catenate | --tx_if | ${tg_interface_name1}
+| | ...                 | --rx_if | ${tg_interface_name2}
+| | ...                 | --tx_src_ip | ${tx_src_ip}
+| | ...                 | --tx_dst_ip | ${tx_dst_ip}
+| | Run Traffic Script On Node | dhcp/send_and_check_proxy_discover.py
+| | ... | ${tg_node} | ${args}
+
+| DHCP DISCOVER should fail
+| | [Documentation] | Send and receive DHCP DISCOVER should fail.
+| | ...
+| | ... | *Arguments:*
+| | ... | - tg_node - TG node. Type: dictionary
+| | ... | - tg_interface1 - TG interface. Type: string
+| | ... | - tg_interface2 - TG interface. Type: string
+| | ... | - tx_src_ip - Source address of DHCP DISCOVER packet. Type: string
+| | ... | - tx_dst_ip - Destination address of DHCP DISCOVER packet. Type: string
+| | ...
+| | ... | *Return:*
+| | ... | - No value returned.
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| DHCP DISCOVER should fail \| ${nodes['TG']} \
+| | ... | \| eth3 \| eth4 \| 0.0.0.0 \| 255.255.255.1 \|
+| | ...
+| | [Arguments] | ${tg_node} | ${tg_interface1} | ${tg_interface2}
+| | ... | ${tx_src_ip} | ${tx_dst_ip} |
+| | ${tg_interface_name1}= | Get interface name | ${tg_node} | ${tg_interface1}
+| | ${tg_interface_name2}= | Get interface name | ${tg_node} | ${tg_interface2}
+| | ${args}= | Catenate | --tx_if | ${tg_interface_name1}
+| | ...                 | --rx_if | ${tg_interface_name2}
+| | ...                 | --tx_src_ip | ${tx_src_ip}
+| | ...                 | --tx_dst_ip | ${tx_dst_ip}
+| | Run Keyword And Expect Error | DHCP DISCOVER Rx timeout
+| | ... | Run Traffic Script On Node | dhcp/send_and_check_proxy_discover.py
+| | ... | ${tg_node} | ${args}
+
+| Send DHCPv6 Messages
+| | [Documentation] | Send and receive DHCPv6 messages between client
+| | ...             | and server through DHCPv6 proxy.
+| | ...
+| | ... | *Arguments:*
+| | ... | - tg_node - TG node. Type: dictionary
+| | ... | - tg_interface1 - TG interface. Type: string
+| | ... | - tg_interface2 - TG interface. Type: string
+| | ... | - proxy_ip - DHCPv6 proxy IP address. Type: string
+| | ... | - proxy_mac - Proxy MAC address. Type: string
+| | ... | - server_ip - DHCPv6 server IP address. Type: string
+| | ... | - server_mac - Server MAC address. Type: string
+| | ... | - client_mac - Client MAC address. Type: string
+| | ... | - proxy_to_server_mac - MAC address of proxy interface
+| | ... |   connected to server. Type: string
+| | ...
+| | ... | *Return:*
+| | ... | - No value returned.
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Send DHCPv6 Messages \| ${nodes['TG']} \
+| | ... | \| eth3 \| eth4 \| 3ffe:62::1 \| 08:00:27:54:59:f9 \
+| | ... | \| 3ffe:63::2 \| 08:00:27:cc:4f:54 \|
+| | ... | \| 08:00:27:64:18:d2 \| 08:00:27:c9:6a:d5 \|
+| | ...
+| | [Arguments] | ${tg_node} | ${tg_interface1} | ${tg_interface2} | ${proxy_ip}
+| | ...         | ${proxy_mac} | ${server_ip} | ${server_mac} | ${client_mac}
+| | ...         | ${proxy_to_server_mac}
+| | ${tg_interface_name1}= | Get interface name | ${tg_node} | ${tg_interface1}
+| | ${tg_interface_name2}= | Get interface name | ${tg_node} | ${tg_interface2}
+| | ${args}= | Catenate | --tx_if | ${tg_interface_name1}
+| | ...                 | --rx_if | ${tg_interface_name2}
+| | ...                 | --proxy_ip | ${proxy_ip}
+| | ...                 | --proxy_mac | ${proxy_mac}
+| | ...                 | --server_ip | ${server_ip}
+| | ...                 | --server_mac | ${server_mac}
+| | ...                 | --client_mac | ${client_mac}
+| | ...                 | --proxy_to_server_mac | ${proxy_to_server_mac}
+| | Run Traffic Script On Node | dhcp/send_dhcp_v6_messages.py
+| | ... | ${tg_node} | ${args}
diff --git a/resources/libraries/robot/features/policer.robot b/resources/libraries/robot/features/policer.robot
new file mode 100644
index 0000000000..321488b8c5
--- /dev/null
+++ b/resources/libraries/robot/features/policer.robot
@@ -0,0 +1,99 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+*** Settings ***
+| Resource | resources/libraries/robot/shared/default.robot
+| Resource | resources/libraries/robot/shared/testing_path.robot
+| Library | resources.libraries.python.Policer
+| Library | resources.libraries.python.InterfaceUtil
+| Library | resources.libraries.python.IPv4Util
+| Library | resources.libraries.python.TrafficScriptExecutor
+| Library | resources.libraries.python.IPv6Util
+| Library | resources.libraries.python.IPv6Setup
+| Library | resources.libraries.python.IPv4Setup.Dut | ${nodes['DUT1']}
+| ...     | WITH NAME | dut1_v4
+| Documentation | *Policer keywords*
+
+*** Keywords ***
+| Configure topology for IPv4 policer test
+| | [Documentation] | Setup topology for IPv4 policer testing.
+| | ...
+| | ... | _NOTE:_ This KW sets following test case variables:
+| | ... | - dut_to_tg_if1_ip - DUT first interface IP address. Type: string
+| | ... | - dut_to_tg_if2_ip - DUT second interface IP address. Type: string
+| | ... | - tg_to_dut_if1_ip - TG first interface IP address. Type: string
+| | ... | - tg_to_dut_if2_ip - TG second interface IP address. Type: string
+| | Configure path in 2-node circular topology | ${nodes['TG']} | ${nodes['DUT1']}
+| | ...                            | ${nodes['TG']}
+| | Set interfaces in 2-node circular topology up
+| | Set Interface Address | ${dut_node} | ${dut_to_tg_if1}
+| | ...                   | ${dut_to_tg_if1_ip4} | ${ip4_plen}
+| | Set Interface Address | ${dut_node} | ${dut_to_tg_if2}
+| | ...                   | ${dut_to_tg_if2_ip4} | ${ip4_plen}
+| | dut1_v4.Set ARP | ${dut_to_tg_if2} | ${tg_to_dut_if2_ip4}
+| | ...             | ${tg_to_dut_if2_mac}
+| | Set Test Variable | ${dut_to_tg_if1_ip} | ${dut_to_tg_if1_ip4}
+| | Set Test Variable | ${dut_to_tg_if2_ip} | ${dut_to_tg_if2_ip4}
+| | Set Test Variable | ${tg_to_dut_if1_ip} | ${tg_to_dut_if1_ip4}
+| | Set Test Variable | ${tg_to_dut_if2_ip} | ${tg_to_dut_if2_ip4}
+
+| Configure topology for IPv6 policer test
+| | [Documentation] | Setup topology for IPv6 policer testing.
+| | ...
+| | ... | _NOTE:_ This KW sets following test case variables:
+| | ... | - dut_to_tg_if1_ip - DUT first interface IP address. Type: string
+| | ... | - dut_to_tg_if2_ip - DUT second interface IP address. Type: string
+| | ... | - tg_to_dut_if1_ip - TG first interface IP address. Type: string
+| | ... | - tg_to_dut_if2_ip - TG second interface IP address. Type: string
+| | Configure path in 2-node circular topology | ${nodes['TG']} | ${nodes['DUT1']}
+| | ...                            | ${nodes['TG']}
+| | Set interfaces in 2-node circular topology up
+| | Vpp Set If IPv6 Addr | ${dut_node} | ${dut_to_tg_if1}
+| | ...                  | ${dut_to_tg_if1_ip6} | ${ip6_plen}
+| | Vpp Set If IPv6 Addr | ${dut_node} | ${dut_to_tg_if2}
+| | ...                  | ${dut_to_tg_if2_ip6} | ${ip6_plen}
+| | Add IP Neighbor | ${dut_node} | ${dut_to_tg_if2} | ${tg_to_dut_if2_ip6}
+| | ...             | ${tg_to_dut_if2_mac}
+| | Vpp All RA Suppress Link Layer | ${nodes}
+| | Set Test Variable | ${dut_to_tg_if1_ip} | ${dut_to_tg_if1_ip6}
+| | Set Test Variable | ${dut_to_tg_if2_ip} | ${dut_to_tg_if2_ip6}
+| | Set Test Variable | ${tg_to_dut_if1_ip} | ${tg_to_dut_if1_ip6}
+| | Set Test Variable | ${tg_to_dut_if2_ip} | ${tg_to_dut_if2_ip6}
+
+| Send packet and verify marking
+| | [Documentation] | Send packet and verify DSCP of the received packet.
+| | ...
+| | ... | *Arguments:*
+| | ... | - node - TG node. Type: dictionary
+| | ... | - tx_if - TG transmit interface. Type: string
+| | ... | - rx_if - TG receive interface. Type: string
+| | ... | - src_mac - Packet source MAC. Type: string
+| | ... | - dst_mac - Packet destination MAC. Type: string
+| | ... | - src_ip - Packet source IP address. Type: string
+| | ... | - dst_ip - Packet destination IP address. Type: string
+| | ... | - dscp - DSCP value to verify. Type: enum
+| | ...
+| | ... | *Example:*
+| | ... | \| ${dscp}= \| DSCP AF22 \|
+| | ... | \| Send packet and verify marking \| ${nodes['TG']} \| eth1 \| eth2 \
+| | ... | \| 08:00:27:87:4d:f7 \| 52:54:00:d4:d8:22 \| 192.168.122.2 \
+| | ... | \| 192.168.122.1 \| ${dscp} \|
+| | [Arguments] | ${node} | ${tx_if} | ${rx_if} | ${src_mac} | ${dst_mac}
+| | ...         | ${src_ip} | ${dst_ip} | ${dscp}
+| | ${tx_if_name}= | Get Interface Name | ${node} | ${tx_if}
+| | ${rx_if_name}= | Get Interface Name | ${node} | ${rx_if}
+| | ${args}= | Traffic Script Gen Arg | ${rx_if_name} | ${tx_if_name}
+| | ...      | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
+| | ${dscp_num}= | Get DSCP Num Value | ${dscp}
+| | ${args}= | Set Variable | ${args} --dscp ${dscp_num}
+| | Run Traffic Script On Node | policer.py | ${node} | ${args}